Плагин бан список !

#include <amxmodx>
#include <amxmisc>

public plugin_init()
{
    register_plugin("AMXX Ban List Viewer","0.1a","Drak");
    
    register_concmd("amx_banlist","CmdBanList",ADMIN_BAN,"Views the users in the banned.cfg file");
    register_concmd("amx_iplist", "CmdIPList", ADMIN_BAN, "Views the users in the listip.cfg file");
}

public CmdBanList(id,level,cid)
{
    if(!cmd_access(id,level,cid,1))
        return PLUGIN_HANDLED
    
    new pFile = fopen("banned.cfg","r");
    if(!pFile)
        return client_print(id,print_console,"[AMXX BanList] Unable to open banned.cfg.");
    
    new Data[256],Arg1[24],Arg2[24],Arg3[24]
    while(!feof(pFile))
    {
        fgets(pFile,Data,255);
        if(contain(Data,"banid") != -1)
        {
            // BANID TIME USER
            parse(Data,Arg1,23,Arg2,23,Arg3,23);
            if(equal(Arg2,"0.0"))
                replace(Arg2,23,"0.0","Forever");
            
            client_print(id,print_console,"[AMXX] Type: %s Time: %s AuthID/IP: %s",Arg1,Arg2,Arg3);
        }
    }
    fclose(pFile);
    return PLUGIN_HANDLED
}

public CmdIPList(id, level, cid)
{
    if(!cmd_access(id, level, cid, 1))
    {
        return PLUGIN_HANDLED;
    }
    
    new file = fopen("listip.cfg", "rt");
    if(!file)
    {
        console_print(id, "[AMXX] Unabled to find listip.cfg");
        return PLUGIN_HANDLED;
    }
    
    console_print(id, "[AMXX] Start of listip.cfg");
    
    new sData[256];
    new sAddIP[6];
    new sTime[10];
    new sIP[64];
    
    new start;
    
    do
    {
        fgets(file, sData, sizeof(sData) - 1);
        start = containi(sData, "addip");
        if(start < 0)
        {
            continue;
        }
        
        parse(sData[start], sAddIP, sizeof(sAddIP) - 1, sTime, sizeof(sTime) - 1, sIP, sizeof(sIP) - 1);
        console_print(id, "[AMXX] Banip Time: %s  -- IP: %s", sTime, sIP);
    }
    while(!feof(file))
    console_print(id, "[AMXX] End of listip.cfg");
    return PLUGIN_HANDLED;
}