Show_ip - Shows Players Ip And Subnet Description

/* AMX Mod X script.
*
*   Show IP and hostname
*   Copyright (c) 2008 ahtoh /Russia/
*
*
*   INSTALLATION TIPS:
*
*   1. In order to use this plugin you need NETDB module
*      get it here http://forums.alliedmods.net/showthread.php?t=52326
*      Put netdb_amxx_i386.so to amxmodx\modules dir
*   2. Add line "netdb" to amxmodx\configs\modules.ini file.
*   3. Put show_ip.amxx to amxmodx\plugins dir.
*   4. Add line "show_ip.amxx" to amxmodx\configs\plugins.ini file.
*   5. Copy example ipdesc.ini file to amxmodx\configs dir.
*   6. Edit ipdesc.ini file.
*      Fill it with IP Subnets and their Descriptions.
*      IP Subnet must be in CIDR Notation (like 192.168.0.0/24).
*      Online Subnet Calcilator: http://www.subnet-calculator.com/cidr.php
*      IP Subnet Description will be shown to all players or admins only (depending on amx_showip_admins cvar)
*      when player connects or disconnects from the server.
*
*
*   CONSOLE COMMANDS:
*
*   - amx_showip
*       - shows IP, hostname and IP description of players on server
*
*
*   CVARS:
*
*   - amx_showip_unknown (default is "")
*       - unknown IP subnet (not in ipdesc.ini)
*
*   - amx_showip_showhost (default is "1")
*       - show hostnames on connect/disconnect
*
*      - amx_showip_admins (default is "0")
*       - show for admins only
*
*
*   VERSION HISTORY:
*
*   v1.61 - 07/30/08
*         - minor display changes
*
*   v1.6 - 07/29/08
*         - removed ADMIN_LEVEL macro
*         - added amx_showip_admins CVAR
*       - code cleanup
*
*   v1.55 - 04/20/07
*       - Performance optimizations
*
*   v1.5 - 04/05/07
*       - Threading support for socket functions added (should fix lagging)
*
*   v1.4 - 03/08/07
*       - reverse DNS support added (use "amx_showip_showhost 0" to disable it)
*
*   v1.3 - 03/06/07
*       - ADMIN_LEVEL macro added to restrict access if needed
*       - code cleanup and performance optimizations
*
*   v1.2 - 03/03/07
*       - Added colored chat messages support (use "amx_showip_usecolor 0" to disable it)
*
*   v1.1 - 03/01/07
*       - Added support for CIDR notation for ipdesc.ini file
*
*   v1.0 - 02/28/07
*    - Original show_ip plugin by W@lker /Yakutsk,Russia/ was rewritten for amxx
*/

#include <amxmodx>
#include <amxmisc>
#include "netdb"

#define MAX_PLAYERS 32
#define MAX_DESCRIPTION_LEN 64
#define MAX_HOSTNAME_LEN 180

#define SHIFT_8  8
#define SHIFT_16 16
#define SHIFT_24 24

#define MAX_SUBNETS 1024 // Maximum records in ipdesc.ini file

enum ChatColor
{
    CHATCOLOR_YELLOW = 1,     // Yellow
    CHATCOLOR_GREEN,         // Green Color
    CHATCOLOR_TEAM_COLOR,     // Red, grey, blue
    CHATCOLOR_GREY,         // grey
    CHATCOLOR_RED,             // Red
    CHATCOLOR_BLUE,         // Blue
}

new g_TeamName[][] =
{
    "",
    "TERRORIST",
    "CT",
    "SPECTATOR"
}


new PLUGINNAME[] = "ShowIP"
new PLUGINVERSION[] = "1.61"

new g_SubnetIP[MAX_SUBNETS]
new g_SubnetMask[MAX_SUBNETS]
new g_SubnetDescription[MAX_SUBNETS][MAX_DESCRIPTION_LEN + 1]
new g_SubnetCount = 0

new g_IPDescription[MAX_PLAYERS + 1][MAX_DESCRIPTION_LEN + 1]
new g_HostName[MAX_PLAYERS + 1][MAX_HOSTNAME_LEN + 1]
new g_msgSayText
new g_msgTeamInfo

new amx_showip_admins
new amx_showip_unknown
new amx_showip_showhost

public plugin_init()
{
    register_plugin(PLUGINNAME, PLUGINVERSION, "ahtoh")

    register_cvar(PLUGINNAME, PLUGINVERSION, FCVAR_SERVER | FCVAR_SPONLY)

    amx_showip_unknown     = register_cvar("amx_showip_unknown", "")         // unknown IP subnet
    amx_showip_showhost = register_cvar("amx_showip_showhost", "1")     // show hostnames on connect/disconnect
    amx_showip_admins     = register_cvar("amx_showip_admins", "0")         // show only for admins

    register_concmd("amx_showip", "cmdShowIP", ADMIN_ALL,"- shows players IPs")

    new configsDir[64]
    get_configsdir(configsDir, sizeof(configsDir)-1)
    format(configsDir, sizeof(configsDir)-1, "%s/ipdesc.ini", configsDir)

    loadSubnets(configsDir) // Load IP Descriptions from ipdesc.ini
    
    g_msgSayText = get_user_msgid("SayText")
    g_msgTeamInfo = get_user_msgid("TeamInfo")
}

public cmdShowIP(id, level, cid)
{
    if (!cmd_access(id, level, cid, 1))
        return PLUGIN_HANDLED

    new players[32], inum, userip[16], name[32]
    
    get_players(players, inum)
    console_print(id, "^nPlayers on server:^n #  %-25.24s %-20s %-33.32s %s", "Nick", "IP", "Hostname", "Description")
    
    for (new a = 0; a < inum; ++a)
    {
        get_user_ip(players[a],userip,sizeof(userip)-1,1)
        get_user_name(players[a], name, sizeof(name)-1)
        console_print(id, "%2d  %-25.24s %-20s %-33.32s %s", players[a], name, userip, g_HostName[players[a]], g_IPDescription[players[a]])
    }
    
    console_print(id, "Total: %d", inum)
    
    return PLUGIN_HANDLED
}

public client_authorized(id)
{
    new userip[16]

    get_user_ip(id,userip,sizeof(userip)-1,1)
    get_ip_description(userip, g_IPDescription[id], MAX_DESCRIPTION_LEN)

    thr_gethostbyaddr("client_showconnected", userip, g_HostName[id], MAX_HOSTNAME_LEN, id)
    
    return PLUGIN_CONTINUE
}
    
public client_showconnected(id)
{
    displayToPlayers(id,"is trying to connect");
}  

public client_disconnect(id)
{
    displayToPlayers(id,"dropped");

    return PLUGIN_CONTINUE
}

displayToPlayers(id, const msg[])
{
    new userip[16]
    new name[32]

    get_user_ip(id,userip,sizeof(userip)-1,1)
    get_user_name(id,name,sizeof(name)-1)

    new bool:showhost
    new bool:showdesc
    
    new maxpl = get_maxplayers();
    for (new i = 1; i <= maxpl; i++)
    {
        if (! is_user_connected(i))
            continue
        
        if (get_pcvar_num(amx_showip_admins) == 1 && !access(i, ADMIN_ADMIN))
            continue

        showhost = equal(userip, g_HostName[id]) ? false : (get_pcvar_num(amx_showip_showhost) == 1)

        showdesc = (g_IPDescription[id][0] == 0) ? false : true
        
        if (showhost && showdesc)
        {
            colorChat(i, CHATCOLOR_RED, "^x04%s ^x01(^x03%s^x01, ^x03%s^x01, ^x03%s^x01) %s", name, userip, g_HostName[id], g_IPDescription[id], msg)
        }
        else if (showhost)
        {
            colorChat(i, CHATCOLOR_RED, "^x04%s ^x01(^x03%s^x01, ^x03%s^x01) %s", name, userip, g_HostName[id], msg)
        }
        else if (showdesc)
        {
            colorChat(i, CHATCOLOR_RED, "^x04%s ^x01(^x03%s^x01, ^x03%s^x01) %s", name, userip, g_IPDescription[id], msg)
        }
        else
        {
            colorChat(i, CHATCOLOR_RED, "^x04%s ^x01(^x03%s^x01) %s", name, userip, msg)
        }
    }
}


// ColorChat function, stolen from http://forums.alliedmods.net/showthread.php?t=45753
colorChat(id, ChatColor:color, const msg[], {Float,Sql,Result,_}:...)
{
    new team, index, MSG_Type
    new bool:teamChanged = false
    new message[192]

    switch(color)
    {
        case CHATCOLOR_YELLOW: // Yellow
        {
            message[0] = 0x01;
        }
        case CHATCOLOR_GREEN: // Green
        {
            message[0] = 0x04;
        }
        default: // Grey, Red, Blue
        {
            message[0] = 0x03;
        }
    }

    vformat(message[1], sizeof(message)-2, msg, 4);

    if (id == 0)
    {
        index = findAnyPlayer();
        MSG_Type = MSG_ALL;
    }
    else
    {
        index = id;
        MSG_Type = MSG_ONE;
    }
    
    if (index != 0)
    {
        team = get_user_team(index);    

        if (color == CHATCOLOR_RED && team != 1)
        {
            messageTeamInfo(index, MSG_Type, g_TeamName[1])
            teamChanged = true
        }
        else if (color == CHATCOLOR_BLUE && team != 2)
        {
            messageTeamInfo(index, MSG_Type, g_TeamName[2])
            teamChanged = true
        }
        else if (color == CHATCOLOR_GREY && team != 0)
        {
            messageTeamInfo(index, MSG_Type, g_TeamName[0])
            teamChanged = true
        }
    
        messageSayText(index, MSG_Type, message);
            
        if (teamChanged)
        {
            messageTeamInfo(index, MSG_Type, g_TeamName[team]);
        }
    }
}

messageSayText(id, type, message[])
{
    message_begin(type, g_msgSayText, _, id)
    write_byte(id)        
    write_string(message)
    message_end()
}

messageTeamInfo(id, type, team[])
{
    message_begin(type, g_msgTeamInfo, _, id)
    write_byte(id)
    write_string(team)
    message_end()
}

findAnyPlayer()
{
    new maxpl = get_maxplayers();
    for (new i = 1; i <= maxpl; i++)
    {
        if (is_user_connected(i))
        {
            return i
        }
    }

    return 0
}

// Find subnet description
get_ip_description(const ip[], description[], maxlen)
{
    new numIP = ip_to_num(ip)
    
    for (new i = 0; i < g_SubnetCount; i++)
    {
        if (apply_mask(numIP, g_SubnetMask[i]) == g_SubnetIP[i])
        {
            copy(description, maxlen, g_SubnetDescription[i])
            return 0
        }
    }

    get_pcvar_string(amx_showip_unknown, description, maxlen)

    return -1
}

// IP to NUM
ip_to_num(const ip[])
{
    new n1[4], n2[4], n3[4], n4[4]
    new tmpStr[16]
    
    copy(tmpStr, sizeof(tmpStr)-1, ip)
    replace_all(tmpStr, sizeof(tmpStr)-1, ".", " ")
    if (parse(tmpStr, n1, sizeof(n1)-1, n2, sizeof(n2)-1, n3, sizeof(n3)-1, n4, sizeof(n4)-1) != 4)
        return -1 // wrong ip address
        
    return (str_to_num(n1) << SHIFT_24) + (str_to_num(n2) << SHIFT_16) + (str_to_num(n3) << SHIFT_8) + str_to_num(n4)
}

// this rounds ip to its subnet by given mask
apply_mask(const numIP, const maskBit)
{
    if (maskBit < 0 || maskBit > 32)
        return -1 // wrong mask

    new shift = 32 - maskBit
    
    return (numIP >> shift) << shift
}

loadSubnets(szFilename[])
{
    g_SubnetCount = 0
    
    new File=fopen(szFilename,"r");

    if (File)
    {
        new Text[256]
        new subnet[24], subnetIP[16], subnetMask[8]
    
        while(g_SubnetCount < MAX_SUBNETS && !feof(File))
        {
            fgets(File,Text,sizeof(Text)-1);

            trim(Text)
            
            // comment or blank line
            if (Text[0]==';' || Text[0] == 0)
            {
                continue;
            }

            strbreak(Text, subnet, sizeof(subnet)-1, g_SubnetDescription[g_SubnetCount], MAX_DESCRIPTION_LEN)

            replace(subnet, sizeof(subnet)-1, "/", " ")
            if (parse(subnet, subnetIP, sizeof(subnetIP)-1, subnetMask, sizeof(subnetMask)-1) != 2)
                continue // wrong subnet
            
            g_SubnetIP[g_SubnetCount] = ip_to_num(subnetIP)
            g_SubnetMask[g_SubnetCount] = str_to_num(subnetMask)
            
            ++g_SubnetCount
        }
    }

    return 1
}

[ua]
PLAYER_CONNECT = пробує з'єднатися
PLAYER_DISCONNECT = від'єднався

[ru]
PLAYER_CONNECT = пробует соединится
PLAYER_DISCONNECT = отсоединился

[en]
PLAYER_CONNECT = is trying to connect
PLAYER_DISCONNECT = dropped