RCON Defencer

/*
Created by DJ_WEST

Web: http://amx-x.ru
Русское сообщество по AMX Mod X и SourceMod

Присоединяйтесь к нам. Здесь рождаются новые идеи.
*/


#include <amxmodx>
#include <amxmisc>
#include <orpheu>
#include <orpheu_advanced>

#define PLUGIN "RCON Defencer"
#define VERSION "1.2"
#define AUTHOR "DJ_WEST"

// Укажите здесь ваш RCON пароль в MD5 формате
#define RCON_PASSWORD "пароль в md5"

#define IP_FILE "rcon_defencer.ini"


new g_CvarRconPassword, g_CvarDefencerType, Array:g_a_IP

enum
{
NA_UNUSED = 0,
NA_LOOPBACK,
NA_BROADCAST,
NA_IP,
NA_IPX,
NA_BROADCAST_IPX
}


public plugin_init()
{
register_plugin(PLUGIN, VERSION, AUTHOR)

OrpheuRegisterHook(OrpheuGetFunction("SV_Rcon_Validate"), "On_Rcon_Validate_Pre", OrpheuHookPre)
OrpheuRegisterHook(OrpheuGetFunction("SV_Rcon_Validate"), "On_Rcon_Validate_Post", OrpheuHookPost)

g_CvarRconPassword = get_cvar_pointer("rcon_password")
g_CvarDefencerType = register_cvar("rcon_defencer_type", "0")
}

public plugin_cfg()
{
if (get_pcvar_num(g_CvarDefencerType))
{
static i_File, s_File[128], s_IP[16], i_Len

get_configsdir(s_File, charsmax(s_File))
format(s_File, charsmax(s_File), "%s/%s", s_File, IP_FILE)

g_a_IP = ArrayCreate(16)
i_File = fopen(s_File, "rt")

while (!feof(i_File))
{
fgets(i_File, s_IP, charsmax(s_IP))
i_Len = strlen(s_IP)

if (i_Len && s_IP[i_Len-1] == 0x0A)
s_IP[i_Len-1] = '^0'

ArrayPushString(g_a_IP, s_IP)
}

fclose(i_File)

OrpheuRegisterHook(OrpheuGetFunction("SV_Rcon"), "On_Rcon", OrpheuHookPre)
}
}

public plugin_end()
ArrayDestroy(g_a_IP)

public OrpheuHookReturn:On_Rcon_Validate_Pre()
{
static s_Rcon[32], s_MD5[34]

read_argv(2, s_Rcon, charsmax(s_Rcon))
md5(s_Rcon, s_MD5)

if (equal(s_MD5, RCON_PASSWORD))
set_pcvar_string(g_CvarRconPassword, s_Rcon)
}

public OrpheuHookReturn:On_Rcon_Validate_Post()
set_pcvar_string(g_CvarRconPassword, "")

public OrpheuHookReturn:On_Rcon(p_Adress)
{
static i_Adress[22], s_IP[16], s_RconIP[16], i_Type, i

s_IP[0] = '^0'
i_Type = get_pcvar_num(g_CvarDefencerType)

OrpheuGetBytesAtAddress(p_Adress, i_Adress, charsmax(i_Adress))

if (i_Adress[0] == NA_IP)
{
formatex(s_RconIP, charsmax(s_RconIP), "%i.%i.%i.%i",i_Adress[4], i_Adress[5], i_Adress[6], i_Adress[7])

for (i = 0; i < ArraySize(g_a_IP); i++)
{
ArrayGetString(g_a_IP, i, s_IP, charsmax(s_IP))

if (equal(s_IP, s_RconIP))
{
switch (i_Type)
{
case 1: return OrpheuIgnored
case 2: return OrpheuSupercede
}
}
}
}

switch (i_Type)
{
case 1: return OrpheuSupercede
case 2: return OrpheuIgnored
}

return OrpheuIgnored
}