Скрытый слот

/* AMX Mod X
*   Slots Reservation Plugin
*
* by the AMX Mod X Development Team
*  originally developed by OLO
*
* This file is part of AMX Mod X.
*
*
*  This program is free software; you can redistribute it and/or modify it
*  under the terms of the GNU General Public License as published by the
*  Free Software Foundation; either version 2 of the License, or (at
*  your option) any later version.
*
*  This program is distributed in the hope that it will be useful, but
*  WITHOUT ANY WARRANTY; without even the implied warranty of
*  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
*  General Public License for more details.
*
*  You should have received a copy of the GNU General Public License
*  along with this program; if not, write to the Free Software Foundation,
*  Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
*
*  In addition, as a special exception, the author gives permission to
*  link the code of this program with the Half-Life Game Engine ("HL
*  Engine") and Modified Game Libraries ("MODs") developed by Valve,
*  L.L.C ("Valve"). You must obey the GNU General Public License in all
*  respects for all of the code used other than the HL Engine and MODs
*  from Valve. If you modify this file, you may extend this exception
*  to your version of the file, but you are not obligated to do so. If
*  you do not wish to do so, delete this exception statement from your
*  version.
*/

/*
*    Rebuilding by UFPS Team (Part of UFPS Slots Management plugin)
*
*   Slots Reservation Plugin Extended
*
*    amx_reservation 0|1|2
*        0 - kick bots
*        1 - kick bots and high ping players
*        2 - kick bots and shortest playing time players
*
*    amx_hideslots -    slots for reservation
*
*    amx_redirect 0|1
*        0 - redirect disable
*        1 - redirect enable
*
*    amx_redirectserver "server:port"
*
*/

#include <amxmodx>
#include <amxmisc>

new g_ResPtr
new g_HidePtr

public plugin_init()
{
    register_plugin("Slots Reservation", AMXX_VERSION_STR, "AMXX Dev Team")
    register_dictionary ( "adminslots.txt" )
    register_dictionary ( "common.txt" )

    g_ResPtr = register_cvar ( "amx_reservation", "1" )
    g_HidePtr = register_cvar ( "amx_hideslots", "1" )

    register_cvar ( "amx_redirect","0" )
    register_cvar ( "amx_redirectserver","" )
}

public plugin_cfg()
{
    if ( get_pcvar_num ( g_HidePtr ) )
    {
        set_cvar_num ( "sv_visiblemaxplayers", get_maxplayers() - get_pcvar_num ( g_HidePtr ) )
    }
}

public client_authorized ( id )
{
    new maxplayers = get_maxplayers()
    new players = get_playersnum ( 1 )
    new limit = maxplayers - get_pcvar_num ( g_HidePtr )

    if ( players > limit )
    {
        new lReason[64]

        format ( lReason, sizeof ( lReason ) - 1, "%L", id, "DROPPED_RES" )

        if ( access ( id, ADMIN_RESERVATION ) )
        {
            if ( players < maxplayers )
            {
                return PLUGIN_CONTINUE
            }

            new who = findKickPlayer()

            if ( who )
            {
                if ( is_user_bot ( who ) )
                {
                    server_cmd ( "kick #%d", get_user_userid ( who ) )
                }

                else
                {
                    new name[32]

                       get_user_name ( who, name, sizeof ( name ) - 1 )

                       client_cmd ( id, "echo ^"* %s was kicked to free this slot^"", name )
                       server_cmd ( "kick #%d ^"%s^"", get_user_userid ( who ), lReason )
                }
            }

            return PLUGIN_CONTINUE
        }

        if ( !is_user_bot ( id ) && get_cvar_num ( "amx_redirect" ) )
        {
            new redir_server[64]

            get_cvar_string ( "amx_redirectserver", redir_server, sizeof ( redir_server ) - 1 )

            client_cmd ( id, "echo ^"* Server is full, redirect to free server.^";wait;wait;wait;connect %s", redir_server )
            server_cmd ( "kick #%d ^"%s^"", get_user_userid ( id ), lReason )
        }

        else
        {
            server_cmd ( "kick #%d ^"%s^"", get_user_userid ( id ), lReason )
        }

        return PLUGIN_HANDLED
    }

    return PLUGIN_CONTINUE
}

findKickPlayer()
{
    new players[32], num
    get_players ( players, num, "" )
    
    new f_id, ping, loss, time, shrt, tmp = -1
    new f_type = get_pcvar_num ( g_ResPtr )

    if ( num ) shrt = get_user_time ( players[0] )

    for ( new i = 0; i < num; ++i )
    {
        if ( !access ( players[i], ADMIN_RESERVATION ) )
        {
            if ( is_user_bot ( players[i] ) )
            {
                return players[i]
            }
    
            if ( f_type == 1 )
            {
                get_user_ping ( players[i], ping, loss )
    
                if ( ping > tmp )
                {
                    tmp = ping
                    f_id = players[i]
                }
            }
    
            else
            {
                time = get_user_time ( players[i] )
    
                if ( time <= shrt )
                {
                    shrt = time
                    f_id = players[i]
                }
            }
        }
    }
    
    return f_id
}