Autobuy Fix v.1.1

#include <amxmodx>

#define PLUGIN_NAME "Fix AutoBuy Bug"
#define PLUGIN_VERSION "1.4"
#define PLUGIN_AUTHOR "PomanoB / UFPS.Team"

#define DEFAULT_AUTOBUY "m4a1 ak47 famas galil p90 mp5 primammo secammo defuser vesthelm vest"


new g_menuid
new g_verify [33]
new g_logfile [64]


public plugin_init( )
{
register_plugin( PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR )
register_dictionary( "autobuyfix.txt" )

register_clcmd( "cl_setautobuy", "cmd_check" )
register_clcmd( "cl_setrebuy", "cmd_check" )

get_time ( "autobuy_%Y%m.log", g_logfile, charsmax ( g_logfile ) )
}

public plugin_cfg()
{
g_menuid = menu_create( "AUTOBUY_CLEAR_MENU", "_handle_menu", 1 )
menu_additem( g_menuid, "", "1" )
menu_additem( g_menuid, "", "2" )
menu_setprop( g_menuid, MPROP_NUMBER_COLOR, "\r" )
menu_setprop( g_menuid, MPROP_EXIT, MEXIT_NEVER )
}

public cmd_check( id )
{
static arg[512], args, i
args = read_argc( )

for( i = 1; i < args; ++i )
{
read_argv( i, arg, charsmax( arg ) )

if( is_cmd_long( arg, charsmax( arg ) ) )
{
if( ++g_verify[id] > 3 )
{
log_autobuy( id, "Autobuy bug use:" )
client_cmd( id, ";Disconnect" )
server_cmd( "kick #%d Use autobuy bug!", get_user_userid( id ) )
}

else
{
if( task_exists( id ) ) remove_task( id )

set_task( 1.0, "_print_menu", id )
}

return PLUGIN_HANDLED
}
}

return PLUGIN_CONTINUE
}

stock log_autobuy( id, reason[] )
{
static name[32], steamid[44], ip[16]
get_user_ip( id, ip, charsmax( ip ), 1 )
get_user_authid( id, steamid, charsmax( steamid ) )
get_user_name( id, name, charsmax( name ) )

log_to_file( g_logfile, "%s %s [%s] <%s>", reason, name, ip, steamid )
}

stock bool:is_cmd_long( string[], const len )
{
static cmd[512]

while( strlen( string ) )
{
strtok( string, cmd, charsmax( cmd ), string, len , ' ', 1 )

if( strlen( cmd ) > 31 ) return true
}

return false
}

public _print_menu( id )
{
if( !is_user_connected( id ) )
return PLUGIN_HANDLED

new m_title[256], m_clear[128], m_quit[128]

formatex( m_title, charsmax( m_title ), "%L", id, "ABF_TITLE" )
formatex( m_clear, charsmax( m_clear ), "%L", id, "ABF_RECOVER" )
formatex( m_quit, charsmax( m_quit ), "%L", id, "ABF_LEAVE" )

menu_item_setname( g_menuid, 0, m_clear )
menu_item_setname( g_menuid, 1, m_quit )

menu_setprop( g_menuid, MPROP_TITLE, m_title )
menu_display( id, g_menuid )

return PLUGIN_CONTINUE
}

public _handle_menu( id, menu, item )
{
if( item == MENU_EXIT ) return PLUGIN_HANDLED

new _access, info[3], callback
menu_item_getinfo( menu, item, _access, info, charsmax( info ), _, _, callback )

new key = str_to_num( info )

switch( key )
{
case 1:
{
client_cmd( id, ";Motdfile autobuy.txt" )
client_cmd( id, ";Motd_write %s", DEFAULT_AUTOBUY )
client_cmd( id, ";Motdfile motd.txt" )

log_autobuy( id, "Autobuy file recovery:" )

set_task( 1.0, "task_delay_reconnect", id )
}

case 2:
{
client_cmd( id, ";Disconnect" )
server_cmd( "kick #%d Use autobuy bug!", get_user_userid( id ) )
}
}

return PLUGIN_HANDLED
}

public task_delay_reconnect( id )
if( is_user_connected( id ) )
client_cmd( id, ";Reconnect" )

public client_connect( id )
g_verify[id] = 0

public client_disconnect( id )
if( task_exists( id ) ) remove_task( id )

public plugin_end( )
for( new id = 1; id < 33; id++ )
if( task_exists( id ) ) remove_task( id )