Модели игроков подпрыгивают вверх

#include <amxmodx>
#include <fakemeta>

#define PLUGIN "Anti-Record Demo Bug"
#define VERSION "1.0"
#define AUTHOR "DJ_WEST"

#define MAXPLAYERS 32

new bool:g_Fullupdate[MAXPLAYERS+1]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_forward(FM_AddToFullPack, "Add_To_Full_Pack", 1)
    register_clcmd("fullupdate", "Fullupdate")
}

public Fullupdate(id)
{
    g_Fullupdate[id] = true
    set_task(0.1, "ResetFullupdate", id)
}

public ResetFullupdate(id)
    g_Fullupdate[id] = false

public Add_To_Full_Pack(es, e, ent, host, hostflags, player, pSet)
{
    if (host == ent)
        return FMRES_IGNORED
        
    if (!(1 <= host <= MAXPLAYERS))
        return FMRES_IGNORED
        
    if (!(1 <= ent <= MAXPLAYERS))
        return FMRES_IGNORED
        
    if (!g_Fullupdate[host])
        return FMRES_IGNORED
        
    if (!is_user_alive(host))
        return FMRES_IGNORED
    
    static Float:f_Origin[3]
    
    pev(ent, pev_origin, f_Origin)
    f_Origin[2] += 0.1
    set_es(es, ES_Origin, f_Origin)
    
    return FMRES_IGNORED
}

#include < amxmodx >
#include < fakemeta >

enum {
   Disable = 0,
   Enable
};

new g_iFwdAddToFullPack, g_iFullUpdaters, bool:g_bFullUpdate[ 33 ];

public plugin_init( ) {
   register_plugin( "Anti-Record Demo Bug", "1.0", "DJ_WEST / xPaw" );
  
   register_clcmd( "fullupdate", "CmdFullUpdate" );
}

public CmdFullUpdate( const id ) {
   g_bFullUpdate[ id ] = true;
  
   CheckForward( Enable );
  
   set_task( 0.1, "CheckForward", Disable );
}

// С таском не самая лучшая идея..
// Надо просто прогнать разок через всех игроков, и дисейбл фвд. Но как без извращения.. ? :)

public FwdAddToFullPack( const iEsHandle, const e, const iEntity, const iHost, iHostFlags, bPlayer, pSet ) {
   if( bPlayer && iHost != iEntity && g_bFullUpdate[ iHost ] ) {
      new Float:vOrigin[ 3 ];
      get_es( iEsHandle, ES_Origin, vOrigin );
      
      vOrigin[ 2 ] += 0.01;
      
      set_es( iEsHandle, ES_Origin, vOrigin );
   }
}

CheckForward( const iState ) {
   switch( iState ) {
      case Disable: {
         if( --g_iFullUpdaters == 0 ) {
            unregister_forward( FM_AddToFullPack, g_iFwdAddToFullPack, 1 );
            
            g_iFwdAddToFullPack = 0;
         }
      }
      case Enable: {
         ++g_iFullUpdaters;
        
         if( !g_iFwdAddToFullPack )
            g_iFwdAddToFullPack = register_forward( FM_AddToFullPack, "FwdAddToFullPack", 1 );
      }
   }
}