VoteBan проблема

#include <amxmodx>
#include <amxmisc>

#define MAX_players 32
#define MAX_menudata 1024

new ga_PlayerName[MAX_players][32]
new ga_PlayerAuthID[MAX_players][35]
new ga_PlayerID[MAX_players]
new ga_PlayerIP[MAX_players][16]
new ga_MenuData[MAX_menudata]
new ga_Choice[2]
new gi_VoteStarter
new gi_MenuPosition
new gi_Sellection
new gi_TotalPlayers
new gi_SysTimeOffset = 0
new i
//pcvars
new gi_LastTime
new gi_DelayTime
new gi_DelayTimeVip
new gf_Ratio
new gf_MinVoters
new gi_BanTime
new gi_Disable
new gi_BanType


public plugin_init()
{
  register_plugin("VoteBan","0.1","*****")
  register_clcmd( "say /voteban", "SayIt" )
  register_clcmd( "voteban", "SayIt" )
  register_menucmd(register_menuid("ChoosePlayer"), 1023, "ChooseMenu")
  register_menucmd(register_menuid("VoteMenu"), 1023, "CountVotes")

  gi_LastTime=register_cvar("vipvote_VoteBan_lasttime","1")
  gi_DelayTime=register_cvar("vipvote_VoteBan_delaytime","210")
  gi_DelayTimeVip=register_cvar("vipvote_VoteBan_delaytime", "30")
  gf_Ratio=register_cvar("vipvote_VoteBan_ratio","0.65")
  gf_MinVoters=register_cvar("vipvote_VoteBan_minvoters","0.0")
  gi_BanTime=register_cvar("vipvote_VoteBan_bantime","30")
  gi_Disable=register_cvar("vipvote_VoteBan_disable","0")
  gi_BanType=register_cvar("vipvote_VoteBan_type","2")
}

public SayIt(id)
{
  if(get_pcvar_num(gi_Disable))
  {
    client_print(id,print_chat,"[HNS] VoteBan выключен.")
    return 0
  }

  new Elapsed=get_systime(gi_SysTimeOffset) - get_pcvar_num(gi_LastTime)
  new Delay=get_pcvar_num(gi_DelayTime)
  new DelayVip=get_pcvar_num(gi_DelayTimeVip)

  if( Delay > Elapsed && !(get_user_flags(id) & ADMIN_LEVEL_H) )
  {
    new seconds = Delay - Elapsed
    client_print(id,print_chat,"[HNS] жди еще %d секунд(ы) до нового голосвания.", seconds)
    return 0
  }
  
  if ( DelayVip > Elapsed && (get_user_flags(id) & ADMIN_LEVEL_H) )
  {
    new secondsVIP = DelayVip - Elapsed
    client_print(id,print_chat,"[HNS-VIP] жди еще %d секунд(ы) до нового голосвания.", secondsVIP)
    return 0
  }

  get_players( ga_PlayerID, gi_TotalPlayers )
  for(i=0; i<gi_TotalPlayers; i++)
  {
    new TempID = ga_PlayerID[i]
    if(get_user_flags(TempID) & ADMIN_LEVEL_G)
    {
        client_print(id,print_chat,"На сервере админ, VoteBan меню отключено!")
        return 0
    }

    if(TempID == id)
      gi_VoteStarter=i

    get_user_name( TempID, ga_PlayerName[i], 31 )
    get_user_authid( TempID, ga_PlayerAuthID[i], 34 )
    get_user_ip( TempID, ga_PlayerIP[i], 15, 1 )
  }

  gi_MenuPosition = 0
  ShowPlayerMenu(id)
  return 0
}

public ShowPlayerMenu(id)
{
  new arrayloc = 0
  new keys = (1<<9)

  arrayloc = format(ga_MenuData,(MAX_menudata-1),"Меню бана ^n")
  for(i=0; i<8; i++)
   if( gi_TotalPlayers>(gi_MenuPosition+i) )
   {
     arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"%d. %s^n", i+1, ga_PlayerName[gi_MenuPosition+i])
     keys |= (1<<i)
   }
  if( gi_TotalPlayers>(gi_MenuPosition+8) )
  {
    arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"^n9. Дальше")
    keys |= (1<<8)
  }
  arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"^n0. Назад/Выйти")

  show_menu(id, keys, ga_MenuData, 20, "ChoosePlayer")
  return PLUGIN_HANDLED
}

public ChooseMenu(id, key)
{
  switch(key)
  {
    case 8:
    {
      gi_MenuPosition=gi_MenuPosition+8
      ShowPlayerMenu(id)
    }
    case 9:
    {
      if(gi_MenuPosition>=8)
      {
        gi_MenuPosition=gi_MenuPosition-8
        ShowPlayerMenu(id)
      }
      else
        return 0
    }
    default:
    {
      gi_Sellection=gi_MenuPosition+key
      new Now=get_systime(gi_SysTimeOffset)
      set_pcvar_num(gi_LastTime, Now)

      run_vote()
      return 0
    }
  }
  return PLUGIN_HANDLED
}

public run_vote()
{
  log_amx("Vote ban started by %s for %s %s", ga_PlayerName[gi_VoteStarter], ga_PlayerName[gi_Sellection], ga_PlayerAuthID[gi_Sellection])
  format(ga_MenuData,(MAX_menudata-1),"Забанить %s на %d минут?^n1. Да^n2. Нет",ga_PlayerName[gi_Sellection], get_pcvar_num(gi_BanTime))
  ga_Choice[0] = 0
  ga_Choice[1] = 0
  show_menu( 0, (1<<0)|(1<<1), ga_MenuData, 15, "VoteMenu" )
  set_task(15.0,"outcom")
  return 0
}

public CountVotes(id, key)
{
  ++ga_Choice[key]
  return PLUGIN_HANDLED
}

public outcom()
{
  new TotalVotes = ga_Choice[0] + ga_Choice[1]
  new Float:result = (float(ga_Choice[0]) / float(TotalVotes))

  if( get_pcvar_float(gf_MinVoters) >= ( float(TotalVotes) / float(gi_TotalPlayers) ) )
  {
    client_print(0,print_chat,"[HNS] Недостаточно проголосовавших для бана %s!", ga_PlayerName[gi_Sellection])
    return 0
  }
  else
  {
    if( result >= get_pcvar_float(gf_Ratio) )
    {
      client_print(0,print_chat,"[HNS] Голосование успешное, %s забанен на %d минут", ga_PlayerName[gi_Sellection], get_pcvar_num(gi_BanTime))
      log_amx("[HNS] Голосование успешное, %s забанен на %d минут", ga_PlayerAuthID[gi_Sellection], get_pcvar_num(gi_BanTime))
      ActualBan(gi_Sellection)
    }
    else
    {
      client_print(0,print_chat,"[HNS] Голосование не удалось. Игрок не забанен!")
      log_amx("[HNS] Голосование не удалось. Игрок не забанен!")
    }
  }
  client_print(0,print_chat,"Из %d игроков, %d проголосовали за.", gi_TotalPlayers, ga_Choice[0])

  return 0
}

public ActualBan(Selected)
{
  new Type = get_pcvar_num(gi_BanType)
  switch(Type)
  {
    case 1:
      server_cmd("addip %d %s", get_pcvar_num(gi_BanTime), ga_PlayerIP[Selected])
    case 2:
      server_cmd("amx_ban %d %s VoteBan", get_pcvar_num(gi_BanTime), ga_PlayerAuthID[Selected])
    default:
      server_cmd("banid %d %s kick", get_pcvar_num(gi_BanTime), ga_PlayerAuthID[Selected])
  }
  return 0
}