Насчет "HE" гранаты

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

new const PLUGIN_NAME[ ] = "[HE] Grenade Effect";
new const PLUGIN_VERSION[ ] = "0.0.0.1";
new const PLUGIN_AUTHOR[ ] = "Bos93";

#define IsPlayer(%0) ( 1 <= %0 <= g_iMaxClients && is_user_alive( %0 ) )

const DMG_NADE = ( 1 << 24 );
const UNIT_SECOND = ( 1 << 12 );
const FFADE_IN = 0x0000;

new const GRENADE_SOUND[ ] = "weapons/explode.wav";
const Float:GRENADE_KNOCK = 300.0;

new    g_iMaxClients,
    g_iMSG_ScreenFade;

public plugin_precache( )
{
    precache_sound( GRENADE_SOUND );
}

public plugin_init( )
{
    register_plugin
    (
        PLUGIN_NAME,
        PLUGIN_VERSION,
        PLUGIN_AUTHOR
    );

    RegisterHam( Ham_TakeDamage, "player", "CBasePlayer__TakeDamage_Post", .Post = true );

    g_iMaxClients = get_maxplayers( );
    g_iMSG_ScreenFade = get_user_msgid( "ScreenFade" );
}

public CBasePlayer__TakeDamage_Post( pevVictim, pevInflictor, pevAttacker, Float:flDamage, iDmgBits )
{
    if( !IsPlayer( pevAttacker ) )
    {
        return HAM_IGNORED;
    }
    
    if( !is_user_alive( pevAttacker )  )
    {
        return HAM_IGNORED;
    }

    if ( iDmgBits & DMG_NADE )
    {
        static Float:vecSrc[ 3 ];

        vecSrc[ 0 ] =  GRENADE_KNOCK / 2;
        vecSrc[ 1 ] =  GRENADE_KNOCK / 2;
        vecSrc[ 2 ] =  GRENADE_KNOCK * 2;

        UTIL_MakeKnockback( pevVictim, vecSrc, GRENADE_KNOCK );
        UTIL_SendScreenFade( pevVictim, UNIT_SECOND, UNIT_SECOND, FFADE_IN, 204, 6, 5, 75 );

        emit_sound ( pevVictim, CHAN_WEAPON, GRENADE_SOUND , VOL_NORM, ATTN_NORM, 0, PITCH_NORM );
    }

    return HAM_IGNORED;
}

UTIL_SendScreenFade( pPlayer, sDuration = 0, sHoldTime = 0, sFlags = 0, r = 0, g = 0, b = 0, a = 0 )
{
    message_begin( MSG_ONE_UNRELIABLE, g_iMSG_ScreenFade, .player = pPlayer );
    write_short( sDuration );
    write_short( sHoldTime );
    write_short( sFlags );
    write_byte( r );
    write_byte( g );
    write_byte( b );
    write_byte( a );
    message_end( );
}

UTIL_MakeKnockback( pevVictim, Float:vecSrc[ 3 ], Float:flSpeed )
{
    if( flSpeed == 0.0 )
    {
        return;
    }

    static Float:vecVelocity[ 3 ], Float:vecEntOrigin[ 3 ], Float:flDist, Float:flTime;
    pev( pevVictim, pev_origin, vecEntOrigin );
    flDist = get_distance_f( vecEntOrigin, vecSrc );
    flTime = flDist / flSpeed;
    
    vecVelocity[ 0 ] = ( ( vecSrc[ 0 ] - vecEntOrigin[ 0 ] ) / flTime ) * 1.5;
    vecVelocity[ 1 ] = ( ( vecSrc[ 1 ] - vecEntOrigin[ 1 ] ) / flTime ) * 1.5;
    vecVelocity[ 2 ] = ( vecSrc[ 2 ] - vecEntOrigin[ 2 ] ) / flTime;

    set_pev( pevVictim, pev_velocity, vecVelocity );
}