Плагин Доминирование

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>
#include <xs>
#include <engine>
#include <WPMGPrintChatColor>

#define PLUGIN "Dominations"
#define VERSION "0.6"
#define AUTHOR "Psycrow"

#define sound_domination    "next21_dominations/tf_domination.wav"
#define sound_revenge         "next21_dominations/tf_revenge.wav"
#define sound_freeze_cam     "next21_dominations/freeze_cam.wav"

new dm_frags[33][33]            // Кол-во убийств для доминирования [игрок][жертва]
new dm_dominations_now[33]         // Кол-во доминирований на данный момент у игрока
new bool:dm_domination[33][33]         // Флаг доминирования [игрок][жертва]


public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    RegisterHam(Ham_Killed,"player","Dominations")
    register_cvar("cv_dominations_frags","3")
    register_cvar("cv_dominations_sounds","1")
    register_cvar("cv_dominations_total","1")
    
    if(get_timeleft() < 99999999 && get_cvar_num("cv_dominations_total"))
        set_task(180.0, "check_timeleft")
}

public plugin_precache()
{        
    precache_sound(sound_domination)
    precache_sound(sound_revenge)
    precache_sound(sound_freeze_cam)
}

public client_connect(id)
{    
    for(new i=0; i < 33; i++)
    {
        dm_frags[id][i] = 0
        dm_frags[i][id] = 0
        dm_domination[id][i] = false
        dm_domination[i][id] = false
    }
    
    dm_dominations_now[id] = 0
}

public client_disconnect(id)
{
    new playersnames[33][32], count
    for(new i=0; i < 33; i++)
        if(dm_frags[i][id] >= get_cvar_num("cv_dominations_frags"))
            get_user_name(i, playersnames[count++], 31)
    
    if(count == 0)
        return PLUGIN_CONTINUE
    
    new victimname[32], message[256], len
    get_user_name(id, victimname, 31)
    
    if(count == 1)
        PrintChatColor(0,PRINT_COLOR_RED,"!g[%s] !tР?РіСЂРѕРє !g%s !tпокадает сервер, РЅРµ отомстив своему палачу !g%s", PLUGIN, victimname, playersnames[0])
    else
    {
        PrintChatColor(0,PRINT_COLOR_RED,"!g[%s] !tР?РіСЂРѕРє !g%s !tпокадает сервер, РЅРµ отомстив СЃРІРѕРёРј палачам:", PLUGIN, victimname)
        for(new x = 0; x < count; x++)
        {
            len += format(message[len], 255-len, "!g%s!t%s ", playersnames[x], x < (count-1) ? ", ":"")
            if(len > 96 )
                break
        }
        PrintChatColor(0,PRINT_COLOR_RED,"%s", message)
    }
    
    return PLUGIN_CONTINUE
}

public Dominations(victim, attacker)
{
    if(!is_user_connected(attacker) || !is_user_connected(victim))
        return HAM_IGNORED
    
    if(cs_get_user_team(attacker) == cs_get_user_team(victim))
        return HAM_IGNORED
    
    dm_frags[attacker][victim] += 1
    dm_frags[victim][attacker] = 0
    
    if(dm_frags[attacker][victim] == get_cvar_num("cv_dominations_frags"))
    {
        dm_domination[attacker][victim] = true
        dm_dominations_now[attacker]++
        new player_name_v[33], player_name_a[33]
        get_user_name(victim, player_name_v, 31)
        get_user_name(attacker, player_name_a, 31)
        PrintChatColor(0,PRINT_COLOR_RED,"!g[%s] !tР?РіСЂРѕРє !g%s !tтеперь доминирует над РёРіСЂРѕРєРѕРј !g%s", PLUGIN ,player_name_a, player_name_v) // Объявляем всем, что началось доминирование между игроками
        if(get_cvar_num("cv_dominations_sounds"))
            emit_sound(attacker,CHAN_AUTO,sound_domination,1.0, 1.0, 0, 100 )
    }
    
    if(dm_frags[attacker][victim] > get_cvar_num("cv_dominations_frags"))
    {
        new player_name_v[33], player_name_a[33]
        get_user_name(victim, player_name_v, 31)
        get_user_name(attacker, player_name_a, 31)
        PrintChatColor(attacker,PRINT_COLOR_RED,"!g[%s] !tР’С‹ СЃРЅРѕРІР° убили СЃРІРѕСЋ жертву !g%s", PLUGIN ,player_name_v) // Объявляем убийце, что жертва являеться его жертвой доминирования
        PrintChatColor(victim,PRINT_COLOR_RED,"!g[%s] !tВас СЃРЅРѕРІР° СѓР±РёР» ваш палач !g%s", PLUGIN ,player_name_a)  // Объявляем жертве доминирования, что убийца являеться его палачом
        if(get_cvar_num("cv_dominations_sounds"))
            client_cmd(victim, "spk %s", sound_freeze_cam)
    }
    
    if(dm_frags[victim][attacker] == 0 && dm_domination[victim][attacker])
    {
        dm_domination[victim][attacker] = false
        if(dm_dominations_now[victim] != 0)
            dm_dominations_now[victim]--
        new player_name_v[33], player_name_a[33]
        get_user_name(victim, player_name_v, 31)
        get_user_name(attacker, player_name_a, 31)
        PrintChatColor(0,PRINT_COLOR_RED,"!g[%s] !tР?РіСЂРѕРє !g%s !tотомстил своему обидчику !g%s", PLUGIN, player_name_a, player_name_v)  // Объявляем, что жертва смогла отомстить
        if(get_cvar_num("cv_dominations_sounds"))
            emit_sound(attacker,CHAN_AUTO,sound_revenge,1.0, 1.0, 0, 100 )
    }
    
    return HAM_IGNORED
}

public check_timeleft()
{
    new time_string[12]
    format(time_string, 11, "%d.0",get_timeleft())
    set_task(str_to_float(time_string), "Dominations_total")
}

public Dominations_total(id)
{
    new dm_max, player_name[33]
    for (new i = 0; i < 33; i++ )
    {
        if(dm_dominations_now[i] > dm_max)
        {
            dm_max = dm_dominations_now[i]
            get_user_name(i, player_name, 31)
        }
    }
    
    if(dm_max > 2)
        PrintChatColor(id,PRINT_COLOR_RED,"!g[%s] !tР?РіСЂРѕРє !g%s !tсохранил !g%d !tдоминирований", PLUGIN, player_name, dm_max)
}