Team Flash Punisher

#include <amxmodx>
#include <fakemeta>

#define TEMPENTITY    "23"
#define BLINDED_FULLY    255
#define BLINDED_PARTLY    200

new const TFSVERSION[] = "1.1"
new Float:FLASH_TIMER = 1.52    // Time from throwing a FB to the bang (1.52 seconds?)
new g_flasher = 0         // id of the flasher


public plugin_init() {
    register_plugin("Team Flash Snitch",TFSVERSION,"Tender")
    
    register_cvar("tfs_sound","1")
    register_cvar("tfs_adminchat","1")
    
    register_event("ScreenFade", "event_blinded", "be", "4=255", "5=255", "6=255", "7>199")
    register_event(TEMPENTITY, "event_flashsmokepuff", "a", "1=5", "6=25", "7=6")
    register_forward(FM_SetModel, "forward_setmodel")
}

public plugin_precache() {
    precache_sound ("radio/blind1.wav")
    return PLUGIN_CONTINUE
}



public event_blinded(const ID) { // someone got flashed
    
    new alpha = read_data(7)
    if (alpha != BLINDED_FULLY && alpha != BLINDED_PARTLY || !is_user_alive(ID))
        return PLUGIN_CONTINUE
    if(get_user_team(ID) == get_user_team(g_flasher) && ID != g_flasher){
        new message1[128], message2[128]
        new flasher[32], name[32]
        get_user_name(g_flasher, flasher, 31)
        get_user_name(ID, name, 31)
        format(message1, 127, "^x04[Флеш контроль]^x01 Вы были ослеплены - %s", flasher)    
        format(message2, 127, "^x04[Флеш контроль]^x01 Вы %sослепили - %s", alpha == BLINDED_FULLY ? "totally " : "", name)
        colored_msg(ID,message1)
        colored_msg(g_flasher,message2)
        if(get_cvar_num("tfs_sound")>0) client_cmd(g_flasher,"spk sound/radio/blind1.wav")
        if(alpha == BLINDED_FULLY && get_cvar_num("tfs_adminchat")) server_cmd("amx_chat %s flashed a teammate (%s)",flasher,name)
    }
    return PLUGIN_CONTINUE
}


public colored_msg(id,msg[]) {
    message_begin(MSG_ONE, get_user_msgid("SayText"), {0,0,0}, id)
    write_byte(id)
    write_string(msg)
    message_end()
}

public event_flashsmokepuff() { // a flash has banged

    set_task(0.05,"reset_flasher") // wait until all is announced
    return PLUGIN_CONTINUE
}

public reset_flasher(){
    g_flasher = 0    // clear g_flasher
}


public get_flasher(id){ // a flash is about to bang
    g_flasher = (id - 524627)
}


public forward_setmodel(const ENTITY, model[]) { // a flash is thrown
    
    if (!equal(model, "models/w_flashbang.mdl"))
        return FMRES_IGNORED

    new owner = pev(ENTITY, pev_owner)
    if (owner == 0)
        return FMRES_IGNORED

    set_task(FLASH_TIMER,"get_flasher", 524627+owner)
  
    return FMRES_IGNORED
}


/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1053\\ f0\\ fs16 \n\\ par }
*/