NonSteam Voice Mute

#include <amxmodx>
#include <fakemeta>

#define PLUGIN 	"GameUpdates Voice Mute"
#define VERSION "1.0"
#define AUTHOR 	"Fintok!"

#define MAX_PLAYERS	32
#define TASK_CHECKCVAR	100

new bool:g_mute[MAX_PLAYERS + 1]

new g_SyncMsg
new cvar_type_mutemsg, cvar_repeat_msg, cvar_time_repeat_msg

new const info_mutemsg[] = { "Только не обновленные игроки могут общаться с помощью голосового чата!" }

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_cvar("guvm_version", VERSION, FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_SPONLY)

	cvar_type_mutemsg = register_cvar("guvm_type_msg", "1")
	cvar_repeat_msg = register_cvar("guvm_repeat_msg", "1")
	cvar_time_repeat_msg = register_cvar("guvm_time_repeat_msg", "5")

	register_forward(FM_Voice_SetClientListening, "fwd_voice_setclientlistening")
	
	g_SyncMsg = CreateHudSyncObj()
}

public client_putinserver(id)
{
	if(!is_user_hltv(id) && !is_user_bot(id))
	{
		set_task(1.0, "check_cvar", id + TASK_CHECKCVAR, _, _, "b")
	}	
}

public check_cvar(id)
{
	id -= TASK_CHECKCVAR
	
	query_client_cvar(id, "cl_filterstuffcmd", "check_results")
}

public check_results(id, cvar[], result[])
{
	remove_task(id + TASK_CHECKCVAR)

	if(!equal(result, "Bad CVAR request"))
	{
		set_task(10.0, "task_mutemsg", id)

		g_mute[id] = true

		if(get_pcvar_num(cvar_repeat_msg))
		{
			new Float:itime_repeatmsg = get_pcvar_float(cvar_time_repeat_msg)

			set_task(itime_repeatmsg * 60, "task_mutemsg", id, _, _, "b")
		}
	}
}

public task_mutemsg(id)
{
	if(!is_user_connected(id))
		return PLUGIN_HANDLED

	switch(get_pcvar_num(cvar_type_mutemsg))
	{
		case 1:
		{
			set_hudmessage(255, 20, 0, -1.0, 0.20, 2, 0.25, 5.0, 0.08, 0.2, -1)
			ShowSyncHudMsg(id, g_SyncMsg, "%s", info_mutemsg)
		}
		case 2:
		{
			client_print(id, print_chat, "* %s", info_mutemsg)
		}
		case 3:
		{
			client_print(id, print_center, "%s", info_mutemsg)
		}
	}
	return PLUGIN_CONTINUE
}

public client_disconnect(id)
{
	if(task_exists(id))
	{
		remove_task(id)
	}

	if(task_exists(id + TASK_CHECKCVAR))
	{
		remove_task(id + TASK_CHECKCVAR)
	}

	g_mute[id] = false
}

public fwd_voice_setclientlistening(receiver, sender, bool:listen)
{
	if(g_mute[sender] || g_mute[receiver])
	{
		engfunc(EngFunc_SetClientListening, receiver, sender, 0)
		return FMRES_SUPERCEDE
	}
	return FMRES_IGNORED
}