Каким способом лучше отбирать оружие?

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta_util>

#define PLUGIN "Arp - Auto respawn player"
#define VERSION "0.1"
#define AUTHOR "svh0st"

new cvar_enable_arp, cvar_remove_weapons

public plugin_init()
{
    register_plugin("PLUGIN", "VERSION", "AUTHOR")
    
    //Квари:
    cvar_enable_arp = register_cvar("enable_arp", "1")
    cvar_remove_weapons = register_cvar("remove_weapons", "1")
    
    //События:
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn", 1)
    RegisterHam(Ham_Killed, "player", "fw_PlayerKilled", 1)
}

public fw_PlayerSpawn(id)
{
    if(get_pcvar_num(cvar_enable_arp) == 1 && get_pcvar_num(cvar_remove_weapons) == 1 && is_user_connected(id))
        set_task(0.1, "strip_weapon", id)
}

public fw_PlayerKilled(id)
{
    if(get_pcvar_num(cvar_enable_arp) == 1 && is_user_connected(id))
        set_task(2.0, "respawn_player", id)
}

public respawn_player(id)
{
    if(get_user_team(id) == 1 || get_user_team(id) == 2)
    {
        ExecuteHam(Ham_CS_RoundRespawn, id)
    }
}

public strip_weapon(id)
{
    if(get_user_team(id) == 1 || get_user_team(id) == 2)
    {
        if(user_has_weapon(id, CSW_USP))
            fm_strip_user_gun(id, CSW_USP)
        if(user_has_weapon(id, CSW_GLOCK18))
            fm_strip_user_gun(id, CSW_GLOCK18)
        if(user_has_weapon(id, CSW_C4))
            fm_strip_user_gun(id, CSW_C4)
    }
}

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta_util>

#define PLUGIN "Strip user weapon"
#define VERSION "0.1"
#define AUTHOR "svh0st"

public plugin_init()
{
    register_plugin("PLUGIN", "VERSION", "AUTHOR")
    
    //События:
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn", 1)
}

public fw_PlayerSpawn(id)
{
    if(get_user_team(id) == 1 || get_user_team(id) == 2)
        {
            if(user_has_weapon(id, CSW_USP))
                fm_strip_user_gun(id, CSW_USP)
            if(user_has_weapon(id, CSW_GLOCK18))
                fm_strip_user_gun(id, CSW_GLOCK18)
            if(user_has_weapon(id, CSW_C4))
                fm_strip_user_gun(id, CSW_C4)
        }
}

#include < amxmodx >
#include < cstrike >
#include < fakemeta >
#include < hamsandwich >

new g_iMaxClients;
new Float: g_flBlockSpawn;

public plugin_init( )
{    
    register_event("HLTV", "Event__Round_Start", "a", "1=0", "2=0");

    RegisterHam( Ham_Spawn, "player", "CBasePlayer__Spawn_Post", .Post = true );
    RegisterHam( Ham_Killed, "player", "CBasePlayer__Killed_Post", .Post = true );

    g_iMaxClients = get_maxplayers( );
}


public Event__Round_Start( )
{
    new iCell;

    for( iCell = 1; iCell <= g_iMaxClients; iCell++ )
    {
        if( !is_user_connected( iCell ) )
        {
            continue;
        }

        remove_task( iCell );
    }

    g_flBlockSpawn = get_gametime( ) + 15;
}

public CBasePlayer__Spawn_Post( pPlayer )
{
    if( !is_user_alive( pPlayer ) || g_flBlockSpawn >= get_gametime( ) )
    {
        return HAM_IGNORED;
    }

    switch( cs_get_user_team( pPlayer ) )
    {
        case CS_TEAM_T: UTIL_StripWeapon( pPlayer, "weapon_glock18" );
        case CS_TEAM_CT: UTIL_StripWeapon( pPlayer, "weapon_usp" );
    }

    return HAM_IGNORED;
}

public CBasePlayer__Killed_Post( pVictim )
{
    if( g_flBlockSpawn >= get_gametime( ) )
    {
        return HAM_IGNORED;
    }

    set_task( 5.0, "Ctask__Spawn", pVictim );

    return HAM_IGNORED;
}

public Ctask__Spawn( pVictim )
{
    ExecuteHam( Ham_CS_RoundRespawn, pVictim );
}

UTIL_StripWeapon( pPlayer, sWeapon[ ] )
{
    if( !equal( sWeapon,"weapon_", 7 ) )
    {
        return 0;
    }

    new pWeapon = get_weaponid( sWeapon );

    if( !pWeapon )
    {
        return 0;
    }

    new pEntity;

    while( ( pEntity = engfunc( EngFunc_FindEntityByString, pEntity, "classname", sWeapon ) ) && pev( pEntity, pev_owner ) != pPlayer ) { }

    if( !pEntity )
    {
        return 0;
    }

    if( get_user_weapon( pPlayer ) == pWeapon )
    {
        ExecuteHamB( Ham_Weapon_RetireWeapon, pEntity );
    }

    if( !ExecuteHamB( Ham_RemovePlayerItem, pPlayer, pEntity ) )
    {
        return 0;
    }

    ExecuteHamB( Ham_Item_Kill, pEntity );

    set_pev( pPlayer, pev_weapons,pev( pPlayer, pev_weapons ) & ~(1<<pWeapon ) );

    return 1;
}