Sign's Wallhack Blocker

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

#define MAX_CACHE	10

new alive[33], team[33], tr_handle

new Float:offset[][] =
{
	{-17.0, -8.5, -8.5,-17.0},
	{ 17.0,  8.5,  8.5, 17.0}
}

new Float:points[][] =
{
	{-34.0,-17.0, 17.0, 34.0},
	{-17.0, -8.5, 17.0, 34.0}
}

public plugin_init()
{
	register_plugin("WH Blocker", "1.1", "Sign")

	register_forward(FM_AddToFullPack, "fw_addtofullpack")

	RegisterHam(Ham_Spawn, "player", "fw_alivehandle", 1)
	RegisterHam(Ham_Killed, "player", "fw_alivehandle", 1)

	tr_handle = create_tr2()
}

public fw_addtofullpack(es, e, ent, id, flags, player, set)
{
	if(player && id != ent && alive[id] && alive[ent] && team[id] != team[ent])
	{
		if(!is_entity_visible(id, ent, set))
		{
			forward_return(FMV_CELL, 0)

			return FMRES_SUPERCEDE
		}
	}

	return FMRES_IGNORED
}

public fw_alivehandle(id)
{
	alive[id] = is_user_alive(id)
	team[id] = get_user_team(id)
}

public is_entity_visible(id, entity, set)
{
	static Float:p_origin[3], Float:e_origin[3], Float:v_offset[3], Float:v_temp[3], calls[33][33], cache[33][33], crouch, i, j

	if(++calls[id][entity] % MAX_CACHE && cache[id][entity])
	{
		return 1
	}

	if(!is_entity_in_pvs(entity, set) || is_user_flashed(id))
	{
		return cache[id][entity] = 0
	}

	pev(id, pev_origin, p_origin)
	pev(id, pev_view_ofs, v_temp)
	xs_vec_add(p_origin, v_temp, p_origin)

	pev(entity, pev_origin, e_origin)
	pev(entity, pev_view_ofs, v_temp)
	xs_vec_add(e_origin, v_temp, v_temp)

	if(is_point_visible(p_origin, v_temp, id))
	{
		return cache[id][entity] = 1
	}

	xs_vec_sub(e_origin, p_origin, v_temp)
	xs_vec_normalize(v_temp, v_temp)

	vector_to_angle(v_temp, v_temp)
	angle_vector(v_temp, ANGLEVECTOR_RIGHT, v_offset)

	crouch = !!(pev(entity, pev_button) & IN_DUCK)

	for(i = 0; i < 2; i++)
	{
		for(j = 0; j < 4; j++)
		{
			xs_vec_mul_scalar(v_offset, offset[i][j], v_temp)
			xs_vec_add(e_origin, v_temp, v_temp)

			v_temp[2] += points[crouch][j]

			if(is_point_visible(p_origin, v_temp, id))
			{
				return cache[id][entity] = 1
			}
		}
	}

	return cache[id][entity] = 0
}

public is_point_visible(Float:start[3], Float:point[3], ignore_ent)
{
	static Float:fraction

	engfunc(EngFunc_TraceLine, start, point, IGNORE_GLASS | IGNORE_MONSTERS, ignore_ent, tr_handle)
	get_tr2(tr_handle, TR_flFraction, fraction)

	return fraction == 1.0
}

public is_entity_in_pvs(entity, set)
{
	return engfunc(EngFunc_CheckVisibility, entity, set)
}

public is_user_flashed(id)
{
	return get_pdata_int(id, 518) > 200 && get_gametime() < get_pdata_float(id, 514)
}

public plugin_end()
{
	free_tr2(tr_handle)
}