Борьба с авторестартом сервера на MyArena

#include <amxmodx>
#include <dhudmessage>

#define PLUGIN "ShutdownServer"
#define VERSION "1.0"
#define AUTHOR "S0m3Th1nG_AwFul!"

#define TIMER_TASK		123456
#define RESTART_TASK	  789123

new g_counter
new g_autorestart
new g_autocds

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_concmd("amx_shutdown","RestartTask",ADMIN_RCON," - server shutdown") //команда для планировщика заданий или админов с ADMIN_RCON флагом
	g_autocds = register_cvar("amx_rs_countdown","1") //звук обратного отсчёта (за 10 сек до конца)
	g_autorestart = register_cvar("amx_rs_time","30") //длительность обратного отсчёта
}

stock ClearDHUDMessages(id, iClear = 8)
		for (new iDHUD = 0; iDHUD < iClear; iDHUD++)
				show_dhudmessage(id, "");

public RestartTask(id) 
{
	if (!(get_user_flags(id) & ADMIN_RCON))
		return PLUGIN_HANDLED
	
	client_cmd(0, "spk ambience/doorbell")
	server_cmd("amxx pause deagsmapmanager2")
	server_cmd("amxx pause admincmd")
	server_cmd("amxx pause adminvote")
	server_cmd("amxx pause mapsmenu") //отключение плагинов, которые могут помешать шатдауну
	server_cmd("mp_timelimit 0")
	
	set_task(1.0,"TimeCounter",TIMER_TASK,_,_,"a",get_pcvar_num(g_autorestart))
	set_task(get_pcvar_float(g_autorestart),"QuitServer",RESTART_TASK)
	
	return PLUGIN_CONTINUE
}

public TimeCounter() 
{
	server_cmd("mp_timelimit 0")
	g_counter++
	new Float:iRestartTime = get_pcvar_float(g_autorestart) - g_counter
	new Float:fSec
	fSec = iRestartTime 
	
	ClearDHUDMessages(0)
	set_dhudmessage(255, 25, 25, -1.0, 0.25, 0, 1.0, 1.0, 0.0, 0.0, false)
	show_dhudmessage(0, "Внимание! Сервер будет полностью перезагружен через %d секунд!", floatround(fSec))
	set_dhudmessage(25, 255, 25, -1.0, 0.25, 0, 1.0, 1.0, 0.0, 0.0, false)
	show_dhudmessage(0, "^nПожалуйста, оставайтесь на линии!;)")
	
	if(get_pcvar_num(g_autocds) && get_pcvar_num(g_autorestart) - g_counter < 11 && get_pcvar_num(g_autorestart) - g_counter !=0)
	{
		static szNum[32]
		num_to_word(get_pcvar_num(g_autorestart) - g_counter, szNum, 31)
		client_cmd(0,"speak ^"fvox/%s^"", szNum)
	}
}

public QuitServer() 
	server_cmd("quit")