Скрыть живых ботов

#include <amxmodx>
#include <fakemeta>
#include <cstrike>
#include <hamsandwich>


#define PLUGIN "Fake TeamBot"
#define VERSION "1.3"
#define AUTHOR "OneEyed & Sebul"

#define TASK_BOT 4325

new botteam[2];
new HamHook:bothandle;

new const botnames[2][] = {
    "BOT Terrorist",            //Change Terrorist Bot Name
    "BOT Counter-Terrorist"        //Change CT Bot name
}

new g_MaxPlayers;
new cvar_min_player;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);

    register_event("TextMsg", "RozpocznijGre", "a", "2&#Game_C");

    cvar_min_player = register_cvar("dm_fakebot_min_player", "8");

    g_MaxPlayers = get_maxplayers();
}

public RozpocznijGre() {
    if(!task_exists(TASK_BOT)) set_task(8.0, "check_player", TASK_BOT, _, _, "b");
}

public FakeBotSpawn(id) {
    if(!is_user_bot(id))
        return;

    for(new x=0; x<2; ++x) {
        if(id == botteam[x]) {
            set_pev(id, pev_effects, (pev(id, pev_effects) | EF_NODRAW)); //set invisible
            set_pev(id, pev_solid, SOLID_NOT); //Not Solid
            set_pev(id, pev_takedamage, DAMAGE_NO);
            break;
        }
    }
}

public check_player() {
    if(get_playersnum(1) < g_MaxPlayers-1 && get_teamplayersnum() < get_pcvar_num(cvar_min_player)) {
        createBots();
    }
    else {
        for(new x=0; x<2; ++x) {
            if(botteam[x]) {
                server_cmd("kick #%d", get_user_userid(botteam[x]));
                botteam[x] = 0;
            }
        }
        if(bothandle) DisableHamForward(bothandle);
    }
}

createBots() {
    if(bothandle) EnableHamForward(bothandle);
    else bothandle = RegisterHam(Ham_Spawn, "player", "FakeBotSpawn", 1);

    new bot, x;
    for(x=0; x<2; ++x) {
        bot = find_player("bli", botnames[x]);
        if(bot) {
            botteam[x] = bot;
            continue;
        }

        bot = engfunc(EngFunc_CreateFakeClient, botnames[x]);
        if(pev_valid(bot)) {
            botteam[x] = bot;
            /*new ptr[128];
            dllfunc(DLLFunc_ClientConnect, bot, botnames[x], "127.0.0.1", ptr);
            dllfunc(DLLFunc_ClientPutInServer, bot);*/
            dllfunc(MetaFunc_CallGameEntity, "player", bot);
            set_pev(bot, pev_flags, pev(bot, pev_flags) | FL_FAKECLIENT);
            set_pev(bot, pev_frags, 0.0);
            select_model(bot, x+1);
            dllfunc(DLLFunc_Spawn, bot);
            dllfunc(DLLFunc_Think, bot);
        }
    }
}

select_model(id, team) {
    switch(team) {
        case 1: cs_set_user_team(id, CS_TEAM_T, CS_T_TERROR);
        case 2: cs_set_user_team(id, CS_TEAM_CT, CS_CT_URBAN);
    }
}

stock get_teamplayersnum() {
    new playerTeam, playerCnt, i;
    for(i=1; i<=g_MaxPlayers; ++i) {
        if(!is_user_connected(i) || is_user_bot(i) || is_user_hltv(i))
            continue;

        playerTeam = _:cs_get_user_team(i);
        if(playerTeam == 1 || playerTeam == 2)
            ++playerCnt;
    }

    return playerCnt;
}

            set_pev(id, pev_effects, (pev(id, pev_effects) | EF_NODRAW)); //set invisible
            set_pev(id, pev_solid, SOLID_NOT); //Not Solid
            set_pev(id, pev_takedamage, DAMAGE_NO);