Spam & Mat Control 0.4 (fix d-s.ru fix winzh1 от 16.03.2014)

#include <amxmodx>
#include <fakemeta>
#include <regex>

#define TIME_GAG_CHAT 120.0            // Длительность блокировки.
#define CHANGE_NAME "Change Name"   // Имя которое будет присваивается игроку.

#pragma semicolon 1

#define MAX_PLAYERS 32
#define MSG_SAY_TEXT 76
#define MSG_SEND_AUDIO 100

#define BIT_VALID(%1,%2) ((%1) & (1 << ((%2) - 1)))
#define BIT_ADD(%1,%2) ((%1) |= (1 << ((%2) - 1)))
#define BIT_SUB(%1,%2) ((%1) &= ~(1 << ((%2) - 1)))
#define BIT_NOT_VALID(%1,%2) (~(%1) & (1 << ((%2) - 1)))

new Array:g_aWhileList, g_iSizeWhileList;
new Array:g_aBlockName, g_iSizeBlockName;
new Array:g_aBlockChat, g_iSizeBlockChat;

new Regex:g_iPattern, iError;
new g_iBitClientAccess, g_iBitClientConnected, g_iWarning[MAX_PLAYERS + 1];

new const __UPPER_CASE[][] = { "А", "Б", "В", "Г", "Д", "Е", "Ё", "Ж", "З", "И", "Й", "К", "Л", "М", "Н", "О", "П", "Р", "С", "Т", "У", "Ф", "Х", "Ц", "Ч", "Ш", "Щ", "Ъ", "Ы", "Ь", "Э", "Ю", "Я" };
new const __LOWER_CASE[][] = { "а", "б", "в", "г", "д", "е", "ё", "ж", "з", "и", "й", "к", "л", "м", "н", "о", "п", "р", "с", "т", "у", "ф", "х", "ц", "ч", "ш", "щ", "ъ", "ы", "ь", "э", "ю", "я" };

new const __CHARS_CASE = sizeof __UPPER_CASE;

new const PREFIX[] = "Chat Control";

public plugin_init()
{
    register_plugin("Chat Control", "0.4", "Freedo.m");
    register_clcmd("say", "HookMessage");
    register_clcmd("say_team", "HookMessage");
    register_forward(FM_ClientUserInfoChanged, "ClientUserInfoChanged_Pre", 0);
    g_aWhileList = ArrayCreate(32);
    g_aBlockName = ArrayCreate(32);
    g_aBlockChat = ArrayCreate(32);
    new szError[32];
    g_iPattern = regex_compile("(?:\w{2,}\.[A-z]{2,4}\b|(?:\d+\W+){3})", iError, szError, charsmax(szError), "i");
    if(g_iPattern != REGEX_OK) log_amx("Regex error: %s (%d)", szError, iError);
}

public plugin_cfg()
{
    new szDirName[64], szFileName[128];
    get_localinfo("amxx_configsdir", szDirName, charsmax(szDirName));
    formatex(szFileName, charsmax(szFileName), "%s/chat_control/while_list.ini", szDirName);
    switch(file_exists(szFileName))
    {
        case 0: log_amx("File ^"%s^" not found", szFileName);
        case 1: ReadFile(szFileName, g_aWhileList);
    }
    formatex(szFileName, charsmax(szFileName), "%s/chat_control/block_name.ini", szDirName);
    switch(file_exists(szFileName))
    {
        case 0: log_amx("File ^"%s^" not found", szFileName);
        case 1: ReadFile(szFileName, g_aBlockName);
    }
    formatex(szFileName, charsmax(szFileName), "%s/chat_control/block_msg.ini", szDirName);
    switch(file_exists(szFileName))
    {
        case 0: log_amx("File ^"%s^" not found", szFileName);
        case 1: ReadFile(szFileName, g_aBlockChat);
    }
    g_iSizeWhileList = ArraySize(g_aWhileList);
    g_iSizeBlockName = ArraySize(g_aBlockName);
    g_iSizeBlockChat = ArraySize(g_aBlockChat);
}

ReadFile(szFileName[], Array:iData)
{
    new szBuffer[32], szFile = fopen(szFileName, "rt");
    while(!feof(szFile))
    {
        fgets(szFile, szBuffer, charsmax(szBuffer));
        trim(szBuffer);
        if(!szBuffer[0] || szBuffer[0] == '/' && szBuffer[1] == '/') continue;
        ArrayPushString(iData, szBuffer);
    }
    fclose(szFile);
}

public client_putinserver(id)
{
    BIT_ADD(g_iBitClientConnected, id);
    set_task(5.0, "client_access_add", id);
}

public client_access_add(id)
    BIT_ADD(g_iBitClientAccess, id);
    
public client_disconnect(id)
{
    g_iWarning[id] = 0;
    BIT_SUB(g_iBitClientAccess, id);
    BIT_SUB(g_iBitClientConnected, id);
    if(task_exists(id)) remove_task(id);
}

public ClientUserInfoChanged_Pre(id, szBuffer)
{
    static szNewName[32], szOldName[32];
    if(BIT_VALID(g_iBitClientConnected, id)) get_user_name(id, szOldName, charsmax(szOldName));
    else szOldName = CHANGE_NAME;
    engfunc(EngFunc_InfoKeyValue, szBuffer, "name", szNewName, charsmax(szNewName));
    if(CheckWhite(szNewName)) return FMRES_IGNORED;
    new iMatch = regex_match_c(szNewName, g_iPattern, iError);
    if(iMatch > 0 || CheckName(szNewName))
    {
        engfunc(EngFunc_SetClientKeyValue, id, szBuffer, "name", szOldName);
        return FMRES_SUPERCEDE;
    }
    return FMRES_IGNORED;
}

bool:CheckName(szBuffer[])
{
    static szBlockLine[32];
    for(new i; i < g_iSizeBlockName; i++)
    {
        ArrayGetString(g_aBlockName, i, szBlockLine, charsmax(szBlockLine));
        if(strfind(utf_strtolower(szBuffer), utf_strtolower(szBlockLine)) != -1) return true;
    }
    return false;
}

public HookMessage(id)
{
    if(BIT_NOT_VALID(g_iBitClientAccess, id))
    {
        PrintChat(id, "!y[!g%s!y] Вам заблокирован чат на !t%i !yсек.", PREFIX, floatround(TIME_GAG_CHAT));
        return PLUGIN_HANDLED;
    }
    static szMessage[192];
    read_args(szMessage, charsmax(szMessage));
    remove_quotes(szMessage);
    strtolower(szMessage);
    if(CheckWhite(szMessage)) return PLUGIN_CONTINUE;
    static iMatch; iMatch = regex_match_c(szMessage, g_iPattern, iError);
    if(iMatch > 0 || CheckMessage(szMessage))
    {
        if(++g_iWarning[id] < 3)
        {
            SendAudio(id, "events/tutor_msg.wav");
            PrintChat(id, "!y[!g%s!y] Сервер предупреждает вас о запрете спама/мата: !t%i!y/!t3", PREFIX, g_iWarning[id]);
        }
        else
        {
            BIT_SUB(g_iBitClientAccess, id);
            SendAudio(id, "events/friend_died.wav");
            PrintChat(id, "!y[!g%s!y] Сервер заблокировал вам чат на !t%i !yсек.", PREFIX, floatround(TIME_GAG_CHAT));
            set_task(TIME_GAG_CHAT, "GagExpired", id);
        }
        return PLUGIN_HANDLED;
    }
    return PLUGIN_CONTINUE;
}

bool:CheckMessage(szBuffer[])
{
    static szBlockLine[32];
    for(new i; i < g_iSizeBlockChat; i++)
    {
        ArrayGetString(g_aBlockChat, i, szBlockLine, charsmax(szBlockLine));
        if(strfind(utf_strtolower(szBuffer), utf_strtolower(szBlockLine)) != -1) return true;
    }
    return false;
}

bool:CheckWhite(szBuffer[])
{
    static szBlockLine[32];
    for(new i; i < g_iSizeWhileList; i++)
    {
        ArrayGetString(g_aWhileList, i, szBlockLine, charsmax(szBlockLine));
        if(contain(szBuffer, szBlockLine) != -1) return true;
    }
    return false;
}

public GagExpired(id)
{
    BIT_ADD(g_iBitClientAccess, id);
    g_iWarning[id] = 0;
    SendAudio(id, "events/task_complete.wav");
    PrintChat(id, "!y[!g%s!y] Чат разблокирован. Мат и спам !tзапрещён!", PREFIX);
}

public plugin_end()
{
    regex_free(g_iPattern);
}

stock SendAudio(id, szDirSound[])
{
    message_begin(MSG_ONE_UNRELIABLE, MSG_SEND_AUDIO, _, id);
    write_byte(id);
    write_string(szDirSound);
    write_short(100);
    message_end();
}

stock PrintChat(const id, const szMessage[], any:...)
{
    if(!is_user_connected(id)) return;
    new szBuffer[190];
    vformat(szBuffer, charsmax(szBuffer), szMessage, 3);
    while(replace(szBuffer, charsmax(szBuffer), "!y", "^1")) {}
    while(replace(szBuffer, charsmax(szBuffer), "!t", "^3")) {}
    while(replace(szBuffer, charsmax(szBuffer), "!g", "^4")) {}
    message_begin(MSG_ONE, MSG_SAY_TEXT, _, id);
    write_byte(id);
    write_string(szBuffer);
    message_end();
}

stock utf_strtolower( const arg[] )
{
    new utf_string[192];
    copy(utf_string, 191, arg);
    
    for(new i; i < __CHARS_CASE; ++i)
    {
        replace_utf_char(utf_string, __UPPER_CASE[i], __LOWER_CASE[i]);
    }
    strtolower(utf_string);
    return(utf_string);
}

stock replace_utf_char(arg[], char_find[], char_replace[])
{
    if(strlen(char_find) != strlen(char_replace)) return;
    new pos, len = strlen(char_replace);
    while((pos = strfind(arg, char_find)) != -1)
    {
        for(new i = pos; i < pos + len; ++i)
        {
            arg[i] = char_replace[i-pos];
        }
    }
    return;
}

/* AMX Mod X
*   Anti Flood Plugin
*
* by the AMX Mod X Development Team
*  originally developed by OLO
*
* This file is part of AMX Mod X.
*
*
*  This program is free software; you can redistribute it and/or modify it
*  under the terms of the GNU General Public License as published by the
*  Free Software Foundation; either version 2 of the License, or (at
*  your option) any later version.
*
*  This program is distributed in the hope that it will be useful, but
*  WITHOUT ANY WARRANTY; without even the implied warranty of
*  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
*  General Public License for more details.
*
*  You should have received a copy of the GNU General Public License
*  along with this program; if not, write to the Free Software Foundation,
*  Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
*
*  In addition, as a special exception, the author gives permission to
*  link the code of this program with the Half-Life Game Engine ("HL
*  Engine") and Modified Game Libraries ("MODs") developed by Valve,
*  L.L.C ("Valve"). You must obey the GNU General Public License in all
*  respects for all of the code used other than the HL Engine and MODs
*  from Valve. If you modify this file, you may extend this exception
*  to your version of the file, but you are not obligated to do so. If
*  you do not wish to do so, delete this exception statement from your
*  version.
*/

#include <amxmodx>

new Float:g_Flooding[33] = {0.0, ...}
new g_Flood[33] = {0, ...}

new amx_flood_time;

public plugin_init()
{
    register_plugin("Anti Flood", AMXX_VERSION_STR, "AMXX Dev Team")
    register_dictionary("antiflood.txt")
    register_clcmd("say", "chkFlood")
    register_clcmd("say_team", "chkFlood")
    amx_flood_time=register_cvar("amx_flood_time", "0.75")
}

public chkFlood(id)
{
    new Float:maxChat = get_pcvar_float(amx_flood_time)

    if (maxChat)
    {
        new Float:nexTime = get_gametime()
        
        if (g_Flooding[id] > nexTime)
        {
            if (g_Flood[id] >= 3)
            {
                client_print(id, print_notify, "** %L **", id, "STOP_FLOOD")
                g_Flooding[id] = nexTime + maxChat + 3.0
                return PLUGIN_HANDLED
            }
            g_Flood[id]++
        }
        else if (g_Flood[id])
        {
            g_Flood[id]--
        }
        
        g_Flooding[id] = nexTime + maxChat
    }

    return PLUGIN_CONTINUE
}