Admin, Vip and Lady models 0.3b обновление от 03.05.2014 (Админ, Вип и Женские модели для Т и СТ)

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>
 
#pragma semicolon 1
 
#define MAX_PLAYERS 32
 
#define admin ADMIN_LEVEL_E
#define lady ADMIN_LEVEL_G
 
#define BIT_VALID(%1,%2) ((%1) & (1 << ((%2) - 1)))
#define BIT_ADD(%1,%2) ((%1) |= (1 << ((%2) - 1)))
#define BIT_SUB(%1,%2) ((%1) &= ~(1 << ((%2) - 1)))
#define BIT_NOT_VALID(%1,%2) (~(%1) & (1 << ((%2) - 1)))
 
new g_iBitClientAdmin, g_iBitClientLady, g_iBitCustomModel;
 
public plugin_init()
{
   register_plugin("Admin, Vip and Lady models", "0.3b", "Freedo.m +mod.Leg");
   RegisterHam(Ham_Spawn, "player", "Ham_PlayerSpawn_Post", 1);
   register_forward(FM_SetClientKeyValue, "FM_SetClientKeyValue_Pre", 0);
}
 
public plugin_precache()
{
   precache_model("models/player/lady_teeee/lady_teeee.mdl");
   precache_model("models/player/lady_ctttt/lady_ctttt.mdl");
 
   precache_model("models/player/admin_te/admin_te.mdl");
   precache_model("models/player/admin_ct/admin_ct.mdl");
}
 
public client_putinserver(id)
{
   resetBit(id);
 
   new flags = get_user_flags(id);
   if (flags & lady)
      BIT_ADD(g_iBitClientLady, id);
   else if (flags & admin)
      BIT_ADD(g_iBitClientAdmin, id);
}
 
public client_disconnect(id)
{
   resetBit(id);
}
 
public resetBit(id)
{
   BIT_SUB(g_iBitCustomModel, id);
   BIT_SUB(g_iBitClientLady, id);
   BIT_SUB(g_iBitClientAdmin, id);
}
 
public Ham_PlayerSpawn_Post(id)
{
   if (is_user_alive(id))
   {
      if(BIT_VALID(g_iBitClientLady, id))
      {
         switch(cs_get_user_team(id))
         {
            case CS_TEAM_T: fm_cs_set_user_model(id, "lady_teeee");
            case CS_TEAM_CT: fm_cs_set_user_model(id, "lady_ctttt");
         }
      }
 
      else if(BIT_VALID(g_iBitClientAdmin, id))
      {
         switch(cs_get_user_team(id))
         {
            case CS_TEAM_T: fm_cs_set_user_model(id, "admin_te");
            case CS_TEAM_CT: fm_cs_set_user_model(id, "admin_ct");
         }
      }
 
      else fm_cs_reset_user_model(id);
   }
 
}
 
new g_szPlayerModel[MAX_PLAYERS + 1][32];
 
public FM_SetClientKeyValue_Pre(id, const szInfobuffer[], const szKey[])
{
   if(BIT_VALID(g_iBitCustomModel, id) && equal(szKey, "model"))
   {
      static szCurrentModel[32];
      fm_cs_get_user_model(id, szCurrentModel, charsmax(szCurrentModel));
      if(!equal(szCurrentModel, g_szPlayerModel[id])) fm_cs_set_user_model(id, g_szPlayerModel[id]);
      return FMRES_SUPERCEDE;
   }
   return FMRES_IGNORED;
}
 
stock fm_cs_get_user_model(id, szModel[], szLen) engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, id), "model", szModel, szLen);
stock fm_cs_set_user_model(id, const szModelName[])
{
   engfunc(EngFunc_SetClientKeyValue, id, engfunc(EngFunc_GetInfoKeyBuffer, id), "model", szModelName);
   copy(g_szPlayerModel[id], charsmax(g_szPlayerModel[]), szModelName);
   BIT_ADD(g_iBitCustomModel, id);
}
 
stock fm_cs_reset_user_model(id)
{
   BIT_SUB(g_iBitCustomModel, id);
   dllfunc(DLLFunc_ClientUserInfoChanged, id, engfunc(EngFunc_GetInfoKeyBuffer, id));
}