AFK+Ping менеджер

https://c-s.net.ua/forum/topic55067.html?hl=afk+control

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>

#define TIME_VALID_ADD 15.0 // Длительность защиты игрока от плагина, когда он только зашёл на сервер.
#define TIME_AFK_CHECK 20.0 // Интервал между проверками игроков, чем меньше значение, тем больше нагрузка на сервер.
#define MAX_AFK_WARNING 3 // Количество предупреждений после которых последует наказание.
#define TIME_SPECT_CHECK 60.0 // Интервал между проверками зрителей, чем меньше значение, тем больше нагрузка на сервер.
#define MIN_PLAYERS_CHECK 30 // Минимальное количество игроков, когда включается функция проверки зрителей.
#define ACCESS_LEVEL_IMMUNITY ADMIN_IMMUNITY

#pragma semicolon 1

#define MAX_PLAYERS 32
#define MSG_SAY_TEXT 76
#define MSG_SEND_AUDIO 100

#define TASK_AFK_CHECK 139734
#define TASK_VALID_ADD 759846
#define TASK_SPECT_CHECK 645986
#define TASK_SPECT_REMOVE 295466

#define BIT_VALID(%1,%2) ((%1) & (1 << ((%2) - 1)))
#define BIT_ADD(%1,%2) ((%1) |= (1 << ((%2) - 1)))
#define BIT_SUB(%1,%2) ((%1) &= ~(1 << ((%2) - 1)))
#define BIT_NOT_VALID(%1,%2) (~(%1) & (1 << ((%2) - 1)))

#define _BIT_VALID(%1,%2) ((%1) & (1 << (%2)))
#define _BIT_ADD(%1,%2) ((%1) |= (1 << (%2)))
#define _BIT_SUB(%1,%2) ((%1) &= ~(1 << (%2)))
#define _BIT_NOT_VALID(%1,%2) (~(%1) & (1 << (%2)))

new Float:g_fOldOrigin[MAX_PLAYERS + 1][3], Float:g_fOldAngles[MAX_PLAYERS + 1][3];
new g_iBitClientValid, g_iWarning[MAX_PLAYERS + 1];
new g_iMaxPlayers;

public plugin_init()
{
register_plugin("Afk Control", "0.1 Final", "Freedo.m");
RegisterHam(Ham_Spawn, "player", "Ham_PlayerSpawn_Post", 1);
RegisterHam(Ham_Killed, "player", "Ham_PlayerKilled_Post", 1);
register_menucmd(register_menuid("Afk Menu"), 1, "Handle_AfkMenu");
g_iMaxPlayers = get_maxplayers();
set_task(TIME_SPECT_CHECK, "SpectatorCheck", TASK_SPECT_CHECK, _, _, "b");
}

public client_putinserver(id)
{
if(get_user_flags(id) & ACCESS_LEVEL_IMMUNITY || is_user_bot(id) || is_user_hltv(id)) return;
set_task(TIME_VALID_ADD, "ClientValidAdd", id+TASK_VALID_ADD);
}

public client_disconnect(id)
{
if(task_exists(id+TASK_AFK_CHECK)) remove_task(id+TASK_AFK_CHECK);
if(task_exists(id+TASK_VALID_ADD)) remove_task(id+TASK_VALID_ADD);
if(task_exists(id)) remove_task(id);
BIT_SUB(g_iBitClientValid, id);
}

public ClientValidAdd(id)
{
id -= TASK_VALID_ADD;
BIT_ADD(g_iBitClientValid, id);
}

public Ham_PlayerSpawn_Post(id)
{
if(!is_user_alive(id)) return;
g_iWarning[id] = 0;
if(task_exists(id+TASK_AFK_CHECK)) remove_task(id+TASK_AFK_CHECK);
set_task(1.0, "SpawnCheck", id+TASK_AFK_CHECK);
set_task(TIME_AFK_CHECK, "AfkCheck", id+TASK_AFK_CHECK, _, _, "b");
}

public Ham_PlayerKilled_Post(id) remove_task(id+TASK_AFK_CHECK);

public SpawnCheck(id)
{
id -= TASK_AFK_CHECK;
pev(id, pev_origin, g_fOldOrigin[id]);
pev(id, pev_angles, g_fOldAngles[id]);
}

public AfkCheck(id)
{
id -= TASK_AFK_CHECK;
new Float:fNewOrigin[3], Float:fNewAngles[3];
pev(id, pev_origin, fNewOrigin);
pev(id, pev_angles, fNewAngles);
if(xs_vec_equal(g_fOldOrigin[id], fNewOrigin) && xs_vec_equal(g_fOldAngles[id], fNewAngles))
{
if(++g_iWarning[id] >= MAX_AFK_WARNING)
{
user_kill(id, 1);
engclient_cmd(id, "jointeam", "6");
SendAudio(id, "events/friend_died.wav");
}
else SendAudio(id, "events/tutor_msg.wav");
PrintMsg(id, "!g|AFK|!y Вы не проявляете активность, предупреждения: !g%i/%i", g_iWarning[id], MAX_AFK_WARNING);
if(user_has_weapon(id, CSW_C4)) engclient_cmd(id, "drop", "weapon_c4");
}
else
{
if(g_iWarning[id]) g_iWarning[id] = 0;
xs_vec_copy(fNewOrigin, g_fOldOrigin[id]);
xs_vec_copy(fNewAngles, g_fOldAngles[id]);
}
}

public SpectatorCheck()
{
if(get_playersnum() < MIN_PLAYERS_CHECK) return;
new id;
for(new i; i < g_iMaxPlayers; i++)
{
if(_BIT_VALID(g_iBitClientValid, i))
{
id = (i + 1);
switch(_:cs_get_user_team(id))
{
case 0: AfkPunishment(id);
case 3:
{
Show_AfkMenu(id);
SendAudio(id, "events/tutor_msg.wav");
set_task(10.0, "AfkPunishment", id);
}
}
}
}
}

public Show_AfkMenu(id)
{
new szMenu[256], iLen = formatex(szMenu, charsmax(szMenu), "\y[AFK-spectr] Вы наблюдаете за игрой?^nЕсли Вы не АФК нажмите 1.^nУ Вас 10 сек. для ответа.^n^n");
formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y1. \wДа! Я не АФК!");
return show_menu(id, 1, szMenu, 10, "Afk Menu");
}
public Handle_AfkMenu(id)
{
remove_task(id);
return PLUGIN_HANDLED;
}

public AfkPunishment(id)
{
server_cmd("kick #%d Вы были кикнуты из-за нахождения в зрителях.", get_user_userid(id));
}

stock bool:xs_vec_equal(const Float:vec1[], const Float:vec2[])
{
return (vec1[0] == vec2[0]) && (vec1[1] == vec2[1]) && (vec1[2] == vec2[2]);
}

stock xs_vec_copy(const Float:vecIn[], Float:vecOut[])
{
vecOut[0] = vecIn[0];
vecOut[1] = vecIn[1];
vecOut[2] = vecIn[2];
}

stock SendAudio(id, szDirSound[])
{
message_begin(MSG_ONE_UNRELIABLE, MSG_SEND_AUDIO, _, id);
write_byte(id);
write_string(szDirSound);
write_short(100);
message_end();
}

stock PrintMsg(const id, const szMessage[], any:...)
{
if(!is_user_connected(id)) return;
new szMsg[190];
vformat(szMsg, charsmax(szMsg), szMessage, 3);
while(replace(szMsg, charsmax(szMsg), "!y", "^1")) {}
while(replace(szMsg, charsmax(szMsg), "!t", "^3")) {}
while(replace(szMsg, charsmax(szMsg), "!g", "^4")) {}
message_begin(MSG_ONE_UNRELIABLE, MSG_SAY_TEXT, _, id);
write_byte(id);
write_string(szMsg);
message_end();
}