Status Protection

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Status Protect"
#define VERSION "1.0"
#define AUTHOR "SKAJIbnEJIb"

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_concmd("status", "status_handle")
}

public status_handle(id)
{
	// server
	new hostname[64], server_ip[32], Map[32], ActivePlayers, MaxPlayers
	get_cvar_string("hostname", hostname, 63)
	get_user_ip(0, server_ip, 31, 0)
	get_mapname(Map, 31)
	ActivePlayers = get_playersnum()
	MaxPlayers = get_maxplayers()
	
	console_print(id, "hostname:  %s", hostname)
//	console_print(id, "version :  ????????") // не знаю как сделать, и вообще нужна ли эта инфа?
	console_print(id, "tcp/ip  :  %s", server_ip)
	console_print(id, "map     :  %s", Map)
	console_print(id, "players :  %d active (%d max)", ActivePlayers, MaxPlayers)
	
	// players
	new Name[32], userid, authid[32], frags, time, ping, loss, player = 1, bool:is_player, users
	if (!is_user_admin(id))
	{
		player = id
		is_player = true
	}

	console_print(id, "^n#   name userid uniqueid frag time ping loss adr")
	for (new i = player; i <= MaxPlayers; i++)
	{
		if (is_user_connected(i))
		{
			users++
			
			get_user_name(i, Name, 31)
			userid = get_user_userid(i)
			get_user_authid(i, authid, 31)
			frags = get_user_frags(i)
			time = get_user_time(i)
			get_user_ping(i, ping, loss)
			
			console_print(id, "#%-2.1d %s %d %s %d %d:%02d %d %d", i, Name, userid, authid, frags, (time/60), (time%60), ping, loss)
			
			if (is_player)
				break
		}
	}
	console_print(id, "%d users", users)

	return PLUGIN_HANDLED
}