Изменение эфекта флеш гранаты

/*    Copyright © 2008, ConnorMcLeod

    Flash Shake Effect is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with Flash Shake Effect; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>

#define PLUGIN "Flash Shake Effect"
#define AUTHOR "ConnorMcLeod"
#define VERSION "0.0.1"

#define MAX_PLAYERS    32

#define DEAF_SOUND    "misc/deaf_sound.wav"

new g_iMaxPlayers
new g_iFwd

new bool:g_bFlashed[MAX_PLAYERS+1]
new Float:g_flFlashedUntill[MAX_PLAYERS+1]

public plugin_precache()
{
    precache_sound(DEAF_SOUND)
}

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, AUTHOR )
    register_event("ScreenFade", "Event_ScreenFade", "be", "1>0", "2>0", "3=0","4=255", "5=255", "6=255", "7>199")
    g_iMaxPlayers = get_maxplayers()
}

public client_connect(id)
{
    g_bFlashed[id] = false
}

public client_disconnect(id)
{
    g_bFlashed[id] = false
}

public Event_ScreenFade(id)
{
    client_cmd(id, "speak %s", DEAF_SOUND)

    g_flFlashedUntill[id] = get_gametime() + float(read_data(1) - read_data(2)) / (1<<12)

    if(!g_bFlashed[id])
        Set_PlayerPreThink(id)
}

Set_PlayerPreThink(id, bool:Status=true)
{
    if(Status)
    {
        g_bFlashed[id] = true
        client_cmd(id, "room_type 20")
        if(!g_iFwd)
        {
            g_iFwd = register_forward(FM_PlayerPreThink, "PlayerPreThink")
        }
    }
    else
    {
        g_bFlashed[id] = false
        client_cmd(id, "room_type 0")
        for(new id=1; id<=g_iMaxPlayers; id++)
        {
            if(g_bFlashed[id])
            {
                return
            }
        }
        unregister_forward(FM_PlayerPreThink, g_iFwd)
        g_iFwd = 0
    }
}

public PlayerPreThink(id)
{
    if(!g_bFlashed[id])
        return

    static Float:fFlashedTime
    fFlashedTime = g_flFlashedUntill[id] - get_gametime()

    if(fFlashedTime < 0.0)
    {
        set_pev(id, pev_punchangle, Float:{0.0,0.0,0.0})
        Set_PlayerPreThink(id, false)
        return
    }

    static Float:fPunchAngle[3]

    for(new i; i<3; i++)
    {
        if(random_num(0,1))
            fPunchAngle[i] = 0.5 * fFlashedTime
        else
            fPunchAngle[i] = -0.5 * fFlashedTime
    }

    set_pev(id, pev_punchangle, fPunchAngle)

}