АнтиСпидхак

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "SpeedHack Detector"
#define VERSION "0.12"
#define AUTHOR "Mistrick"

#pragma semicolon 1

#define MAX_WARN_TIME 5.0
#define MAX_SLOW_WARN 7
#define MAX_SPEED_WARN 7

new bool:g_bAlive[33], g_iFPS[33], g_iFrame[33], g_iMsec[33], g_iWarnSlow[33], g_iWarnSpeed[33], g_iMaxPlayers;
new Float:g_fWarnSlowTime[33], Float:g_fWarnSpeedTime[33], Float:g_fOrigin[33][3];

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_forward(FM_CmdStart, "FM_CmdStart_Pre", 0);
	register_forward(FM_PlayerPostThink, "FM_PlayerPostThink_Pre", 0);
	RegisterHam(Ham_Killed, "player", "Ham_Player_Alive", 1);
	RegisterHam(Ham_Spawn, "player", "Ham_Player_Alive", 1);
	set_task(1.0, "CheckFps", _, _, _, "b");
	g_iMaxPlayers = get_maxplayers();
}
public client_disconnect(id)
{
	g_bAlive[id] = false;
}
public Ham_Player_Alive(id)
{
	g_bAlive[id] = bool:is_user_alive(id);
}
public FM_PlayerPostThink_Pre(id)
{
	if(!g_bAlive[id]) return FMRES_IGNORED;
	
	g_iFrame[id] += 1;
	
	return FMRES_IGNORED;
}
public FM_CmdStart_Pre(id, uc_handle, seed)
{
	if(!g_bAlive[id]) return FMRES_IGNORED;

	g_iMsec[id] = get_uc(uc_handle, UC_Msec);
	
	return FMRES_IGNORED;
}
public CheckFps()
{
	for(new id = 1; id <= g_iMaxPlayers; id++)
	{
		if(!g_bAlive[id])
		{
			g_iFrame[id] = 0;
			continue;
		}
		g_iFPS[id] = g_iFrame[id];
		g_iFrame[id] = 0;
		CheckHack(id);
	}
}
public CheckHack(id)
{
	static iMsecFPS, offset, offset2, Float:fOrigin[3];
	static Float:fTime; fTime = get_gametime();
	
	pev(id, pev_origin, fOrigin);
	if(equal_array(fOrigin, g_fOrigin[id])) return;
	
	if(g_iMsec[id])
	{
		iMsecFPS = floatround(1000.0/g_iMsec[id]);
	}
	else
	{
		iMsecFPS = 2000;
	}

	//console_print(0, "id:%d, FPS: %d, Msec: %d => FPS: %d, TimeFPS: %d", id, g_iFPS[id], g_iMsec[id], iMsecFPS, g_iTimeFPS[id]);		
	
	switch(iMsecFPS)
	{
		case 1000:{ offset = 360; offset2 = 360; }
		case 500:{ offset = 180; offset2 = 360; }
		case 333:{ offset = 95; offset2 = 180; }
		case 250:{ offset = 60; offset2 = 95; }
		default:{ offset = 50; offset2 = 50; }
	}
	
	if(iMsecFPS > g_iFPS[id] + offset)
	{
		if(g_iWarnSlow[id] && fTime - g_fWarnSlowTime[id] >= MAX_WARN_TIME)
		{
			g_iWarnSlow[id] = 0;
		}
		g_iWarnSlow[id]++;
		g_fWarnSlowTime[id] = fTime;
	}
	if(iMsecFPS + offset2 < g_iFPS[id])
	{
		if(g_iWarnSpeed[id] && fTime - g_fWarnSpeedTime[id] >= MAX_WARN_TIME)
		{
			g_iWarnSpeed[id] = 0;
		}
		g_iWarnSpeed[id]++;
		g_fWarnSpeedTime[id] = fTime;
	}
	if(g_iWarnSlow[id] >= MAX_SLOW_WARN)
	{
		g_iWarnSlow[id] = 0;
		Punish(id, "Type 1");
	}
	if(g_iWarnSpeed[id] >= MAX_SPEED_WARN)
	{
		g_iWarnSpeed[id] = 0;
		Punish(id, "Type 2");
	}
	g_fOrigin[id][0] = fOrigin[0];
	g_fOrigin[id][1] = fOrigin[1];
	g_fOrigin[id][2] = fOrigin[2];
}
public Punish(id, type[])
{
	new szName[32];
	get_user_name(id, szName, charsmax(szName));
	client_print(0, print_chat, "[AMXX] %s using hack[%s]", szName, type);
}
equal_array(Float:a[3], Float:b[3])
{
	return (floatabs(a[0] - b[0]) < 0.000001 && floatabs(a[1] - b[1]) < 0.000001 && floatabs(a[2] - b[2]) < 0.000001);
}