Плагин рестарт

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "MegaRestart"
#define VERSION "1.0"
#define AUTHOR "DumoH4uk"

new Cvar[2]
new RoundStart
new BlockRestart
new TimerRestart
new Cony_Post[33], Cony_Pre[33]

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	Cvar[0] = register_cvar("reatart_cherez", "60")
	Cvar[1] = register_cvar("kolvo_restartov", "3")
	
	register_event("TextMsg", "Commencing", "a", "2=#Game_Commencing")
	register_event("HLTV", "Round", "a", "1=0", "2=0")
	register_logevent("JoinTeam",3,"1=joined team")
	
	RegisterHam(Ham_Killed, "player", "RunKillMatch")
}

public Commencing()
{
	if(BlockRestart) return;
	RoundStart = 1
}

public Round() {
	if(BlockRestart) return;
	
	RoundStart--
		
	if(RoundStart == 0) {
		TimerRestart = get_pcvar_num(Cvar[0])
		set_task(1.0, "Restart_Through", 01, _, _, "b")
	}
}

public JoinTeam() {
	if(BlockRestart) return;
	
	new log[256], user[32]
	
	read_logargv(0, log, 255)
	parse_loguser(log, user, 31)
	
	new id = get_user_index(user)
	
	if(is_user_connected(id) && cs_get_user_team(id) != CS_TEAM_SPECTATOR)
		set_task(1.0, "DeathSpawn", id)
}

public Restart_Through() {
	TimerRestart--
	
	if(TimerRestart >= 1) {
		new Players[32], Player, Num
		
		get_players(Players, Num, "ch")

		for(new i; i < Num; i++)  {
			Player = Players[i]
			
			if(!is_user_connected(Player) || !is_user_alive(Player)) continue;
			
			set_hudmessage(255, 127, 0, -1.0, -1.0, 0, 6.0, 1.0)
			show_hudmessage(Player, "Restart cherz: %d", TimerRestart)
			
			if(get_user_weapon(Player) != CSW_KNIFE)
				engclient_cmd(Player, "weapon_knife")
		}
	}else{
		remove_task(01)
		BlockRestart = true
		
		TimerRestart = get_pcvar_num(Cvar[1])
		set_task(1.0, "Restart", 02, _, _, "b")
	}
}

public Restart() {
	TimerRestart--
	
	if(TimerRestart >= 0) {
		server_cmd("sv_restart 1")
	}else{
		remove_task(02)
	}
}

public RunKillMatch(id) {
	if(BlockRestart) return;
	set_task(1.0, "DeathSpawn", id)
}

public DeathSpawn(id) {
	if(get_user_team(id) == 1 || get_user_team(id) == 2) {
		if(!is_user_alive(id) && is_user_connected(id)) {
			ExecuteHam(Ham_CS_RoundRespawn, id)
		}
	}
}

public client_PreThink(id) {
	if(TimerRestart <= 1)
		return PLUGIN_CONTINUE

	new szButton = pev(id, pev_button)
	new szOldButton = pev(id, pev_oldbuttons)
 
	if((szButton & IN_JUMP) && !(pev(id, pev_flags) & FL_ONGROUND) && !(szOldButton & IN_JUMP)) {
		if(!Cony_Pre[id]) {
			Cony_Post[id] = true
			Cony_Pre[id]++
 
			return PLUGIN_CONTINUE
		}
	}
	if((szButton & IN_JUMP) && (pev(id, pev_flags) & FL_ONGROUND)) {
		Cony_Pre[id] = 0
	}
	return PLUGIN_CONTINUE
}

public client_PostThink(id) {
	if(TimerRestart <= 1)
		return PLUGIN_CONTINUE

	if(!is_user_alive(id))
		return PLUGIN_CONTINUE
 
	if(Cony_Post[id]) {
		new Float:szVelocity[3]  
 
		pev(id, pev_velocity, szVelocity)
 
		szVelocity[2] = random_float(295.0,305.0)
		set_pev(id, pev_velocity, szVelocity)
 
		Cony_Post[id] = false
 
		return PLUGIN_CONTINUE
	}
	return PLUGIN_CONTINUE
}