Mute menu

#include <amxmodx>
#include <fakemeta>
 
new bool:g_mute[33][33]
new g_menuposition[33]
new g_menuplayers[33][32]
new g_menuplayersnum[33]
new muteall[33]
new cvar_alltalk
new maxplayers
 
public plugin_init()
{
        register_plugin("mute menu", "0.5", "Bl0ck and default")
 
        register_clcmd("say /mute", "mutemenu")
        register_clcmd("say_team /mute", "mutemenu")
        register_clcmd("mute", "mutemenu")
 
        register_forward(FM_Voice_SetClientListening, "fwd_voice_setclientlistening")
        register_menucmd(register_menuid("mute menu"), 1023, "action_mutemenu")
       
        cvar_alltalk = get_cvar_pointer("sv_alltalk")
        maxplayers = get_maxplayers()
}
 
public mutemenu(id)
{
        display_mutemenu(id, g_menuposition[id] = 0)
        return PLUGIN_HANDLED
}
 
public fwd_voice_setclientlistening(receiver, sender, listen)
{
        if(receiver == sender)
                return FMRES_IGNORED
               
        if(g_mute[receiver][sender])
        {
                engfunc(EngFunc_SetClientListening, receiver, sender, 0)
                return FMRES_SUPERCEDE
        }
        return FMRES_IGNORED
}
 
display_mutemenu(id, pos)
{
        if(pos < 0)  
                return
 
        new at = get_pcvar_num(cvar_alltalk)
        g_menuplayersnum[id] = get_players_new(id, g_menuplayers[id], at ? -1 : get_user_team(id))
 
        new start = pos * 7
        if(start >= g_menuplayersnum[id])
        start = pos = g_menuposition[id]
 
        new end = start + 7
        if(end > g_menuplayersnum[id])
        end = g_menuplayersnum[id]
 
        static menubody[512]   
        new len = format(menubody, 511, "\yЗаткнуть игрока:^n^n\w")
 
        static name[32]
       
        new b = 0, i
        new keys = MENU_KEY_0
       
        for(new a = start; a < end; ++a)
        {
                i = g_menuplayers[id][a]
                get_user_name(i, name, 31)
 
                keys |= (1<<b)
                len += format(menubody[len], 511 - len, "\r%d.\w %s %s\w^n", ++b, name, g_mute[id][i] ? "\r(Заглушен)" : "")
        }
        if(muteall[id])
                len += format(menubody[len], 511 - len, "^n\r8.\w Разглушить всех")
        else
                len += format(menubody[len], 511 - len, "^n\r8.\w Заткнуть всех")
        keys |= MENU_KEY_8
 
        if(end != g_menuplayersnum[id])
        {
        format(menubody[len], 511 - len, "^n\r9.\w %s^n\r0.\w %s", "Дальше", pos ? "Назад" : "Выход")
        keys |= MENU_KEY_9
        }
        else
                format(menubody[len], 511-len, "^n\r0.\w %s", pos ? "Назад" : "Выход")
       
        show_menu(id, keys, menubody, -1, "mute menu")
}
 
 
public action_mutemenu(id, key)
{
        switch(key)
        {
                case 7:
                {
                        if(muteall[id])
                        {
                                for(new i = 1; i <= maxplayers; ++i)
                                        g_mute[id][i] = false
 
                                muteall[id] = false
                        }
                        else
                        {
                                for(new i = 1; i <= maxplayers; ++i)
                                        g_mute[id][i] = true
 
                                muteall[id] = true
                        }
                       
                        display_mutemenu(id, g_menuposition[id])
                }
                case 8: display_mutemenu(id, ++g_menuposition[id])
                case 9: display_mutemenu(id, --g_menuposition[id])
        default:
                {
                        new player = g_menuplayers[id][g_menuposition[id] * 7 + key]
                       
                        g_mute[id][player] = g_mute[id][player] ? false : true
                        display_mutemenu(id, g_menuposition[id])
        }
        }
       
        return PLUGIN_HANDLED
}
 
get_players_new( id, players[ 32 ], team = -1 )
{
        new num;
        for( new i = 1; i <= maxplayers; i++ )
        {
                if( is_user_connected( i ) && !is_user_hltv( i ) && !is_user_bot( i ) && i != id )
                {
                        if( team > -1 && get_user_team( i ) != team )
                                continue;
                       
                        players[ num++ ] = i;
                }
        }
        return num;
}