Ищу плагин "лучшие игроки" [ZM]

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <zombieplague>

#define PLUGIN "[ZP] Addon: Best Players"
#define VERSION "0.2"
#define AUTHOR "PomanoB & Fintok!"

#define m_iTeam 114
#define fm_cs_get_user_team_index(%1) get_pdata_int(%1, m_iTeam)

enum { ME_DMG, ME_INFECT, ME_KILLS, ME_NUM }

new g_Me[33][ME_NUM]

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_cvar(PLUGIN, VERSION, FCVAR_SERVER|FCVAR_SPONLY)

	RegisterHam(Ham_Killed, "player", "fw_HamKilled")
	RegisterHam(Ham_TraceAttack, "player", "fw_TraceAttack", 1)
	RegisterHam(Ham_CS_RoundRespawn, "player", "fw_CS_RoundRespawn", 1)

	register_dictionary("zp_best_players.txt")
}

public zp_user_infected_post(id, infector, nemesis)
{
	if(!is_user_connected(infector))
		return

	g_Me[infector][ME_INFECT]++
}

public zp_round_ended(winteam)
{
	if(!get_playersnum())
		return

	new players[32], playersNum, maxInfectId = 0, maxDmgId = 0, maxKillsId = 0
	new message[200], len
	new maxInfectName[32], maxDmgName[32], maxKillsName[32]

	get_players(players, playersNum, "ch")

	for(new i = 0; i < playersNum; i++)
	{
		if(g_Me[players[i]][ME_INFECT] > g_Me[players[maxInfectId]][ME_INFECT])
			maxInfectId = i

		if(g_Me[players[i]][ME_DMG] > g_Me[players[maxDmgId]][ME_DMG])
			maxDmgId = i

		if(g_Me[players[i]][ME_KILLS] > g_Me[players[maxKillsId]][ME_KILLS])
			maxKillsId = i	
	}

	get_user_name(players[maxInfectId], maxInfectName, 31)
	get_user_name(players[maxDmgId], maxDmgName, 31)
	get_user_name(players[maxKillsId], maxKillsName, 31)

	if(g_Me[players[maxInfectId]][ME_INFECT] || g_Me[players[maxKillsId]][ME_KILLS] || g_Me[players[maxDmgId]][ME_DMG])
	{
		for(new i = 0; i < playersNum; i++)
		{
			len = format(message, charsmax(message), "%L", players[i], "BEST_TITLE")

			if(g_Me[players[maxInfectId]][ME_INFECT])
				len += format(message[len], charsmax(message) - len, "^n%L", players[i], "BEST_INFECT", 
					maxInfectName, g_Me[players[maxInfectId]][ME_INFECT])

			if(g_Me[players[maxKillsId]][ME_KILLS])
				len += format(message[len], charsmax(message) - len, "^n%L", players[i], "BEST_KILLS", 
					maxKillsName, g_Me[players[maxKillsId]][ME_KILLS])

			if(g_Me[players[maxDmgId]][ME_DMG])
				len += format(message[len], charsmax(message) - len, "^n%L", players[i], "BEST_DMG", 
					maxDmgName, g_Me[players[maxDmgId]][ME_DMG])

			set_hudmessage(100, 200, 0, 0.05, 0.55, 0, 0.02, 6.0, 0.0, 1.0)
			show_hudmessage(players[i], message)
		}
	}
}

public fw_HamKilled(victim, attacker, shouldgib)
{
	if(!is_user_connected(attacker) || victim == attacker)
		return

	if(fm_cs_get_user_team_index(victim) == fm_cs_get_user_team_index(attacker))
		return

	g_Me[attacker][ME_KILLS]++
}

public fw_TraceAttack(victim, attacker, Float:damage, Float:direction[3], traceresult, damagebits)
{
	if(!is_user_connected(attacker) || victim == attacker || zp_get_user_nemesis(attacker) || zp_get_user_zombie(attacker))
		return

	if(fm_cs_get_user_team_index(victim) == fm_cs_get_user_team_index(attacker))
		return

	g_Me[attacker][ME_DMG] += floatround(damage)
}

public fw_CS_RoundRespawn(id)
{
	for(new i = 0; i < ME_NUM; i++)
		g_Me[id][i] = 0	
}