[Stable] Lite Translit

#include <amxmodx>
#include <fakemeta>
	
#define ADBLOCK							// Блокировка рекламы в чате  [ По умолчанию выключен ]
// #define DEF_RUS						// Русский язык по умолчанию [ По умолчанию английский ]
// #define LOG_MESSAGE					// Пишет сообщения в логи hlds (<gamedir>/logs) [ Включать только если статистика или плагин пишет чат ]
#define ADMIN_ADBLOCK	ADMIN_BAN		// Флаг доступа для игнорирования рекламы
#define ADMIN			ADMIN_RCON		// Флаг доступа для просмотра всего чата
#define GREEN_MSG						// Зеленый цвет чата админов и випов [ По умолчанию выключен ]

#if defined GREEN_MSG
#define ADMIN_GREEN		ADMIN_LEVEL_H	// Флаг доступа для зеленого ника
#endif

#define	get_bit(%1,%2)	(%1 & (1 << (%2 & 31)))
#define	set_bit(%1,%2)	%1 |= (1 << (%2 & 31))
#define	clr_bit(%1,%2)	%1 &= ~(1 << (%2 & 31))

new szMessage[191]
new iPlayerRus[33], iPlayerRusInfo[33]
new iIgnorePlayer

#if defined ADBLOCK
	new blockedMsgsCounter, approvedMsgsCounter
	new blocked_msgs[128][192], approved_msgs[128][192]
#endif	

new const eng[][]={"A","B","C","D","E","F","G","H","I","J","K","L","M","N","O","P","Q","R","S","T","U","V","W","X","Y","Z","{","}",":",'"',"<",">","~","a","b","c","d","e","f","g","h","i","j","k","l","m","n","o","p","q","r","s","t","u","v","w","x","y","z","[","]",";","'",",",".","`","?","/","@","$","^^","&"};
new const rus[][]={"Ф","И","С","В","У","А","П","Р","Ш","О","Л","Д","Ь","Т","Щ","З","Й","К","Ы","Е","Г","М","Ц","Ч","Н","Я","Х","Ъ","ж","Э","Б","Ю","Ё","ф","и","с","в","у","а","п","р","ш","о","л","д","ь","т","щ","з","й","к","ы","е","г","м","ц","ч","н","я","х","ъ","ж","э","б","ю","ё",",",".","'",";", ":","?"};	
 
public plugin_init()
{
	register_plugin("Lite Translit", "2.4", "neygomon")
	register_cvar("lt_version", "2.4", FCVAR_SERVER | FCVAR_SPONLY)
	
	new const szRegisterClmd[][] =
	{
		"say /rus",	"LangRus",
		"say /eng",	"LangEng",
		"say",		"Say",
		"say_team",	"SayTeam"
	}
	for(new a; a < sizeof szRegisterClmd; a += 2)
		register_clcmd(szRegisterClmd[a],szRegisterClmd[a + 1]);
}

#if defined ADBLOCK
public plugin_cfg()
{
	new file_path[64], configsdir[64]
	get_localinfo("amxx_configsdir", configsdir, charsmax(configsdir))
	formatex(file_path, 63,"%s/lt_blockmessages.ini", configsdir)
	new file = fopen(file_path, "rt")
	if(file)
	{
		new buffer[192], i, j
		while(!feof(file))
		{
			fgets(file, buffer, 191)
			trim(buffer)
			
			if(buffer[0] == ';') continue
			
			if(buffer[0] != '!')
			{
				blocked_msgs[i++] = buffer
				blockedMsgsCounter++
			}
			else 
			{
				buffer[0] = '^x20'
				trim(buffer)
				approved_msgs[j++] = buffer
				approvedMsgsCounter++
			}
		}
		fclose(file)
	}
	else log_to_file("error_lt.log", "[Error] File ^"%s^" not found!", file_path)
}
#endif

public client_putinserver(id)
{
	if(is_user_hltv(id) || is_user_bot(id)) 
	{
		set_bit(iIgnorePlayer, id)
		return
	}
	#if defined DEF_RUS
		iPlayerRus[id] = true
	#endif	
}
	
public client_disconnect(id)
{
	clr_bit(iIgnorePlayer, id)
}	

public LangRus(id)
{
	if(!iPlayerRus[id])
	{
		iPlayerRus[id] = true
		PrintMsg(id, 0, "^3[^4Информация^3]^1 Русский чат активирован!")
	}
	else PrintMsg(id, 0, "^3[^4Информация^3]^1 Русский чат уже активирован!")
}
 
public LangEng(id)
{
	if(iPlayerRus[id])
	{
		iPlayerRus[id] = false
		PrintMsg(id, 0, "^3[^4Информация^3]^1 Английский чат активирован!")
	}
	else PrintMsg(id, 0, "^3[^4Информация^3]^1 Английский чат уже активирован!")
}

public Say(id)
	return SayHandler(id, false)
	
public SayTeam(id)
	return SayHandler(id, true)

public SayHandler(id, bool:is_say_team)
{
	if(get_bit(iIgnorePlayer, id)) return 0
 
	read_args(szMessage, charsmax(szMessage))
	remove_quotes(szMessage)
	#if defined ADBLOCK
		if(!szMessage[0] || szMessage[0] == '/' || Flood_Control(id, szMessage)) return PLUGIN_HANDLED_MAIN  // блочим пустое сообщение, слеш и спам в чате
	#else
		if(!szMessage[0] || szMessage[0] == '/') return PLUGIN_HANDLED_MAIN  // блочим пустое сообщение и слеш в чате
	#endif
	replace_all2(szMessage, charsmax(szMessage), "%", "") // фиксим багу с %S%S%S%S%S и им подобными
	if(!iPlayerRusInfo[id])
	{
		if(!iPlayerRus[id])
		{
			iPlayerRusInfo[id] = true
			PrintMsg(id, 0, "^3[^4Информация^3]^1 Наберите ^4/rus^1 или ^4/eng^1 для переключения языка.")
		}
	}
	if(iPlayerRus[id])
	{	
		for(new i; i < sizeof eng; i++)
			replace_all2(szMessage, charsmax(szMessage), eng[i], rus[i])
	}
	new szFormatedMsg[191], szLen, szName[32], iAlive = is_user_alive(id), iTeam = get_pdata_int(id, 114)
	
	get_user_name(id, szName, charsmax(szName))
	if(is_say_team)
	{
		switch(iTeam)
		{
			case 1: szLen = formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg), "%s(Террорист) ", iAlive ? "^1" : "^1*Мертвый* ")
			case 2: szLen = formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg), "%s(Мент) ", iAlive ? "^1" : "^1*Мертвый* ")
			case 3: szLen = formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg), "^1(Наблюдатель) ")
		}
	}
	else 
	{
		if(iTeam == 3) szLen = formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg), "^1(Наблюдатель) ")
		else szLen = formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg) - szLen, "%s", iAlive ? "^1" : "^1*Мертвый* ")
	}	
	#if defined GREEN_MSG
		if(get_user_flags(id) & ADMIN_GREEN)
			szLen += formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg) - szLen, "^4%s^1 : ", szName)
		else
			szLen += formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg) - szLen, "^3%s^1 : ", szName)   
	#else
		szLen += formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg) - szLen, "^3%s^1 : ", szName)
	#endif	

	szLen += formatex(szFormatedMsg[szLen], charsmax(szFormatedMsg) - szLen, "%s", szMessage)

	static players[32], pcount; get_players(players, pcount, "c")
	if(is_say_team)
	{
		for(new i; i < pcount; i++)
			if(get_user_flags(players[i]) & ADMIN || (iTeam == get_user_team(players[i]) && iAlive == is_user_alive(players[i])))
				PrintMsg(players[i], id, szFormatedMsg)
	}
	else
	{
		for(new i; i < pcount; i++)
			PrintMsg(players[i], id, szFormatedMsg)
	}
	#if defined LOG_MESSAGE
	new authid[32], userteam[16]
	get_user_authid(id, authid, 31)
	get_user_team(id, userteam, 15)
	log_message("^"%s<%d><%s><%s>^" %s ^"%s^"", szName, get_user_userid(id), authid, userteam, is_say_team ? "say_team" : "say" , szMessage)
	#endif
	return PLUGIN_HANDLED
}

stock PrintMsg(const iReceiver, const iSender, const szMessage[], any:...)
{
	new szMsg[191]
	vformat(szMsg, charsmax(szMsg), szMessage, 4)
	message_begin(MSG_ONE_UNRELIABLE, 76, _, iReceiver)
	write_byte(iSender ? iSender : iReceiver)
	write_string(szMsg)
	message_end()
}
#if defined ADBLOCK
bool:Flood_Control(id, iMsg[])
{
	if(get_user_flags(id) & ADMIN_ADBLOCK)
		return false
		
	for(new i; i < approvedMsgsCounter; i++)
		if(containi(iMsg, approved_msgs[i]) != -1) return false
	
	static last_msg[33], said_len
	said_len = strlen(iMsg)
	if(said_len > 13 && last_msg[id] == said_len) return true
	last_msg[id] = said_len
	
	for(new i; i < blockedMsgsCounter; i++)
		if(containi(iMsg, blocked_msgs[i]) != -1) return true	
	return false
}
#endif

// serfreeman1337 fixed. thx =)
stock replace_all2(string[], len, const what[], const with[])
{
	new pos
	if((pos = contain(string, what)) == -1) return 0
	new total, with_len = strlen(with), diff = strlen(what) - with_len, total_len = strlen(string), temp_pos
	while(total_len + with_len < len && replace(string[pos], len - pos, what, with) != 0)
	{
		total++
		pos += with_len
		total_len -= diff
		if (pos >= total_len) break
		temp_pos = contain(string[pos], what)
		if (temp_pos == -1) break
		pos += temp_pos
	}
	return total
}