Проблема с модулем GeoIP

description stat pend file vers src load unlod
[ 1] dproto_EF RUN - dproto_i386.so v0.9.391 ini Start Never
[ 2] WHBlocker RUN - whblocker_mm_i38 v1.5.370 ini Chlvl ANY
[ 3] AMX Mod X RUN - amxmodx_mm_i386. v1.8.2 ini Start ANY
[ 4] VoiceTranscoder RUN - vtc.so v80 ini ANY ANY
[ 5] Ham Sandwich RUN - hamsandwich_amxx v1.8.2-d pl3 ANY ANY
[ 6] CStrike RUN - cstrike_amxx_i38 v1.8.2-d pl3 ANY ANY
[ 7] Engine RUN - engine_amxx_i386 v1.8.2-d pl3 ANY ANY
[ 8] FakeMeta RUN - fakemeta_amxx_i3 v1.8.2-d pl3 ANY ANY
[ 9] Fun RUN - fun_amxx_i386.so v1.8.2-d pl3 ANY ANY
[10] MySQL RUN - mysql_amxx_i386. v1.8.2-d pl3 ANY ANY
[11] CSX RUN - csx_amxx_i386.so v1.8.2-d pl3 ANY ANY
11 plugins, 11 running

stats
CPU In Out Uptime Users FPS Players
5.80 17.13 32.36 51 134 952.10 24

Код:

public client_putinserver( id )
{
	new ip[ 16 ], country[ 3 ];
	get_user_ip( id, ip, charsmax( ip ), WITHOUT_PORT ); // Get player IP
	
	if( geoip_code2_ex( ip, country ) )
	{
		format( g_country[ id ], charsmax( g_country[ ] ), "%s", country ); // Player country detected
	}
	else
	{
		format( g_country[ id ], charsmax( g_country[ ] ), "GB" ); // Default Lang
	}
}

Код:

#include <amxmodx>
#include <geoip>

#define VERSION "1.3"
#define PLUG_ADMIN ADMIN_LEVEL_G	// access flag required to have fake country tag

// uncomment to activate bot support
//#define BOT_TAG

#if defined BOT_TAG
new const gszBotTag[] = "[BOT]" 	// set BOT_TAG to "" if you don't want bots to have tag at all
new gszCountry[33][6]	// this value must be +1 more than 4 and the quantity of symbols in bot tag
#else
new gszCountry[33][5]
#endif

new pDefCountry
new gszInfoName[] = "name"

#define has_country_tag(%1) ( %1[0] == '[' && %1[3] == ']' )

public plugin_init() {
	register_plugin( "Country On Name", VERSION, "Bboy Grun/Safety1st" )
	register_cvar( "country_on_name", VERSION, FCVAR_SERVER | FCVAR_SPONLY )
	pDefCountry = register_cvar( "amx_default_country_code", "??" )
}

public client_putinserver(id) {
	new szName[32], szIp[16], szCountry[3]
	static szDefCountry[3]
	if ( !szDefCountry[0] )
		get_pcvar_string( pDefCountry, szDefCountry, charsmax( szDefCountry ) )

	if ( is_user_hltv(id) )
		return

#if defined BOT_TAG
	if ( is_user_bot(id) ) {
		if ( gszBotTag[0] )
			copy( gszCountry[id], 9, gszBotTag )
		return
	}
#endif

	if ( get_user_flags(id) & PLUG_ADMIN ) {
		get_user_name( id, szName, 31 )
		if ( has_country_tag( szName ) ) {
			copy( gszCountry[id], 4, szName )	// save player fake country tag
			return
		}
	}

	get_user_ip( id, szIp, 15, 1 /*no port*/ )
	if ( geoip_code2_ex( szIp, szCountry ) )
		formatex( gszCountry[id], 4 , "[%s]", szCountry )
	else
		formatex( gszCountry[id], 4 , "[%s]", szDefCountry )
}

public client_disconnected(id) {
	gszCountry[id][0] = EOS;
}

public client_infochanged(id) {
	new szName[32], iPos, szTemp[32]
	if ( !gszCountry[id][0] )
		return PLUGIN_CONTINUE

	get_user_info( id, gszInfoName, szName, 31 )

#if defined BOT_TAG
	new iLen = strlen( gszCountry[id] )
#else
	static const iLen = 4
#endif

	iPos = contain( szName, gszCountry[id] )
	if ( !iPos && szName[iLen] == ' ' && szName[ iLen + 1 ] != ' ' )	// new name is correct
		return PLUGIN_CONTINUE

	// get names of all current players
	new iPlayers[32], iPlayersNum, iPlayer, i, iPlayerNames[31][32] /* we don't save name owned by player*/, szBaseName[32]
	get_players( iPlayers, iPlayersNum )
	
	for ( i = 0; i < iPlayersNum; i++ ) {
		iPlayer = iPlayers[i]
		if ( iPlayer == id )
			continue
		get_user_name( iPlayer, iPlayerNames[i], 31 )
	}

	// save current player name excluding country tag if it exists
	// and remove spaces: <>
	if ( iPos != -1 ) { // tag was found
		copy( szTemp, iPos, szName )	// save prefix
		trim( szTemp )
		copy( szBaseName, 31, szName[ iPos + iLen ] )	// save suffix
		trim( szBaseName )
		format( szBaseName, 31, "%s%s", szTemp, szBaseName )
	}
	else {	// tag was not found
		copy( szBaseName, 31, szName )
		trim( szBaseName )
	}
	
	// format new name as we need
	new iCounter = 0

	if ( szBaseName[0] )
		format( szName, 31, "%s %s", gszCountry[id], szBaseName )
	else	// engine doesn't allow name consisting of spaces, set 'empty' is the default behavior
		format( szName, 31, "%s empty", gszCountry[id] )

	goto check

	fmt:
	// create new name with check to avoid duplicates and don't allow engine to set new name by its own (it leads to BIG problems in CS!)
	format( szName, 31, "%s (%d)%s", gszCountry[id], iCounter, szBaseName )

	check:
	for ( i = 0; i < iPlayersNum - 1; i++ ) {	/* remember that we have (iPlayersNum - 1) names */
		if ( equali( iPlayerNames[i], szName ) ) {
			iCounter++
			goto fmt
		}
	}

	set_user_info( id, gszInfoName, szName )

	return PLUGIN_HANDLED
}