Закрытие меню

public startVote(id)
{	
	new title[192]
	format(title, 191, "%L", id, "AMM_VOTE_MENU_TITLE")
	startVoteMenu = menu_create(title, "startVoteHandler", 1)
	menu_setprop( startVoteMenu, MPROP_PERPAGE, 0 )
	menu_setprop( startVoteMenu, MPROP_EXIT, MEXIT_NEVER )
	for(new i=0; i<g_MapsInVoteCount; i++)
	{
		new key[3]
		num_to_str(i, key, 2)
		menu_additem(startVoteMenu, g_MapsInVote[i], key, 0)
	}
	for(new player=1; player<33; player++)
	{
		if(is_user_connected(player))
		{
			menu_display(player, startVoteMenu)		
		}
	}

	set_task(1.0, "startVoteTask", VOTE_TASK, _, _, "a", 15)
	return PLUGIN_HANDLED
}

public startVoteHandler(id, menu, item)
{
	if (item == MENU_EXIT)
	{
		clearvote(id)
		return PLUGIN_HANDLED
	}
	
	new s_Data[6], s_Name[64], i_Access, i_Callback, name[64]
	menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)
	new key = str_to_num(s_Data)
	get_user_name(id, name, 63)
	client_print(id, print_chat, "key %i", key)
	client_print(id, print_chat, "%s voted for %s", name, g_MapsInVote[key])
	g_MapVotes[key]++
	
	clearvote(id)
	return PLUGIN_HANDLED
}

public startVoteTask(id)
{
	new pid=id-100
	g_VoteSeconds--
	set_hudmessage(.holdtime=2, .channel=2)
	show_hudmessage(pid, "%i seconds", g_VoteSeconds)
	if(g_VoteSeconds < 1)
	{
		clearvote(pid)
		return PLUGIN_HANDLED
	}
	return PLUGIN_CONTINUE
}
public clearvote(id)
{
	if(task_exists(VOTE_TASK))
	{
		remove_task(VOTE_TASK)
	}
	menu_cancel(id)
	menu_destroy(startVoteMenu)
	g_MapsInVoteCount = 0;
	g_VoteSeconds = 15;
	return PLUGIN_HANDLED
}

#include <amxmodx>

 //This will hold the VoteMenu
 new gVoteMenu;
 //This will hold the votes for each option
 new gVotes[2];
 //This determines if a vote is already happening
 new gVoting;

 public plugin_init()
 {
    //Register a way to get to your vote...
    register_clcmd( "start_vote","StartVote" );
 }
 public StartVote( id )
 {
    //If there is already a vote, don't start another
    if ( gVoting )
    {
        client_print( id, print_chat, "There is already a vote going." );
        //We return PLUGIN_HANDLED so the person does not get Unknown Command in console
        return PLUGIN_HANDLED;
    }

    //Reset vote counts from any previous votes
    gVotes[0] = gVotes[1] = 0;
    //Note that if you have more than 2 options, it would be better to use the line below:
    //arrayset( gVotes, 0, sizeof gVotes );

    //Store the menu in the global
    gVoteMenu = menu_create( "\rLook at this Vote Menu!:", "menu_handler" );

    //Add some vote options
    menu_additem( gVoteMenu, "Vote Option 1", "", 0 );
    menu_additem( gVoteMenu, "Vote Option 2", "", 0 );

    //We will need to create some variables so we can loop through all the players
    new players[32], pnum, tempid;

    //Fill players with available players
    get_players( players, pnum );

    //Start looping through all players to show the vote to
    for ( new i; i < pnum; i++ )
    {
        //Save a tempid so we do not re-index
        tempid = players[i];

        //Show the vote to this player
        menu_display( tempid, gVoteMenu, 0 );

        //Increase how many players are voting
        gVoting++;
    }

    //End the vote in 10 seconds
    set_task(10.0, "EndVote" );

    return PLUGIN_HANDLED;
 }
 public menu_handler( id, menu, item )
 {
    //If the menu was exited or if there is not a vote
    if ( item == MENU_EXIT || !gVoting )
    {
        //Note were not destroying the menu
        return PLUGIN_HANDLED;
    }

    //Increase the votes for what they selected
    gVotes[ item ]++;

    //Note were not destroying the menu
    return PLUGIN_HANDLED;
 }
 public EndVote()
 {
    //If the first option recieved the most votes
    if ( gVotes[0] > gVotes[1] )
        client_print(0, print_chat, "First option recieved most votes (%d )", gVotes[0] );

    //Else if the second option recieved the most votes
    else if ( gVotes[0] < gVotes[1] )
        client_print(0, print_chat, "Second option recieved most votes (%d )", gVotes[1] );

    //Otherwise the vote tied
    else
        client_print(0, print_chat, "The vote tied at %d votes each.", gVotes[0] );

    //Don't forget to destroy the menu now that we are completely done with it
    menu_destroy( gVoteMenu );

    //Reset that no players are voting
    gVoting = 0;
 }