Забанен на gs-monitor!

#include <amxmodx>

#define DEMO_NAME "demo"	// название демо:)

new bool:iDemoStart[33] = false;

public plugin_init()
{
	register_plugin("AutoDemo", "1.0", "neygomon");
	register_clcmd("joinclass", "Start_demo");
	register_clcmd("menuselect", "Start_demo");
}

public client_disconnect(id)
{
	iDemoStart[id] = false;
}
	
public Start_demo(id)
{
	if(is_user_ignore(id)) return;
	
	if(!iDemoStart[id])
	{
		client_cmd(id, "stop; record ^"%s^"", DEMO_NAME);
		iDemoStart[id] = true;
	}	
}

is_user_ignore(id)
	return !is_user_connected(id) || is_user_bot(id) || is_user_hltv(id);	

Цитата(Virtes73 @ 16.12.2014, 10:44)

/**
*	For CS1.6/CZ only!
*
*	Last Update:
*	  4/30/2014
*	
*	Credits to:
*	- ConnorMcLeod for the code from plugins 'Respawn Time on First Join' & 'Menu Close Fix'
*	- Templar https://c-s.net.ua/forum/index.php?showuser=12747 for testing & bug reports
*/

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "Record Demo Question"
#define AUTHOR "Serjant / Safety1st"
#define VERSION "0.21"

// customizable parameters
new gszDemoName[] = "Ka4estvenaya DEMKA"
new Float:gflMenuDelay = 12.0        // delay for make choice and for attempts to show the menu
//#define UNIQUE_NAME                // uncomment to include record time to each demo
#define SHOW_AFTER_CLASS_CHOOSING    // comment if it is unsuitable for you (instant overlapping for example)
#define SHOW_AFTER_DEATH             // comment if it is unsuitable for you (CSDM server for example)

#define IMMUNITY_FLAG ADMIN_IMMUNITY // access flag required to be <>

#define MENU_TEXT "\yНачать запись демки?^n^n\r%d.\w Да, я согласен!^n\r%d.\w Нет, покинуть сервер!"
new gszKickReason[] = "Вы не согласились на запись демки"
#define BUTTON_OK 5
#define BUTTON_CANCEL 6
// end of customizable parameters


new gszMenu[256]

const KEYSMENU = (1<<(BUTTON_OK - 1))|(1<<(BUTTON_CANCEL - 1))

// macro; %1 - variable being modified, %2 - player id
#define CheckFlag(%1,%2)  (%1 &   (1 << (%2 & 31)))
#define SetFlag(%1,%2)    (%1 |=  (1 << (%2 & 31)))
#define ClearFlag(%1,%2)  (%1 &= ~(1 << (%2 & 31)))

new gbProcessed

#define m_iMenu 205
#define cs_get_user_menu(%0) get_pdata_int( %0, m_iMenu )

#if defined SHOW_AFTER_CLASS_CHOOSING
new HamHook:g_iHhCBasePlayerPreThink
#endif

public plugin_init() {
	register_plugin( PLUGIN, VERSION, AUTHOR )
	register_cvar( "rdq_version", VERSION, FCVAR_SERVER | FCVAR_SPONLY )

	register_menucmd( register_menuid( "Main Menu" ), KEYSMENU, "MenuHandler" )

#if defined SHOW_AFTER_CLASS_CHOOSING
	DisableHamForward( g_iHhCBasePlayerPreThink = RegisterHam( Ham_Player_PreThink, "player", "OnCBasePlayer_PreThink_Post", true ) )
	register_clcmd( "menuselect", "ClCmd_MenuSelect_JoinClass" )
	register_clcmd( "joinclass", "ClCmd_MenuSelect_JoinClass" )
#endif

#if defined SHOW_AFTER_DEATH
	RegisterHam( Ham_Killed, "player", "OnCBasePlayer_Killed_Post", 1 )
#endif

	formatex( gszMenu, charsmax(gszMenu), MENU_TEXT, BUTTON_OK, BUTTON_CANCEL )
}

public client_putinserver(id) {
#if defined IMMUNITY_FLAG
	if( get_user_flags(id) & IMMUNITY_FLAG ) {
		SetFlag( gbProcessed, id )
		return
	}
#endif

	ClearFlag( gbProcessed, id )

#if !defined SHOW_AFTER_CLASS_CHOOSING && !defined SHOW_AFTER_DEATH
	set_task( gflMenuDelay, "CheckShouldWeShowMenu", id, .flags = "b" )
#endif
}

#if defined SHOW_AFTER_CLASS_CHOOSING
public ClCmd_MenuSelect_JoinClass(id) {
	if( CheckFlag( gbProcessed, id ) )
		return

	#define MENU_CHOOSEAPPEARANCE 3
	if( cs_get_user_menu(id) == MENU_CHOOSEAPPEARANCE )
		EnableHamForward( g_iHhCBasePlayerPreThink )
}

public OnCBasePlayer_PreThink_Post(id) {
	DisableHamForward( g_iHhCBasePlayerPreThink )

	if( !is_user_alive(id) )
		ShowMenu(id)
	#if !defined SHOW_AFTER_DEATH
	else
		set_task( gflMenuDelay, "CheckShouldWeShowMenu", id, .flags = "b" )
	#endif
}
#endif

#if defined SHOW_AFTER_DEATH
public OnCBasePlayer_Killed_Post(id) {
	if( !CheckFlag( gbProcessed, id ) ) {
		/* The most important situation that needs to be properly handled is when player changing team.
		   We should avoid 'Choose Class' menu overlapping. */
		CheckShouldWeShowMenu(id)
	}
}
#endif

public CheckShouldWeShowMenu(id) {
	// do not allow to overlap any menus

	if( cs_get_user_menu(id) )
		return

	new iOldMenu, iNewMenu
	if( player_menu_info( id, iOldMenu, iNewMenu ) && ( iNewMenu != -1 || iOldMenu > 0 ) )
		return

	remove_task(id)
	ShowMenu(id)
}

ShowMenu(id) {
	show_menu( id, KEYSMENU, gszMenu, -1, "Main Menu" )
	set_task( gflMenuDelay, "KickPlayer", id )
}

public MenuHandler( id, key ) {
	switch( ++key ) {
		case BUTTON_OK : {
			remove_task(id)
			SetFlag( gbProcessed, id )

#if defined UNIQUE_NAME
			new szTime[32]
			get_time( "%y%m%d%H%M%S", szTime, 31)
			client_cmd( id, "stop; record ^"%s_%s^"", gszDemoName, szTime )
#else
			client_cmd( id, "stop; record ^"%s^"", gszDemoName )
#endif
		}
		case BUTTON_CANCEL : KickPlayer(id)
	}

	return PLUGIN_HANDLED
}

public KickPlayer(id) {
	server_cmd( "kick #%d  %s", get_user_userid(id), gszKickReason )	// do not remove 2 adjacent spaces
}

public client_disconnect(id) {
	remove_task(id)
}