Автоматическое смена вида игры

#include <amxmodx>
#include <engine>

#define VERSION "1.1.1"

// Change [CLAN-TAG] to your clan name / server name
new const prefix[] = "[CLAN-TAG] Camera Changer:"

// HasView = 1 for 3rd person etc.
new HasView[33]

// This is the cvar if the Camera changer is active or not.
new gCameraActive

public plugin_init()
{
	// Plugin name, Version, Author.
	register_plugin( "Camera Changer", VERSION, "Larcyn")
	
	// Those 2 lines below are the commands that you use if you want to open the camera menu.
	register_clcmd("say /camera", "CmdChoose")
	register_clcmd("say /cam", "CmdChoose")
	
	// Change this cvar if you want to disable the Camera menu
	gCameraActive = register_cvar( "amx_cammenu", "1" ) // 0 Off, 1 On; Default 1
}

public CmdChoose(id)
{
	// If the cvar amx_cammenu is set to 0 players can't open the menu.
	if(get_pcvar_num(gCameraActive) != 0)
	{
		new viewmenu = menu_create( "\rCamera Chooser:", "ViewHandler")
		menu_additem(viewmenu, "\yInformation", "1", 0)
		menu_addblank(viewmenu, 0)
		menu_additem(viewmenu, "\y3rd Person View", "2", 0)
		menu_additem(viewmenu, "\yNormal View", "3", 0)
		menu_additem(viewmenu, "\yDrug View", "4", 0)
	
		menu_setprop(viewmenu, MPROP_EXIT, MEXIT_ALL)
		menu_display(id, viewmenu, 0)
		return PLUGIN_HANDLED
	}
	// If the camera menu is disabled, the message below will print to a client which wants to open the menu.
	client_print(id, print_chat, "%s Camera changer is currently disabled.", prefix)
	return PLUGIN_HANDLED
}

// Actions below
public ViewHandler(id, menu, item) 
{  
	if(item == MENU_EXIT) 
	{ 
		menu_destroy(menu)
		return PLUGIN_HANDLED
	} 
	new data[6], iName[64]
	new access, callback
	
	menu_item_getinfo( menu, item, access, data,5, iName, 63, callback ); 
	new key = str_to_num(data) 
	switch(key) 
	{ 
		case 1: 
		{
			client_print(id, print_chat, "This server is using Camera Changer Version %s by Larcyn", VERSION)
			CmdChoose(id)
			return PLUGIN_HANDLED
		} 
		case 2: 
		{
			if( HasView[id] == 1)
			{
				client_print(id, print_chat, "Error! You already have 3rd person view!")
				return PLUGIN_HANDLED
			}
			
			ResetFOV(id)	
			set_view(id, CAMERA_3RDPERSON)
			client_print(id, print_chat, "%s Your view is successfully changed to 3rd person!", prefix)
			
			HasView[id] = 1
		} 
		case 3:
		{
			if( HasView[id] == 2)
			{
				client_print(id, print_chat, "Error! You already have normal view!")
				return PLUGIN_HANDLED
			}
				
			ResetFOV(id)
			set_view(id, CAMERA_NONE)
			client_print(id, print_chat, "%s Your view is successfully changed back to normal!", prefix)
			
			HasView[id] = 2
		}
		case 4:
		{
			if( HasView[id] == 3)
			{
				client_print(id, print_chat, "Error! You already have drug view!")
				return PLUGIN_HANDLED
			}
			
			message_begin(MSG_ONE, get_user_msgid("SetFOV"), {0,0,0}, id)
			write_byte(170)
			message_end()
			
			set_view(id, CAMERA_NONE)
			client_print(id, print_chat, "%s Your view is successfully changed to drug view!", prefix)
			
			HasView[id] = 3
		}
	}
	return PLUGIN_HANDLED
}

public ResetFOV(id)
{
	message_begin(MSG_ONE, get_user_msgid("SetFOV"), {0,0,0}, id)
	write_byte(90)
	message_end()
}

// When player connect, it fixes so you got "normalview" on.
public client_putinserver(id)
{
	HasView[id] = 2
}

// This model is needed for 3rd view, if you remove the lines below your server will crash when someone press 3rd view.
public plugin_precache()
{
	precache_model("models/rpgrocket.mdl")
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1053\\ f0\\ fs16 \n\\ par }
*/

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <engine>

#define PLUGIN "3D Cam"
#define VERSION "0.1"
#define AUTHOR "igor_ok"

new bool:Cam[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_clcmd("say /cam", "func_cam");
}

public func_cam(id) {
	Cam[id] = !Cam[id];
	set_view(id, Cam[id]);
	client_print(id, print_chat, "3D Camera %s", (Cam[id]) ? "On" : "Off");
	return 1;
}

public client_disconnect(id) {
	Cam[id] = false;
}

#include <amxmodx>
#include <engine> 

new bool:HasView[33]

public plugin_init()
	register_clcmd("say /cam", "camera")

public plugin_precache()
	precache_model("models/rpgrocket.mdl")

public client_putinserver(id)
	HasView[id] = false

public camera(id) {
	if(HasView[id] == true) {
		resetfov(id)
		set_view(id, CAMERA_NONE)

		HasView[id] = false
	}
	else {
		resetfov(id)	
		set_view(id, CAMERA_3RDPERSON)

		HasView[id] = true
	}
	return PLUGIN_CONTINUE
}

public resetfov(id) {
	message_begin(MSG_ONE, get_user_msgid("SetFOV"), {0,0,0}, id)
	write_byte(90)
	message_end()
}