Меню

/*
* Server Menu:		https://c-s.net.ua/forum/topic46803.html
*  last update 12/24/2012
*  - легко конфигурируемое 'меню сервера'
*  - постоянное HUD-сообщение о способе открытия меню (можно выключить cvar'ом show_hudmsg)
*  - автоназначение игрокам кнопки открытия меню
*  - идеально подходит для говнопабликов :P
* 
* Внимание!
*  - для успешного компилирования плагина необходимо наличие в папке include файла dhudmessage.inc
*    его можно загрузить тут: https://forums.alliedmods.net/showthread.php?t=149210
*  - пункты меню не являются рекомендуемыми! они тупо перенесены из прототипа
*  - изменение show_hudmsg вступает в действие со следующей карты
* 
* Credits:
*   GopnikStyle for the prototype
*/

#include <amxmodx>
#include <dhudmessage>

#define PLUGIN "Server Menu"
#define VERSION "0.1"
#define AUTHOR "JIo6koBbIu BoJIoc xD"

new giMenu
new pShowHudMsg
new gszHudMsg[] = "Меню Сервера, нажми на N (nightvision)"

#define ITMS 0	// menu items
#define CMDS 1	// client commands

#define QNTY 10	// total entries
new gszArray[QNTY][2][] = {
	{ "\wПоздороваться", "say Ghbdtn dctv)" },
	{ "\rОбнулить \wСчет", "say /rs" },
	{ "\rЗабанить \wИгрока", "say /voteban" },
	{ "\rЗаткнуть \wИгрока", "say /mute" },
	{ "\rЛучшие \wИгроки Сервера", "say /top15" },
	{ "\rНастроить \wРейты \r[\dУменьшить Разброс\r]", "rate 25000;cl_cmdrate 101;cl_updaterate 101;fps_max 101" },
	{ "\rIP \wСерверa", "say /IP" },
	{ "\wПопрощаться", "say Gjrf dctv" },
	{ "\rКупить \wАдмику", "say /adminka " },
	{ "\rКупить \wVIP", "say /vipka" }
}

public plugin_init() {
	register_plugin( PLUGIN, VERSION, AUTHOR )
	register_clcmd( "amx_menu", "ShowMenu", ADMIN_ALL )
	register_clcmd( "say /menu", "ShowMenu", ADMIN_ALL )
	register_clcmd( "say_team /menu", "ShowMenu", ADMIN_ALL )
	register_clcmd( "nightvision", "ShowMenu", ADMIN_ALL )

	pShowHudMsg = register_cvar( "show_hudmsg", "1" )	// 1 - on, 0 - off
	set_task( 12.0, "CheckConfig" )

	giMenu = menu_create( "\yМеню Сервера", "MenuHandler", .ml = 0 /* Russian only, fucking 'UTF-8 inside SMA' style */ )
	new szInfo[3]
	for ( new i = 0; i < QNTY; i++ ) {
		num_to_str( i, szInfo, charsmax(szInfo) )
		menu_additem( giMenu, gszArray[i][ITMS], .info = szInfo )
	}

	menu_setprop( giMenu, MPROP_EXIT, MEXIT_ALL )
	menu_setprop( giMenu, MPROP_NEXTNAME, "Дальше" )
	menu_setprop( giMenu, MPROP_BACKNAME, "Назад" )
	menu_setprop( giMenu, MPROP_EXITNAME, "Выход" )
}

public CheckConfig() {
	if ( get_pcvar_num( pShowHudMsg) )
		set_task( 15.0, "ShowHudMsgTask", .flags = "b" )
}

public ShowHudMsgTask() {
	set_dhudmessage( 0, 255, 0, .x = 0.15, .y = 0.0, .effects = 0, .fxtime = 1.0, .holdtime = 15.5, .fadeintime = 0.1, .fadeouttime = 0.1 )
	show_dhudmessage( 0, gszHudMsg )
}

public ShowMenu(id) {
	menu_display( id, giMenu )

	return PLUGIN_HANDLED
}

public MenuHandler( id, menu, item ) {
	if ( item == MENU_EXIT )
		return PLUGIN_HANDLED

	new access, info[3], callback
	menu_item_getinfo( menu, item, access, info, charsmax(info), .callback = callback )
	client_cmd(id, gszArray[str_to_num(info)][CMDS] )

	return PLUGIN_HANDLED
}

public plugin_end() {
	menu_destroy(giMenu)
}