PLUGIN "Unlimited ChooseTeam (include Spectator!)"

#include <amxmodx>
#include <fakemeta>
#include <cstrike>

#define PLUGIN "Unlimited ChooseTeam (include Spectator!)"
#define AUTHOR "ConnorMcLeod & pic0 & PomanoB"
#define VERSION "1.0"

#define m_bHasChangeTeamThisRound 125
#define XO_PLAYER 5

new g_msgScoreAttrib
new bool:is_TeamMenu

public plugin_init()
{
	register_plugin( PLUGIN, VERSION, AUTHOR )
	
	register_clcmd("chooseteam", "cmdChooseTeam")
	
	register_clcmd("menuselect", "cmdMenuSelect")
	register_clcmd("jointeam 6", "cmdJoinSpec")
	register_message(get_user_msgid("ShowMenu"), "msgShowMenu")
	
	g_msgScoreAttrib = get_user_msgid("ScoreAttrib")
}


public cmdChooseTeam(id)
{
	if (is_user_alive(id))
	{
		message_begin(MSG_ONE, g_msgScoreAttrib, _, id)  // Thx to pic0
		write_byte(id)
		write_byte((1<<0))	// *DEAD*
		message_end()
	}
	if (is_user_connected(id))
		set_pdata_int(id, m_bHasChangeTeamThisRound, get_pdata_int(id, m_bHasChangeTeamThisRound, XO_PLAYER) & ~(1<<8), XO_PLAYER) // Thx to ConnorMcLeod
}

public msgShowMenu(msg, dest, id)
{
	static menuName[32]
	static const needName[] = "#IG_Team_Select"
	static const replaceName[] = "#IG_Team_Select_Spect"
	
	get_msg_arg_string(4, menuName, charsmax(menuName))
	
	if (!strcmp(menuName, needName))
	{
		set_msg_arg_string(4, replaceName)
		set_msg_arg_int(1, ARG_SHORT, 563)	// menu keys in binary format: 1, 2, 5, 6 and 0
		is_TeamMenu = true
	}
}

public cmdMenuSelect(id)
{
	if(is_TeamMenu)
	{
		is_TeamMenu = false
		new argv[32]
		read_argv(1, argv, charsmax(argv))
		if (is_user_alive(id) && argv[0] == '6')
			user_kill(id, 1)
	}
}

public cmdJoinSpec(id)
{
	if (is_user_alive(id))
		user_kill(id, 1)
}