Лучший игрок раунда

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>
#include <fakemeta>
#include <colorchat>

#define is_user_valid_connected(%1) (1 <= %1 <= g_iMaxPlayers && is_user_connected(%1))
  
enum _:score
{
   frags,
   Float:dmg,
   hs
}
   
new niceP[33][score]
   
new nMoney
new g_iMaxPlayers
   
public plugin_init()
{
   register_plugin("Nice Gamer", "1.0", "Got Milk?")
   
   RegisterHam(Ham_TakeDamage, "player", "hook_TakeDamage")
   register_event("DeathMsg", "Event_DeathMessage", "a")
   register_logevent("event_round_end", 2, "1=Round_End")
   register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
   nMoney   = register_cvar("nkiller_money", "1000")
   g_iMaxPlayers = get_maxplayers()
}
   
public event_round_end ()
{
   new Players[32], num, tmpf, Float:tmpd, tmpid
   get_players( Players, num )
   
   for( new i; i < 32; i++)
   {
      if ( niceP[i][frags] > tmpf )
      {
         tmpid = i
         tmpf = niceP[i][frags]
         tmpd = niceP[i][dmg]
      }
      else if ( niceP[i][frags] == tmpf && niceP[i][dmg] > tmpd)
      {
         tmpid = i
         tmpf = niceP[i][frags]
         tmpd = niceP[i][dmg]
      }
   }
   
   if ( tmpf > 0 )
   {
      new name[32];
      get_user_name(tmpid, name, 31);
   
      client_print_color(0, DontChange, "^1Лучшим игроком раунда стал ^4%s.", name )
      client_print_color(0, DontChange, "^1Убив ^4%d ^1игроков и нанеся ^4%d ^1урон.",  tmpf, floatround(tmpd, floatround_round))
       
      cs_set_user_money( tmpid, cs_get_user_money(tmpid) + get_pcvar_num(nMoney) )
      client_print_color( tmpid, DontChange, "^x3%s^x1 вы получили^x4 %d^x1 $ за то, что были лучшим в раунде.", name, get_pcvar_num(nMoney) )
   }
}
   
public hook_TakeDamage(Victim, inflictor, Attacker, Float:damage, damagebits)
{
   if(Victim == Attacker || !is_user_valid_connected(Attacker))
      return HAM_IGNORED
   if( inflictor == Attacker )
      niceP[Attacker][dmg] += damage
   else
   {
      static classname[32]
      pev (inflictor, pev_classname, classname, 31)
      if( equal (classname, "grenade") )
         niceP[Attacker][dmg] += damage
   }
   
   if ( get_pdata_int(Victim, 75, 5) == HIT_HEAD )
      niceP[Attacker][hs]++
   
   return HAM_IGNORED
}
   
public Event_DeathMessage()
   niceP[read_data(1)][frags]++
   
public event_round_start ( ) 
   for (new i; i < 32; i++)
      for ( new j; j < 3; j++)
         niceP[i][j] = 0
   
public client_disconnect(id)
   for ( new j; j < 3; j++)
      niceP[id][j] = 0