Когда перестанут заминать жалобы?

/* Plugin generated by AMXX-Studio */

//    Код парашютата был взят и переделан из плагина amx_parachute 1.3, авторы: KRoTaL/JTP10181
//    За что им большое спасибо

//    Квары:

//    parachute_fallspeed - скорость падения во время использования парашюта

#include <amxmodx>
#include <engine>
#include <fun>
#include <hamsandwich>


#define PLUGIN "[ZP] Parachute"
#define VERSION "1.0"
#define AUTHOR "Slavvkko"

new para_ent[33]
new pDetach, pFallSpeed, Float:gravity[33]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    pFallSpeed = register_cvar("parachute_fallspeed", "100")
    pDetach = register_cvar("parachute_detach", "1")
    register_event("DeathMsg", "death_event", "a")
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1)
}

public plugin_precache()
{
    precache_model("models/k_parachute.mdl")
}

public client_disconnect(id)
{
    parachute_reset(id)
}

public death_event()
{
    new id = read_data(2)
    parachute_reset(id)
}

parachute_reset(id)
{
    if(para_ent[id] > 0) {
        if (is_valid_ent(para_ent[id])) {
            remove_entity(para_ent[id])
        }
    }

    para_ent[id] = 0
}

public fw_PlayerSpawn_Post(id)
{
    if (!is_user_alive(id))
        return;
    
    gravity[id] = get_user_gravity(id)
}

public zp_user_infected_post(id, infector, nemesis)
{
    gravity[id] = get_user_gravity(id)
}

public zp_user_humanized_post(id, survivor)
{
    gravity[id] = get_user_gravity(id)
}

public client_PreThink(id)
{
    //parachute.mdl animation information
    //0 - deploy - 84 frames
    //1 - idle - 39 frames
    //2 - detach - 29 frames

    if (!is_user_alive(id)) return

    new Float:fallspeed = get_pcvar_float(pFallSpeed) * -1.0
    new Float:frame

    new button = get_user_button(id)
    new oldbutton = get_user_oldbutton(id)
    new flags = get_entity_flags(id)
    
    if (para_ent[id] > 0 && (flags & FL_ONGROUND)) {

        if (get_pcvar_num(pDetach)) {

            if (get_user_gravity(id) == 0.1) set_user_gravity(id, gravity[id])

            if (entity_get_int(para_ent[id],EV_INT_sequence) != 2) {
                entity_set_int(para_ent[id], EV_INT_sequence, 2)
                entity_set_int(para_ent[id], EV_INT_gaitsequence, 1)
                entity_set_float(para_ent[id], EV_FL_frame, 0.0)
                entity_set_float(para_ent[id], EV_FL_fuser1, 0.0)
                entity_set_float(para_ent[id], EV_FL_animtime, 0.0)
                entity_set_float(para_ent[id], EV_FL_framerate, 0.0)
                return
            }

            frame = entity_get_float(para_ent[id],EV_FL_fuser1) + 2.0
            entity_set_float(para_ent[id],EV_FL_fuser1,frame)
            entity_set_float(para_ent[id],EV_FL_frame,frame)

            if (frame > 254.0) {
                remove_entity(para_ent[id])
                para_ent[id] = 0
            }
        }
        else {
            remove_entity(para_ent[id])
            set_user_gravity(id, gravity[id])
            para_ent[id] = 0
        }

        return
    }

    if (button & IN_USE) {
        
        new Float:velocity[3]
        entity_get_vector(id, EV_VEC_velocity, velocity)

        if (velocity[2] < 0.0) {

            if(para_ent[id] <= 0) {
                para_ent[id] = create_entity("info_target")
                if(para_ent[id] > 0) {
                    entity_set_string(para_ent[id],EV_SZ_classname,"parachute")
                    entity_set_edict(para_ent[id], EV_ENT_aiment, id)
                    entity_set_edict(para_ent[id], EV_ENT_owner, id)
                    entity_set_int(para_ent[id], EV_INT_movetype, MOVETYPE_FOLLOW)
                    entity_set_model(para_ent[id], "models/k_parachute.mdl")
                    entity_set_int(para_ent[id], EV_INT_sequence, 0)
                    entity_set_int(para_ent[id], EV_INT_gaitsequence, 1)
                    entity_set_float(para_ent[id], EV_FL_frame, 0.0)
                    entity_set_float(para_ent[id], EV_FL_fuser1, 0.0)
                }
            }

            if (para_ent[id] > 0) {

                entity_set_int(id, EV_INT_sequence, 3)
                entity_set_int(id, EV_INT_gaitsequence, 1)
                entity_set_float(id, EV_FL_frame, 1.0)
                entity_set_float(id, EV_FL_framerate, 1.0)
                set_user_gravity(id, 0.1)

                velocity[2] = (velocity[2] + 40.0 < fallspeed) ? velocity[2] + 40.0 : fallspeed
                entity_set_vector(id, EV_VEC_velocity, velocity)

                if (entity_get_int(para_ent[id],EV_INT_sequence) == 0) {

                    frame = entity_get_float(para_ent[id],EV_FL_fuser1) + 1.0
                    entity_set_float(para_ent[id],EV_FL_fuser1,frame)
                    entity_set_float(para_ent[id],EV_FL_frame,frame)

                    if (frame > 100.0) {
                        entity_set_float(para_ent[id], EV_FL_animtime, 0.0)
                        entity_set_float(para_ent[id], EV_FL_framerate, 0.4)
                        entity_set_int(para_ent[id], EV_INT_sequence, 1)
                        entity_set_int(para_ent[id], EV_INT_gaitsequence, 1)
                        entity_set_float(para_ent[id], EV_FL_frame, 0.0)
                        entity_set_float(para_ent[id], EV_FL_fuser1, 0.0)
                    }
                }
            }
        }
        else if (para_ent[id] > 0) {
            remove_entity(para_ent[id])
            set_user_gravity(id, gravity[id])
            para_ent[id] = 0
        }
    }
    else if ((oldbutton & IN_USE) && para_ent[id] > 0 ) {
        remove_entity(para_ent[id])
        set_user_gravity(id, gravity[id])
        para_ent[id] = 0
    }
}