Bhop Detector

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "BhopHack Detector"
#define VERSION "0.3"
#define AUTHOR "Mistrick"

#pragma semicolon 1

#define MAX_WARN 5
#define MAX_WARN_TIME 10.0

new g_iJumpCount[33], g_iJumpButtonFrame[33], g_iOnGroundFrame[33], g_iBhopWarn[33], bool:g_bAlive[33], Float:g_fWarnTime[33];
new g_iSayText;

public plugin_init()
{
   register_plugin(PLUGIN, VERSION, AUTHOR);
   register_forward(FM_PlayerPreThink, "FM_PlayerPreThink_Pre", 0);
   RegisterHam(Ham_Killed, "player", "Ham_Player_Alive", 1);
   RegisterHam(Ham_Spawn, "player", "Ham_Player_Alive", 1);
  
   g_iSayText = get_user_msgid("SayText");
}
public client_disconnect(id)
{
   g_bAlive[id] = false;
}
public Ham_Player_Alive(id)
{
   g_bAlive[id] = bool:is_user_alive(id);
}
public FM_PlayerPreThink_Pre(id)
{
   if(!g_bAlive[id]) return FMRES_IGNORED;
    
   new iButtons; iButtons = pev(id, pev_button);
   new iOldButton; iOldButton = pev(id, pev_oldbuttons);
    
   if(iButtons & IN_JUMP)
   {
      g_iJumpButtonFrame[id]++;
   }
   if(iButtons & IN_JUMP && !(iOldButton & IN_JUMP))
   {
      g_iJumpCount[id]++;
   }
    
   new bool:bOnGround; bOnGround = bool:(pev(id, pev_flags) & FL_ONGROUND);
    
   if(bOnGround)
   {
      g_iOnGroundFrame[id] += 1;
   }
   else if(g_iOnGroundFrame[id])
   {
      //client_print(id, print_console, "OnGroundFrame is %d, JumpCount is %d; AvgFrame: %d", g_iOnGroundFrame[id], g_iJumpCount[id], g_iJumpButtonFrame[id] / g_iJumpCount[id]);
      
      if(g_iJumpCount[id] && g_iOnGroundFrame[id] <= 3 && (g_iJumpCount[id] < 5 || g_iJumpCount[id] > 16)
         && g_iJumpButtonFrame[id] / g_iJumpCount[id] < 5)
      {
         new Float:fTime = get_gametime();
         if(g_iBhopWarn[id] && fTime - g_fWarnTime[id] > MAX_WARN_TIME)
         {
            g_iBhopWarn[id] = 0;
         }
         g_fWarnTime[id] = fTime;
          
         if(++g_iBhopWarn[id] >= MAX_WARN)
         {
            Punish(id, "Bhop hack");
            g_iBhopWarn[id] = 0;
         }
      }
      
      g_iOnGroundFrame[id] = 0;
      g_iJumpCount[id] = 0;
      g_iJumpButtonFrame[id] = 0;
   }
    
   return FMRES_IGNORED;
}
public Punish(id, type[])
{
   new szName[32]; get_user_name(id, szName, charsmax(szName));
   ColorChat(0, "^3[AC] ^4%s ^3using ^4%s", szName, type);
}

stock ColorChat(const id, const input[], any:...) {
    new count = 1, players[32];
    static msg[191];
    vformat(msg, 190, input, 3);
    replace_all(msg, 190, "!g", "^4");
    replace_all(msg, 190, "!y", "^1");
    replace_all(msg, 190, "!t", "^3");
    if(id) players[0] = id;
    else get_players(players, count, "ch");
    for(new i = 0; i < count; i++) {
        if(is_user_connected(players[i])) {
            message_begin(MSG_ONE_UNRELIABLE, g_iSayText, _, players[i]);
            write_byte(players[i]);
            write_string(msg);
            message_end();
        }
    }
}