SameID

Здравствуйте.
Нужна помощь.

Код:

public client_putinserver(id)
{
 new steamid[32], userid; userid = get_user_userid(id)
 get_user_authid(id, steamid, 31)
 
 if(is_playing_already(steamid))
 {
  server_cmd("kick #%i ^"На сервере уже есть игрок с этим SteamID^"", userid)
 }
}

bool:is_playing_already(steamid[]){   return find_player("c", steamid) ? true : false}

В этом случае плагин будет искать игрока с таким же стим ид, как и у обрабатываемого. Но найдёт его же (обрабатываемого игрока) и кикнет.
Нужно, чтобы обрабатываемый игрок не учитывался.
Буду благодарен за помощь.

KPOCT, увы, не получится это сделать, функцией это не предусмотрено.
Как вариант можно запивать authid игрока в общий массив игроков и сравнивать данные при входе.

Код:

#include <amxmodx>

#define PLUGIN "Anti Double AuthID"
#define VERSION "0.1 Fix"
#define AUTHOR "Fintok!"

#define MAX_PLAYERS 32

new bool:g_bIsPlayer[MAX_PLAYERS + 1]
new g_szAuthIDs[MAX_PLAYERS + 1][35]
new Trie:g_tAuthIDs

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	g_tAuthIDs = TrieCreate()
}

public client_authorized(id)
{
	if(!(g_bIsPlayer[id] = bool:(!is_user_bot(id) && !is_user_hltv(id))))
		return

	get_user_authid(id, g_szAuthIDs[id], charsmax(g_szAuthIDs[]))

	if(TrieKeyExists(g_tAuthIDs, g_szAuthIDs[id]))
		server_cmd("kick #%i ^"На сервере уже есть игрок с этим SteamID^"", get_user_userid(id))
}

public client_putinserver(id)
{
	if(!g_bIsPlayer[id])
		return

	if(is_valid_authid(g_szAuthIDs[id]))
		TrieSetCell(g_tAuthIDs, g_szAuthIDs[id], 1)
}

public client_disconnect(id)
{
	if(!g_bIsPlayer[id])
		return

	TrieDeleteKey(g_tAuthIDs, g_szAuthIDs[id])

	g_szAuthIDs[id][0] = '^0'
}

public plugin_end()
	TrieDestroy(g_tAuthIDs)

stock is_valid_authid(const szAuthID[])
{
	static const szAuthIDs[][] = { "STEAM_ID_LAN", "STEAM_ID_PENDING", "VALVE_ID_LAN", "VALVE_ID_PENDING", "STEAM_666:88:666" }

	for(new i = 0; i <= charsmax(szAuthIDs); i++)
	{
		if(equali(szAuthID, szAuthIDs[i]))
			return false
	}
	return true
}

Спасибо большое, но, как видите, это не помогло.
У меня получилось зайти. Дело в том, что, если подключаться одновременно, то можно обойти проверку.
К слову, в плагине BanIP fakes это предусмотрено.

А почему просто не включить соль в dproto?

floricus, соль не защищает от одинаковых authid на сервере.
Если злоумышленник будет знать реальный authid жертвы, то он сможет его подменить и в итоге получится дубль.

KPOCT, ничего страшного, попробуй тогда такой вариант.
Насчет BanIP fakes, не знаю, не видел его.

Код:

#include <amxmodx>

#define PLUGIN "Anti Double AuthID"
#define VERSION "0.2"
#define AUTHOR "Fintok!"

#define MAX_PLAYERS 32

new bool:g_bIsPlayer[MAX_PLAYERS + 1]
new g_szAuthIDs[MAX_PLAYERS + 1][35]
new Trie:g_tAuthIDs

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	g_tAuthIDs = TrieCreate()
}

public client_putinserver(id)
{
	if(!(g_bIsPlayer[id] = bool:(!is_user_bot(id) && !is_user_hltv(id))))
		return

	get_user_authid(id, g_szAuthIDs[id], charsmax(g_szAuthIDs[]))

	if(!is_valid_authid(g_szAuthIDs[id]))
		return

	if(!TrieKeyExists(g_tAuthIDs, g_szAuthIDs[id]))
		TrieSetCell(g_tAuthIDs, g_szAuthIDs[id], id)
	else
		server_cmd("kick #%i ^"На сервере уже есть игрок с этим SteamID^"", get_user_userid(id))
}

public client_disconnect(id)
{
	if(!g_bIsPlayer[id])
		return

	static iUserId
	TrieGetCell(g_tAuthIDs, g_szAuthIDs[id], iUserId)

	if(iUserId == id)
		TrieDeleteKey(g_tAuthIDs, g_szAuthIDs[id])

	g_szAuthIDs[id][0] = '^0'
}

public plugin_end()
	TrieDestroy(g_tAuthIDs)

stock is_valid_authid(const szAuthID[])
{
	static const szAuthIDs[][] = { "STEAM_ID_LAN", "STEAM_ID_PENDING", "VALVE_ID_LAN", "VALVE_ID_PENDING", "STEAM_666:88:666" }

	for(new i = 0; i <= charsmax(szAuthIDs); i++)
	{
		if(equali(szAuthID, szAuthIDs[i]))
			return false
	}
	return true
}

Преогромное спасибо :) Работает.

Fintok, извиняюсь, но нажать на "Спасибо" не могу, потому как не "насобирал" 15 сообщений.

KPOCT, да ничего страшного, как нибудь тогда в другой раз поставишь.