Магазин золотого оружия

#include <amxmodx>
#include <fakemeta>
#include <fakemeta_util>
#include <fun>
#include <hamsandwich>
#include <cstrike>
#include <colorchat>

#define is_valid_player(%1) (1 <= %1 <= 32)

new const DGL_BIT_SUM = (1<<CSW_DEAGLE)

new DGL_V_MODEL[64] = "models/v_deagles.mdl"
new DGL_P_MODEL[64] = "models/p_deagles.mdl"
new DGL_W_MODEL[64] = "models/w_deagles.mdl"

new gold_damage, golden_model, golddgl_cost
new bool:g_HasDGL[33]

public plugin_init() {
    register_plugin("Gold Deagle", "1.0", "Alienware")
    register_clcmd("say /goldegl", "cmdGoldenDGL")
    register_clcmd("goldegl", "cmdGoldenDGL")
    
    gold_damage = register_cvar("goldendgl_dmg", "3")
    golden_model = register_cvar("goldendgl_custommodel", "1")
    golddgl_cost = register_cvar("goldendgl_cost", "6000")
      
    register_event("DeathMsg", "Death", "a")
    register_event("WeapPickup", "checkModel", "b","1=19")
    register_event("CurWeapon", "checkWeapon", "be","1=1")

    RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
    RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)
        
    register_forward(FM_SetModel, "fw_SetModel")
}

public client_connect(id)
    g_HasDGL[id] = false

public client_disconnect(id)
    g_HasDGL[id] = false

public Death()
    g_HasDGL[read_data(2)] = false

public fwHamPlayerSpawnPost(id)
    g_HasDGL[id] = false
    
public plugin_precache() {
    precache_model(DGL_V_MODEL)
    precache_model(DGL_P_MODEL)
    precache_model(DGL_W_MODEL)
}

public cmdGoldenDGL(id) {
    if(!is_user_alive(id)) return
    
    new money = cs_get_user_money(id)
    
    if(money < get_pcvar_num(golddgl_cost)) {
        ColorChat(id, GREEN, "^x01У вас недостаточно денег")
        return
    }
    
    drop_weapon(id, 1)                
    give_item(id, "weapon_deagle")
    cs_set_user_bpammo(id, CSW_DEAGLE, 35)
    cs_set_user_money(id, money - get_pcvar_num(golddgl_cost))
    ColorChat(id, GREEN, "^x01[^x04Сервер^x01] Вы купили^x04 Gold Deagle")
    g_HasDGL[id] = true
}

public checkModel(id) {      
    new szWeapID = read_data(2)
      
    if(szWeapID == CSW_DEAGLE && g_HasDGL[id] == true && get_pcvar_num(golden_model) == 1) {
        set_pev(id, pev_viewmodel2, DGL_V_MODEL)
        set_pev(id, pev_weaponmodel2, DGL_P_MODEL)
    }
    return PLUGIN_HANDLED
}

public checkWeapon(id) {
    new plrWeapId
    plrWeapId = get_user_weapon(id)

    if (plrWeapId == CSW_DEAGLE && g_HasDGL[id])
        checkModel(id)
    else
        return PLUGIN_CONTINUE
    
    return PLUGIN_HANDLED
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage) {
    if(is_valid_player(attacker) && get_user_weapon(attacker) == CSW_DEAGLE && g_HasDGL[attacker])
        SetHamParamFloat(4, damage * get_pcvar_float(gold_damage))
}

public fw_SetModel(entity, model[]) {
    if(!pev_valid(entity))
        return FMRES_IGNORED
    
    static szClassName[33]
    pev(entity, pev_classname, szClassName, charsmax(szClassName))
    
    if(!equal(szClassName, "weaponbox"))
        return FMRES_IGNORED
    
    static id
    id = pev(entity, pev_owner)
    
    if(equal(model, "models/w_deagle.mdl")) {
        static weapon
        weapon = fm_find_ent_by_owner(-1, "weapon_deagle", entity)
      
        if(!pev_valid(weapon))
            return FMRES_IGNORED
      
        if(g_HasDGL[id]) {
            set_pev(weapon, pev_impulse, 1942)
            engfunc(EngFunc_SetModel, entity, DGL_W_MODEL)
            return FMRES_SUPERCEDE
        }
    }
    return FMRES_IGNORED
}

stock drop_weapon(id, dropwhat) {
    static weapons[32], num, i, weaponid
    num = 0
    get_user_weapons(id, weapons, num)
    
    for (i = 0; i < num; i++) {
        weaponid = weapons[i]
        
        if ((dropwhat == 1 && ((1<<weaponid) & DGL_BIT_SUM))) {
            static wname[32]
            get_weaponname(weaponid, wname, charsmax(wname))
            engclient_cmd(id, "drop", wname)
        }
    }
}