Открытие меню через n секунд

Цитата(DRIVE37 @ 14.11.2015, 2:04)

/**
*   Modified by Safety1st
*
*   Home post:
*     <a href="https://c-s.net.ua/forum/ipb.html?act=findpost&pid=860557" target="_blank">https://c-s.net.ua/forum/index.php?act=find...&pid=860557</a>
*
*   Last update:
*     11/14/2015
*
*   Changes:
*   • next use menu limit is preserved between connects
*   • a lot optimizations
*/
 
#include <amxmodx>
#include <fakemeta>
#if AMXX_VERSION_NUM < 183
#include <dhudmessage>
#endif
 
#define ADMIN_ACCESS   ADMIN_LEVEL_A
#define VIP_ACCESS      ADMIN_LEVEL_H
 
#define OFFSET_CSMONEY   115
 
new g_iStartPlugin, g_pMoneyDelay;
new CountHpAp[33], CountMoney[33]; 
 
new giNextUse[33]
new giTimeLimit = 300
 
new yes[33];
 
new Trie:g_tMoney;
new Trie:g_tHpAp;
new Trie:g_tNextUse
 
public plugin_init()
{
   #define PLUGIN "Admin Menu"
   #define VERSION "1.0.4"
 
   register_plugin(PLUGIN, VERSION, "Realution");
    
   register_clcmd("menu_admin", "Check_Player");
   register_clcmd("menu_vip", "Check_Player");
    
   g_pMoneyDelay = register_cvar("am_money_delay", "5");
 
   register_message(get_user_msgid("ScoreAttrib"), "MessageScoreAttrib");
   register_menucmd(register_menuid(PLUGIN), MENU_KEY_1|MENU_KEY_2|MENU_KEY_0, "HandleMenu");
    
   g_iStartPlugin = get_systime();   
    
   g_tMoney = TrieCreate();
   g_tHpAp = TrieCreate();
   g_tNextUse = TrieCreate();
}
 
public client_disconnect(id) {
   if ( !giNextUse[id] )
      // he is not privileged player
      return
 
   new auth_id[32];
   get_user_authid(id, auth_id, 31);
 
   TrieSetCell(g_tMoney, auth_id, CountMoney[id]);
   TrieSetCell(g_tHpAp, auth_id, CountHpAp[id]);
   TrieSetCell(g_tNextUse, auth_id, giNextUse[id])
 
   CountHpAp[id] = 0;
   CountMoney[id] = 0;
   giNextUse[id] = 0
}
 
public client_authorized(id) {
   yes[id] = 0;
   new iFlags = get_user_flags(id)
   if( !( iFlags & VIP_ACCESS|ADMIN_ACCESS ) )
      return
 
   new name[32]; get_user_name(id, name, 31);
   new auth_id[32]; get_user_authid(id, auth_id, 31);
   new iSetDefaultValues
 
   if( TrieGetCell( g_tNextUse, auth_id, giNextUse[id] ) ) {
      // privileged player is found in base
      TrieGetCell(g_tMoney, auth_id, CountMoney[id]);
      TrieGetCell(g_tHpAp, auth_id, CountHpAp[id]);
   }
   else {
      giNextUse[id] = get_systime() + giTimeLimit
      iSetDefaultValues = 1
   }
 
   if( iFlags & VIP_ACCESS|ADMIN_ACCESS == VIP_ACCESS|ADMIN_ACCESS ) { 
      set_dhudmessage(0, 200, 0, -1.0, 0.25, 1, 0.0, 3.0, 0.0, 0.0);
      show_dhudmessage(0, "Админ + Вип [ ^4%s^1 ] зашел на сервер!", name);
      if ( iSetDefaultValues ) {
         CountMoney[id] = 10;
         CountHpAp[id] = 20;
      }
   }
   else if( iFlags & ADMIN_ACCESS ) {
      set_dhudmessage(200, 0, 0, -1.0, 0.25, 1, 0.0, 3.0, 0.0, 0.0);
      show_dhudmessage(0, "Админ [ ^4%s^1 ] зашел на сервер!", name);
      if ( iSetDefaultValues ) {
         CountMoney[id] = 5;
         CountHpAp[id] = 15;
      }
   }
   else {
      set_dhudmessage(0, 200, 0, -1.0, 0.25, 1, 0.0, 3.0, 0.0, 0.0);
      show_dhudmessage(0, "Вип [ ^4%s^1 ] зашел на сервер!", name);
      if ( iSetDefaultValues ) {
         CountMoney[id] = 5;
         CountHpAp[id] = 15;
      }
   }
}
 
public Check_Player(id)
{
   if(!is_user_alive(id))
      return ChatColor(id, "^1[^4%s^1] ^1Вы должны быть живы, чтобы использовать меню!", PLUGIN, PLUGIN);
    
   if(!(get_user_flags(id) & (ADMIN_ACCESS | VIP_ACCESS)))
      return ChatColor(id, "^1[^4%s^1] ^1У вас нет доступа к меню!", PLUGIN);
    
   return AdminMenu(id);
}
 
public AdminMenu(id) {
   new iLeft = giNextUse[id] - get_systime()
   if ( iLeft > 0 && yes[id] == 0)
      ChatColor(id, "^1Будет доступно через ^4%d ^1сек", iLeft);
   else {
      new szMenu[512], iLen, iKeys = MENU_KEY_0;
      iLen = formatex(szMenu, charsmax(szMenu), "\rАдмин\d|\rVIP Меню^n^n");
       
      iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\r1. \wВзять \r[\y255 жизни + брони\r] \d[\r%d\d]^n", CountHpAp[id]);
      iKeys |= MENU_KEY_1;
       
      if(get_systime() - g_iStartPlugin < get_pcvar_num(g_pMoneyDelay) * 60)
      {
         new iMin = 1 + (get_pcvar_num(g_pMoneyDelay) * 60 - (get_systime() - g_iStartPlugin)) / 60;
         new szMin[16]; get_ending(iMin, "минут", "минута", "минуты", szMin, charsmax(szMin));
         iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\r2. \wВзять \r[\y16000$\r] \d[\rподождите: %d %s\d]^n^n", iMin, szMin);
      }
      else
      {
         iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\r2. \wВзять \r[\y16000$\r] \d[\r%d\d]^n^n", CountMoney[id]);
         iKeys |= MENU_KEY_2;
      }
 
      formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\r0. \wВыход");
      show_menu(id, iKeys, szMenu, -1, PLUGIN);
      yes[id] = 1;
   } 
 
   return PLUGIN_HANDLED;
}
 
public HandleMenu(id, iKey) {
   switch(iKey) {
      case 0: {
         if( !CountHpAp[id] ) return AdminMenu(id);
         fm_set_user_health(id, 255);
         fm_set_user_armor(id, 255);
         CountHpAp[id]--;
         ChatColor(id, "^1[^4%s^1] ^1Вы взяли ^4жизни и броню^1! Осталось раз: ^4%d^1.", PLUGIN, CountHpAp[id]);
      }
      case 1: {
         if( !CountMoney[id] ) return AdminMenu(id);
         fm_set_user_money(id, fm_get_user_money(id) + 16000);
         CountMoney[id]--;
         ChatColor(id, "^1[^4%s^1] ^1Вы взяли^4 16000$^1! Осталось раз: ^4%d^1.", PLUGIN, CountMoney[id]);
      }
   }
 
   giNextUse[id] = get_systime() + giTimeLimit
   return PLUGIN_HANDLED;
}
 
public MessageScoreAttrib(iMsgId, iDest, iReceiver) {
   /* original code by xpaw & Radius */
   #define ARG_PlayerID    1
   #define ARG_Flags       2
   #define SCOREBOARD_VIP  (1 << 2)
 
   if( get_user_flags( get_msg_arg_int(ARG_PlayerID) ) & VIP_ACCESS )
      set_msg_arg_int( ARG_Flags, ARG_BYTE, get_msg_arg_int(ARG_Flags) | SCOREBOARD_VIP )
}
 
stock fm_set_user_armor(id, armor) {
   const m_iKevlar = 112
   const CS_ARMOR_VESTHELM = 2
   set_pev(id, pev_armorvalue, float(armor));
 
   set_pdata_int( id, m_iKevlar, CS_ARMOR_VESTHELM );
 
   static gmsgArmorType
   if( !gmsgArmorType )
      gmsgArmorType = get_user_msgid( "ArmorType" )
 
   message_begin( MSG_ONE_UNRELIABLE, gmsgArmorType, _, id );
   write_byte(1);   // draw icon in case of CS_ARMOR_VESTHELM
   message_end();
 
   return 1;
}
 
stock fm_set_user_health(id, health) 
{
   health > 0 ? set_pev(id, pev_health, float(health)) : dllfunc(DLLFunc_ClientKill, id);
   return 1;
}
 
stock fm_set_user_money(id, money, flash = 0)
{
   set_pdata_int(id, OFFSET_CSMONEY, money);
   message_begin(MSG_ONE, get_user_msgid("Money"), {0,0,0}, id);
   write_long(money);
   write_byte(flash);
   message_end();
}
 
stock fm_get_user_money(id)
return get_pdata_int(id, OFFSET_CSMONEY, 5);
 
stock get_ending(num, const a[], const b[], const c[], output[], lenght)
{
   new num100 = num % 100, num10 = num % 10;
   if(num100 >=5 && num100 <= 20 || num10 == 0 || num10 >= 5 && num10 <= 9) format(output, lenght, "%s", a);
   else if(num10 == 1) format(output, lenght, "%s", b);
   else if(num10 >= 2 && num10 <= 4) format(output, lenght, "%s", c);
}
 
stock ChatColor(const id, const szMessage[], any:...)
{
   static pnum, players[32], szMsg[190], IdMsg; 
   vformat(szMsg, charsmax(szMsg), szMessage, 3);
    
   if(!IdMsg) IdMsg = get_user_msgid("SayText");
    
   if(id) 
   { 
      players[0] = id;
      pnum = 1; 
   } 
   else get_players(players, pnum, "ch");
    
   for(new i; i < pnum; i++)
   {
      message_begin(MSG_ONE, IdMsg, .player = players[i]);
      write_byte(players[i]);
      write_string(szMsg);
      message_end();
   }
   return 1;
}