Steam Bonus

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define MONEY_SIZE 1000    //Кол-во выдаваемых денег игроку.

new const MESSAGE[] = "Спасибо, что использует лицензионную версию игры.";

new bool:gbSteam[33], giRoundCount, giBonusCount[33][2];

public plugin_init()
{
    register_plugin("Steam Bonus", "1.0", "DUKKHAZ0R");
    register_event("HLTV", "eRoundStart", "1=0", "2=0");
    RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost");
}

public eRoundStart() giRoundCount++;

public client_putinserver(id)
{
    switch(is_user_steam(id))
    {
        case true:
        {
            gbSteam[id] = true;
            set_task(10.0, "ShowDhudInfo", id);
        }
        case false: gbSteam[id] = false;
    }
    giBonusCount[id][0] = giBonusCount[id][1] = 0;
}

public ShowDhudInfo(id)
{
    if(!is_user_connected(id)) return;
    set_hudmessage(0, 255, 0, 0.01, 0.20, 0, 6.0, 6.0);
    show_hudmessage(id, MESSAGE);
    ChatColor(id, "^1Вы используете ^3STEAM ^1и за это вы будете получать бонусы!");
}

public fwHamPlayerSpawnPost(id)
{
    static const szBonusMessages[] = {"Смок", "Флешку", "1000$"};
    
    switch(giRoundCount > 2 && ++giBonusCount[id][0] >= 3 && gbSteam[id] && is_user_alive(id))
    {
        case 1:
        {
            switch(giBonusCount[id][1]++)
            {
                case 0: give_item(id, "weapon_smokegrenade");
                case 1: give_item(id, "weapon_flashbang");
                case 2:
                {
                    giBonusCount[id][1] = 0;
                    cs_set_user_money(id, cs_get_user_money(id) + MONEY_SIZE);
                }
            }
            giBonusCount[id][0] = 0;
            ChatColor(id, "^1[^4SteamBonus^1] Бонус за использование ^3steam^1: ^4%s", szBonusMessages[giBonusCount[id][1]]);
        }
    }
}

stock ChatColor(const id, const szRawMessage[], any:...)
{
    if(!is_user_connected(id)) return;
    static szMsg[191]; vformat(szMsg, charsmax(szMsg), szRawMessage, 3);
    message_begin(MSG_ONE_UNRELIABLE, 76, .player = id);
    write_byte(id);
    write_string(szMsg);
    message_end();
}

stock bool:is_user_steam(const id)
{
    static dp_pointer; if(!dp_pointer) dp_pointer = get_cvar_pointer("dp_r_id_provider");
    server_cmd("dp_clientinfo %d", id);
    server_exec();
    return get_pcvar_num(dp_pointer) == 2 ? true : false;
}

/*
* Обновление 28.09.2014
* v1.1 -     
    Исправлены ошибки
    Оптимизирован код
    Выдавание бонусов теперь по очереди
    Добавлено приветственное DHUD сообщение
*
* Обновление 06.03.2015
* v1.2 -
    Исправлено предупреждение при компиляции на AMXX ниже 1.8.3
    Добавлен вывод второго DHUD сообщения, чтобы помещался ник
*/

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>
#include <dhudmessage>

#if AMXX_VERSION_NUM < 183
    #include <colorchat>
    
    #define client_print_color    ColorChat
    #define print_team_red    RED
#endif

#pragma semicolon    1

#define PLUGIN    "Steam Bonus"
#define VERSION    "1.2"
#define AUTHOR    "Stimul"
#define PREFIX    "[Steam бонус]"

#define get_bit(%1,%2)    (%1 & (1 << (%2 & 31)))
#define set_bit(%1,%2)    (%1 |= (1 << (%2 & 31)))
#define reset_bit(%1,%2)    (%1 &= ~(1 << (%2 & 31)))

// Цвет DHUD сообщения
#define COLOR_RED    random(255)    // Количество красного цвета
#define COLOR_GREEN    random(255) // Количество зелёного цвета
#define COLOR_BLUE    random(255)    // Количество синего цвета

#define TIME    10.0    // Время показа

#define NUM_MONEY    1000    // Количество денег

new g_bIsConnected;
new g_bIsSteam;
new g_bProcedure;
new g_Round;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_event("HLTV", "event_round_start", "a", "1=0", "2=0");
    register_event("TextMsg", "event_restart_game", "a", "2=#Game_Commencing", "2=#Game_will_restart_in");
    
    RegisterHam(Ham_CS_RoundRespawn, "player", "fw_CS_RoundRespawn_Post", true);
}

public event_round_start()
{
    g_Round++;
}

public event_restart_game()
{
    g_Round = 0;
}

public client_putinserver(id)
{
    set_bit(g_bIsConnected, id);
    
    if(is_user_steam(id))
    {
        set_bit(g_bIsSteam, id);
        reset_bit(g_bProcedure, id);
        set_task(3.0, "WelcomeMessage", id);
    }
    else
        reset_bit(g_bIsSteam, id);
}

public client_disconnect(id)
    reset_bit(g_bIsConnected, id);

public WelcomeMessage(id)
{
    if(get_bit(g_bIsConnected, id))
    {
        static szName[32];
        get_user_name(id, szName, charsmax(szName));
        
        set_dhudmessage(COLOR_RED, COLOR_GREEN, COLOR_BLUE, -1.0, 0.3, 0, 0.0, TIME);
        show_dhudmessage(id, "Привет, %s!", szName);
        set_dhudmessage(COLOR_RED, COLOR_GREEN, COLOR_BLUE, -1.0, 0.34, 0, 0.0, TIME);
        show_dhudmessage(id, "У тебя Steam, поэтому с 3 Раунда ты будешь получать бонусы");
    }
}

public fw_CS_RoundRespawn_Post(id)
{
    if(g_Round >= 3 && get_bit(g_bIsConnected, id) && get_bit(g_bIsSteam, id))
    {
        if(!get_bit(g_bProcedure, id))
        {
            cs_set_user_money(id, cs_get_user_money(id) + NUM_MONEY);
            client_print_color(id, print_team_red, "^3%s ^1Ты получаешь бонус: ^4'%d$'", PREFIX, NUM_MONEY);
            set_bit(g_bProcedure, id);
        }
        else
        {
            give_item(id, "weapon_hegrenade");
            give_item(id, "weapon_flashbang");
            cs_set_user_bpammo(id, CSW_FLASHBANG, 2);
            give_item(id, "weapon_smokegrenade");
            client_print_color(id, print_team_red, "^3%s ^1Ты получаешь бонус: ^4'все гранаты'", PREFIX);
            reset_bit(g_bProcedure, id);
        }
    }
}

stock bool:is_user_steam(id)
{
    static dp_pointer;
    
    if(dp_pointer || (dp_pointer = get_cvar_pointer("dp_r_id_provider")))
    {
        server_cmd("dp_clientinfo %d", id);
        server_exec();
        return (get_pcvar_num(dp_pointer) == 2) ? true : false;
    }
    
    new szAuthid[34];
    get_user_authid(id, szAuthid, charsmax(szAuthid));
    
    return (containi(szAuthid, "LAN") < 0);
}