Свинорез

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <dhudmessage>
#include <hamsandwich>
#include <colorchat>
 
#define PLUGIN "Svinorez"
#define VERSION "1.0"
#define AUTHOR "Justick"
 
new g_Svinorez
 
public plugin_init()
   {
      register_plugin(PLUGIN, VERSION, AUTHOR)
    
      register_event("DeathMsg", "death_message", "a", "1>0")
      register_event("CurWeapon", "current_weapon", "be", "1=1", "2=29")
    
      RegisterHam(Ham_Spawn, "player", "player_spawn", 1)
   }
 
public plugin_precache()
   {
      precache_sound("svinorez/svinorez_act.wav") 
   }
 
public death_message()
   {
      new killer = read_data(1)
      new weapon[32]
      read_data(4, weapon, 31)
    
      if(equal(weapon, "knife") && killer != g_Svinorez)
      {
         client_cmd(0, "spk sound/svinorez/svinorez_act.wav") 
          
         set_dhudmessage(0, 155, 255, -1.0, 0.55, 0, 0.0, 1.0, 3.0, 1.5) 
         show_dhudmessage(killer, "Ты зарезал кабанчика и получаешь уникальный скин")
          
         g_Svinorez = killer
          
         new name[32]
         get_user_name(killer, name, 31)
         ColorChat(0, TEAM_COLOR, "^1[^4Свинорез^1] Игрок [^4%s^1] зарезал кабанчика и стал ^3свинорезом", name)
      }
   }

/*
*	It is modified plugin not the original.
*	  See Свинорез
*
*	The author of the modification:
*	  Fintok!
*
*	Last update:
*	  08/03/2016
*
*	Changes:
*	- Refactoring and bug fixing in the code of plugin
*
*	Credits:
*	- The original idea of the plugin belongs to xxf3mzue
*	- The original code belongs to Justick
*/

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <dhudmessage>

#if AMXX_VERSION_NUM < 183
	#include <colorchat>

	#define print_team_default	DontChange
	#define print_team_grey		Grey
	#define print_team_red		Red
	#define print_team_blue 	Blue
#endif

#define PLUGIN "Svinorez"
#define VERSION "0.1 Light"
#define AUTHOR "Fintok!"

#define MAX_PLAYERS 32

#define is_user_valid_connected(%1) (1 <= %1 <= g_iMaxPlayers && is_user_connected(%1))

new const SOUND_KILLING[] = "misc/svinorez/svinorez_act.wav"

const PDATA_SAFE = 2
const OFFSET_LINUX_WEAPONS = 4

const m_pActiveItem = 373
const m_iId = 43

new bool:g_bSvinorez[MAX_PLAYERS + 1]
new g_iMaxPlayers

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	RegisterHam(Ham_Killed, "player", "Fwd_PlayerKilled_Post", 1)

	g_iMaxPlayers = get_maxplayers()
}

public plugin_precache()
	precache_sound(SOUND_KILLING)

public Fwd_PlayerKilled_Post(victim, killer, shouldgib)
{
	if(!is_user_valid_connected(killer) || killer == victim)
		return

	static iWeaponId
	iWeaponId = fm_get_weapon_killer(victim, killer)

	if(iWeaponId != CSW_KNIFE)
		return

	if(!g_bSvinorez[killer])
	{
		g_bSvinorez[killer] = true

		client_cmd(0, "stopsound; spk %s", SOUND_KILLING)

		set_dhudmessage(0, 155, 255, -1.0, 0.55, 0, 0.0, 1.0, 3.0, 1.5)
		show_dhudmessage(killer, "Ты зарезал кабанчика и стал свинорезом!")

		static szName[32]
		get_user_name(killer, szName, charsmax(szName))

		client_print_color(0, print_team_default, "^1[^4Свинорез^1] Игрок ^4%s^1 зарезал кабанчика и стал ^3свинорезом", szName)
	}

	if(g_bSvinorez[victim])
		g_bSvinorez[victim] = false
}

public client_disconnect(id)
	g_bSvinorez[id] = false

stock fm_get_weapon_killer(victim, killer)
{
	if(pev_valid(killer) != PDATA_SAFE)
		return 0

	static iInflictor
	iInflictor = pev(victim, pev_dmg_inflictor)

	if(iInflictor != killer) 
		return 0

	static iWeaponEnt
	iWeaponEnt = get_pdata_cbase(killer, m_pActiveItem)

	if(pev_valid(iWeaponEnt) != PDATA_SAFE)
		return 0

	static iWeaponId
	iWeaponId = get_pdata_int(iWeaponEnt, m_iId, OFFSET_LINUX_WEAPONS)

	return iWeaponId
}