Свинорез

/*
*	It is modified plugin not the original.
*	  See Свинорез
*
*	The author of the modification:
*	  Fintok!
*
*	Last update:
*	  09/03/2016
*
*	Changes:
*	- Refactoring and bug fixing in the code of plugin
*
*	Credits:
*	- The original idea of the plugin belongs to wer1K
*	- The original code belongs to Justick
*/

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#if AMXX_VERSION_NUM < 183
	#include <dhudmessage>
	#include <colorchat>

	#define print_team_default DontChange

	#define MAX_PLAYERS 32
#endif

#define PLUGIN "Svinorez"
#define VERSION "2.1 Fix"
#define AUTHOR "Fintok!"

#define is_user_valid_connected(%1) (1 <= %1 <= MaxClients && is_user_connected(%1))

#define get_user_bit(%0) (g_bitSvinorez & (1 << (%0 & 31)))
#define set_user_bit(%0) (g_bitSvinorez |= (1 << (%0 & 31)))
#define clear_user_bit(%0) (g_bitSvinorez &= ~(1 << (%0 & 31)))

new const VIEW_KNIFE_MODEL[] = "models/knife/svinorez/v_offhand_knife.mdl"
new const PLAYER_KNIFE_MODEL[] = "models/knife/svinorez/p_offhand_knife.mdl"

new const SOUND_KILLING[] = "misc/svinorez/svinorez_act.wav"

new const BLOCK_MAPS_NAME[][] = { "100hp", "35hp", "1hp", "etc", "ka" }

const PDATA_SAFE = 2
const OFFSET_LINUX = 5
const OFFSET_CSTEAMS = 114
const OFFSET_WEAPONOWNER = 41
const OFFSET_LINUX_WEAPONS = 4
const OFFSET_ACTIVE_ITEM = 373
const OFFSET_WEAPONID = 43

#if AMXX_VERSION_NUM < 183
	const CS_TEAM_T = 1
	const CS_TEAM_CT = 2
#endif

new g_bitSvinorez
new g_bIsEnabled
new g_pFriendlyFire

#if AMXX_VERSION_NUM < 183
	new MaxClients
#endif

public plugin_precache()
{
	if(!(g_bIsEnabled = !!is_valid_map()))
		return

	precache_model(VIEW_KNIFE_MODEL)
	precache_model(PLAYER_KNIFE_MODEL)

	precache_sound(SOUND_KILLING)
}

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	if(!g_bIsEnabled)
		return

	register_event("TextMsg", "Event_NewGame", "a", "2=#Game_w", "2=#Game_C")

	RegisterHam(Ham_Killed, "player", "Fwd_PlayerKilled_Post", 1)

#if AMXX_VERSION_NUM < 183
	MaxClients = get_maxplayers()
#endif
}

public plugin_cfg()
	g_pFriendlyFire = get_cvar_pointer("mp_friendlyfire")

public Event_NewGame()
{
	static iPlayers[32], iNum, iPlayer

	get_players(iPlayers, iNum, "h")

	for(new i = 0; i < iNum; i++)
	{
		iPlayer = iPlayers[i]

		if(!get_user_bit(iPlayer))
			continue

		clear_user_bit(iPlayer)
	}

	check_forwards()
}

public Fwd_PlayerKilled_Post(victim, killer, shouldgib)
{
	if(!is_user_valid_connected(killer) || killer == victim || get_pcvar_num(g_pFriendlyFire) 
	&& fm_cs_get_user_team(killer) == fm_cs_get_user_team(victim))
		return

	static iWeaponId
	iWeaponId = fm_get_weapon_killer(victim, killer)

	if(iWeaponId != CSW_KNIFE)
		return

	if(!get_user_bit(killer))
	{
		set_user_bit(killer)
		check_forwards()

		replace_knife_models(killer)

		client_cmd(0, "spk %s", SOUND_KILLING)

		set_dhudmessage(0, 155, 255, -1.0, 0.55, 0, 0.0, 1.0, 3.0, 1.5)
		show_dhudmessage(killer, "Ты зарезал кабанчика и получаешь уникальный скин!")

		static szName[32]
		get_user_name(killer, szName, charsmax(szName))

		client_print_color(0, print_team_default, "^1[^4Свинорез^1] Игрок ^4%s^1 зарезал кабанчика и стал ^3свинорезом", szName)
	}

	if(get_user_bit(victim))
	{
		clear_user_bit(victim)
		check_forwards()
	}
}

public Fwd_Item_Deploy_Post(weapon_ent)
{
	static iOwner
	iOwner = fm_cs_get_weapon_ent_owner(weapon_ent)

	if(!get_user_bit(iOwner))
		return

	replace_knife_models(iOwner)
}

#if AMXX_VERSION_NUM < 183
public client_disconnect(id)
#else
public client_disconnected(id)
#endif
{
	if(!g_bIsEnabled)
		return

	clear_user_bit(id)
	check_forwards()
}

replace_knife_models(id)
{
	set_pev(id, pev_viewmodel2, VIEW_KNIFE_MODEL)		// v_knife model
	set_pev(id, pev_weaponmodel2, PLAYER_KNIFE_MODEL)	// p_knife model
}

check_forwards()
{
	static bool:bFwdStatus

	if(!g_bitSvinorez != !bFwdStatus)
	{
		static HamHook:iFwdItemDeploy;

		if((bFwdStatus = !!g_bitSvinorez))
		{
			if(!iFwdItemDeploy) {
				iFwdItemDeploy = RegisterHam(Ham_Item_Deploy, "weapon_knife", "Fwd_Item_Deploy_Post", 1)
			}
			else {
				EnableHamForward(iFwdItemDeploy)
			}
		}
		else
		{
			DisableHamForward(iFwdItemDeploy)
		}
	}
}

stock fm_get_weapon_killer(victim, killer)
{
	if(pev_valid(killer) != PDATA_SAFE)
		return -1

	static iInflictor
	iInflictor = pev(victim, pev_dmg_inflictor)

	if(iInflictor != killer)
		return -1

	static iEnt
	iEnt = get_pdata_cbase(killer, OFFSET_ACTIVE_ITEM)

	if(pev_valid(iEnt) != PDATA_SAFE)
		return -1

	return get_pdata_int(iEnt, OFFSET_WEAPONID, OFFSET_LINUX_WEAPONS)
}

stock fm_cs_get_weapon_ent_owner(ent)
{
	if(pev_valid(ent) != PDATA_SAFE)
		return -1

	return get_pdata_cbase(ent, OFFSET_WEAPONOWNER, OFFSET_LINUX_WEAPONS)
}

stock fm_cs_get_user_team(id)
{
	if(pev_valid(id) != PDATA_SAFE)
		return 0

	return get_pdata_int(id, OFFSET_CSTEAMS, OFFSET_LINUX)
}

stock substr(const str[], dest[], len, pos)
{
	static iPos, iInd

	for(iPos = iInd = 0; iPos < pos; iPos++)
    {
		if(iInd < len)
			dest[iInd++] = str[iPos]
    }
}

stock is_valid_map()
{
	static szMapName[32]
	get_mapname(szMapName, charsmax(szMapName))

	for(new i = 0; i < sizeof(BLOCK_MAPS_NAME); i++)
	{
		if(containi(szMapName, BLOCK_MAPS_NAME[i]) != -1)
			return false
	}
	return true
}