Bonus steam + damager

Всем привет, помогите разобраться с кодом. В общем хочу выдавать бонусы для steam игроков и админов, но работает плагин как то странно. Полученный урон отображается нормально, а нанесенный очень редко когда покажет.

Собственно, код:

Код:

#include <amxmodx>
#include <hamsandwich>
#include <fun>
#include <fakemeta>
#include <amxmisc>

#define INFO_DELAY 10.0

new g_MsgSync
new g_MsgSync2

new pid
new damage

new player_name[32]
new bool:isStartPlugin[32] = false
new roundCounter[32] = 0

public plugin_init()
{
	register_plugin("Bonus Steam", "1.0", "")
	RegisterHam(Ham_Spawn,"player","start_bonus",1)
	register_event("Damage", "EventDamage", "b", "2!0", "3=0", "4!0")
	
	g_MsgSync = CreateHudSyncObj()
	g_MsgSync2 = CreateHudSyncObj()
	
}

public client_putinserver(id)
{
	if(is_user_steam(id)){
		set_task(INFO_DELAY, "bonus_info", id)
	}
	if(is_user_steam(id) || is_user_admin(id)){
		isStartPlugin[id] = true
	}
}

public bonus_info(id){
	get_user_name(id,player_name,31)
	set_hudmessage(60, 255, 170,0.1, 0.5, 2, 4.0, 7.0, 0.03, 0.5, -1)
	show_hudmessage(id, "Привет %s!^nТак как у тебя STEAM версия CS 1.6^nМы делаем бонус для тебя:^n+ Комплект гранат^n+ Damager (Показывает урон)^nСпасибо за то, что ты с нами! =)",player_name)
}

public start_bonus(id){
	//Запуск привилегий
	if(isStartPlugin[id] && is_user_alive(id)){
		give_item(id,"weapon_hegrenade")
		give_item(id,"weapon_smokegrenade")
		give_item(id,"weapon_flashbang")
		if(roundCounter[id] < 3){
			set_hudmessage(60, 255, 170,0.1, 0.7, 2, 4.0, 7.0, 0.03, 0.5, -1)
			show_hudmessage(id, "Вам выданы:^nКомплект гранат^nDamager (Показывает Урон)!",player_name)
			roundCounter[id] += 1
		}
	}
}

public EventDamage(id)
{
	if(pev_valid(id))
	{
		pid = get_user_attacker(id)
		damage = read_data(2)
			
		if(isStartPlugin[id])
		{
			set_hudmessage(255, 0, 0, 0.45, 0.50, 2, 0.1, 4.0, 0.1, 0.1, -1)
			ShowSyncHudMsg(id, g_MsgSync2, "%i", damage)
			
			if(pev(pid, pev_flags) & FL_CLIENT)
			{
				set_hudmessage(0, 100, 200, -1.0, 0.55, 2, 0.1, 4.0, 0.02, 0.02, -1)
				ShowSyncHudMsg(pid, g_MsgSync, "%i", damage)
			}
		}
	}
}

public client_disconnect(id){
	isStartPlugin[id] = false
}

stock bool:is_user_steam(id)
{
// Author Sh0oter
        static dp_pointer
        if(dp_pointer || (dp_pointer = get_cvar_pointer("dp_r_id_provider")))
        {
            server_cmd("dp_clientinfo %d", id)
            server_exec()
            return (get_pcvar_num(dp_pointer) == 2) ? true : false
        }
        return false
}

hacker63, странный вы человек, не понимаете даже как ваш плагин работаетю

Код:

 
if(isStartPlugin[id])
{
	set_hudmessage(255, 0, 0, 0.45, 0.50, 2, 0.1, 4.0, 0.1, 0.1, -1)
	ShowSyncHudMsg(id, g_MsgSync2, "%i", damage)
			
	if(pev(pid, pev_flags) & FL_CLIENT)
	{
		set_hudmessage(0, 100, 200, -1.0, 0.55, 2, 0.1, 4.0, 0.02, 0.02, -1)
		ShowSyncHudMsg(pid, g_MsgSync, "%i", damage)
	}
}

Заменить на ->
Код:

 
if(isStartPlugin[id])
{
	set_hudmessage(255, 0, 0, 0.45, 0.50, 2, 0.1, 4.0, 0.1, 0.1, -1)
	ShowSyncHudMsg(id, g_MsgSync2, "%i", damage)
}    
if(33>pid>0 && isStartPlugin[pid])
{
	set_hudmessage(0, 100, 200, -1.0, 0.55, 2, 0.1, 4.0, 0.02, 0.02, -1)
	ShowSyncHudMsg(pid, g_MsgSync, "%i", damage)
}

Inline,

Спасибо, всё работает.