Dhud сообщение

/************************************ DHUD_Adverts_Deads **********************************
*    - Хочу поблагодарить neygomon'a за основу плагина "[1.5] HUD Message (реклама в HUD)".
*    - Настройка флагов:
*    - a - Не считать мертвых
*    - b - Не считать живых
*    - c - Не считать ботов
*    - d - Не считать реальных игроков
*    - e - Соответствие с командой
*    - f - Соответствие с частью имени ( клантегом например)
*    - g - Игнорирование регистра
*    - h - Не считать HLTV
*    - Финальная версия плагина 1.3
********************************************************************************
************/

#include <amxmodx>
#if AMXX_VERSION_NUM < 183
#include <dhudmessage>
#define MAX_PLAYERS 32
#endif

#pragma semicolon 1

#define TIMESHOW 10.0    // Время отображения DHUD сообщения
#define INTERVAL 11.0    // Интервал отображения DHUD сообщения, не ниже чем TIMESHOW иначе сообщения будут перекрываться
#define X -1.0    // Координата X, идёт слева направо, 0.0 слева, 1.0 справа, -1.0 по центру
#define Y 0.25    // Координата Y, идёт сверху вниз, 0.0 сверху, 1.0 снизу, -1.0 по центру
#define FLAGS "bch"    // флаги кому не выводить рекламу
#define VK_GROUP    // закоментируйте если не нужна реклама группы ВК, say /vk
#define CONSOL    // Логирование в консоль игрокам, закоментируйте если не нужно

#if defined VK_GROUP
#define X_VK -1.0    // Координата X рекламы ВК
#define Y_VK 0.80    // Координата Y рекламы ВК
#define SAY_VK "vk.com/ваша_группа"    // Ваша группа вконтакте
#endif

new const g_szText_dead[][] =
{
    "Сообщение 1",
    "Сообщение 2",
    "Сообщение 3",
    "Сообщение 4",
    "Вступай в группу VK!!!^nЧто бы получить ссылку на группу пропиши в чат /vk",
    "Сообщение 6 и т.д. через запятую, НО! не забывайте что после посл. сообщения запятую не ставить!"
};

public plugin_init() {
    register_plugin("DHUD_Adverts_Deads", "1.3.1", "pUzzlik");
    
    #if defined VK_GROUP
    register_clcmd("say /vk", "say_vk_dhud");
    register_clcmd("say_team /vk", "say_vk_dhud");
    #endif

    set_task(INTERVAL, "dhud_message", .flags="b");
}

public dhud_message() {
    static g_iNumberMessage;
    new players[MAX_PLAYERS], num;
    get_players(players, num, FLAGS);
    
    for(new i, player; i < num; i++) {
        player = players[i];

        set_dhudmessage(random_num(0, 255), random_num(0, 255), random_num(0, 255), X, Y, 0, 10.0, TIMESHOW);
        show_dhudmessage(player, "%s", g_szText_dead[g_iNumberMessage > charsmax(g_szText_dead) ? (g_iNumberMessage = 0) : g_iNumberMessage]);
        
        #if defined CONSOL
        client_print(player, print_console, "%s", g_szText_dead[g_iNumberMessage]);
        #endif
    }
    g_iNumberMessage++;
}

#if defined VK_GROUP
public say_vk_dhud(id) {
    set_dhudmessage(51, 153, 255, X_VK, Y_VK, 0, 6.0, TIMESHOW);
    show_dhudmessage(id, "Группа Вконтакте: %s", SAY_VK);
    #if defined CONSOL
    client_print(id, print_console, "Группа Вконтакте: %s", SAY_VK);
    #endif
}
#endif