Правила форума Гаранты форума
Размещение рекламы AMX-X компилятор

Здравствуйте, гость Вход | Регистрация

Наши новости:

14-дек
Добавлена поддержка utf8mb4
24-апр
Telegram группа
10-апр
Обновление PHP
11-апр
Раздача читов

> Правила форума

Этот раздел, как вы могли заметить по названию, предназначен для решения вопросов по поводу уже существующих модов и плагинов.
Пожалуйста, если у вас проблема с написанием плагина, не путайте этот раздел с разделом по скриптингу.
Для поиска плагинов и модов существует соответствующий раздел.

Название темы должно соответствовать содержанию. Темы с названием типа "Помогите", "Вопрос", "парни подскажите..." - будут удалены.
Все темы, не относящиеся к "Вопросам по модам и плагинам", будут удалены или перемещены в соответствующий раздел.

Правила оформления темы:
1. Помимо заголовка не забудьте верно сформулировать свой вопрос.
2. Выложите исходник (в тег кода + ) или ссылку на плагин который вызывает у вас вопросы.
3. Выложите лог с ошибками (если имеется) под спойлер

Снятие шапки во время раунда "невидимка"
Статус пользователя Captain
сообщение 31.12.2016, 13:51
Сообщение #1
Стаж: 12 лет

Сообщений: 251
Благодарностей: 7
Полезность: < 0

Всем привет, как сделать, чтобы во время раунда "невидимка" у террориста снималась шапка (если конечно он одел шапку)?

Исходник
Код: 
#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fakemeta>

new g_bwEnt[33]

#define PLUG_NAME "Team Hats"
#define PLUG_AUTH "trofian"
#define PLUG_VERS "1.0"

#define menusize 	1024

#define HATS_PATH 	"models/next21_hats"

new HatFile[128]
new MenuPages, TotalHats
new CurrentMenu[33]

new UserHaveHatWith[33] = 'o' // s - skin, m - two models, n - normal hat, o - not connected
new UserHatModel[33][256]

#define MAX_HATS 64
new HATMDL[MAX_HATS][128]
new HATNAME[MAX_HATS][128]

public plugin_init()
{
	register_plugin(PLUG_NAME, PLUG_VERS, PLUG_AUTH)
	register_concmd("amx_givehat", "Give_Hat", ADMIN_RCON, "<nick> <mdl #>")
	register_concmd("amx_removehats", "Remove_Hat", ADMIN_RCON, " - Removes hats from everyone.")
	register_menucmd(register_menuid("\yHat Menu: [Page"),(1<<0|1<<1|1<<2|1<<3|1<<4|1<<5|1<<6|1<<7|1<<8|1<<9),"MenuCommand")
	register_clcmd("say /hats",		"ShowMenu", -1, "Shows Knife menu")
	register_clcmd("hats",		"ShowMenu", -1, "Shows Knife menu")
	register_event("ResetHUD", "ResetHUD", "be")
}

public ResetHUD(id) set_task(2.0, "reload_hat", id)

public reload_hat(id)
{
	if(!is_user_alive(id))
		return
	
	new CsTeams:team = cs_get_user_team(id)
	
	if(!pev_valid(g_bwEnt[id]))
		return
	
	if(UserHaveHatWith[id] == 's')
	{
		if(team == CS_TEAM_CT)
			set_pev(g_bwEnt[id], pev_skin, 1)
		else if(team == CS_TEAM_T)
			set_pev(g_bwEnt[id], pev_skin, 0)
	}
	if(UserHaveHatWith[id] == 'm')
	{
		new hatmodel[256]
		
		if(team == CS_TEAM_CT)
			formatex(hatmodel, charsmax(hatmodel), "%s/c_%s", HATS_PATH, UserHatModel[id])
		else if(team == CS_TEAM_T)
			formatex(hatmodel, charsmax(hatmodel), "%s/t_%s", HATS_PATH, UserHatModel[id])
		
		engfunc(EngFunc_SetModel, g_bwEnt[id], hatmodel)
	}
}

public ShowMenu(id)
{
	CurrentMenu[id] = 1
	ShowHats(id)
	return PLUGIN_HANDLED
}

public ShowHats(id)
{
	new keys = (1<<0|1<<1|1<<2|1<<3|1<<4|1<<5|1<<6|1<<7|1<<8|1<<9)
	
	new szMenuBody[menusize + 1], WpnID
	new nLen = format(szMenuBody, menusize, "\yHat Menu: [Page %i/%i]^n",CurrentMenu[id],MenuPages)
	
	// Get Hat Names And Add Them To The List
	for (new hatid=0; hatid < 8; hatid++) {
		WpnID = ((CurrentMenu[id] * 8) + hatid - 8)
		if (WpnID < TotalHats) {
			new hatText[256]
			if(WpnID > 0)
			{
				if(HATNAME[WpnID][0] == 's')
					format(hatText, charsmax(hatText), "\y%s \w[\rцвет команды\w]", HATNAME[WpnID][1])
				else if(HATNAME[WpnID][0] == 'm')
					format(hatText, charsmax(hatText), "\y%s \w[\rмодель команды\w]", HATNAME[WpnID][1])
				else
					format(hatText, charsmax(hatText), "\y%s", HATNAME[WpnID])
			}
			else
				format(hatText, charsmax(hatText), "\r%s", HATNAME[WpnID])
			nLen += format(szMenuBody[nLen], menusize-nLen, "^n\w %i. %s",hatid + 1,hatText)
		}
	}
	
	// Next Page And Previous/Close
	if (CurrentMenu[id] == MenuPages) {
		nLen += format(szMenuBody[nLen], menusize-nLen, "^n^n\d9. Следующая")
	} else {
		nLen += format(szMenuBody[nLen], menusize-nLen, "^n^n\w9. Следующая")
	}
	
	if (CurrentMenu[id] > 1) {
		nLen += format(szMenuBody[nLen], menusize-nLen, "^n\w0. Предудыщая")
	} else {
		nLen += format(szMenuBody[nLen], menusize-nLen, "^n\w0. Выход")
	}
	show_menu(id, keys, szMenuBody, -1)
	return PLUGIN_HANDLED
}
public MenuCommand(id, key) 
{
	switch(key)
	{
		case 8:		//9 - [Next Page]
		{
			if (CurrentMenu[id] < MenuPages) CurrentMenu[id]++
			ShowHats(id)
			return PLUGIN_HANDLED
		}
		case 9:		//0 - [Close]
		{
			CurrentMenu[id]--
			if (CurrentMenu[id] > 0) ShowHats(id)
			return PLUGIN_HANDLED
		}
		default:
		{
			new HatID = ((CurrentMenu[id] * 8) + key - 8)
			if (HatID < TotalHats) {
				Set_Hat(id,HatID,id)
			}
		}
	}
	return PLUGIN_HANDLED
}

public plugin_precache()
{
	new cfgDir[32]
	get_configsdir(cfgDir,31)
	formatex(HatFile,63,"%s/HatList.ini",cfgDir)
	command_load()
	
	for (new i = 1; i < TotalHats; ++i) {
		if(HATNAME[i][0] == 'm')
		{
			new CurrFile[256]
			
			formatex(CurrFile, charsmax(CurrFile), "%s/t_%s", HATS_PATH, HATMDL[i])
			if(file_exists(CurrFile)) precache_model(CurrFile)
			
			formatex(CurrFile, charsmax(CurrFile), "%s/c_%s", HATS_PATH, HATMDL[i])
			if(file_exists(CurrFile)) precache_model(CurrFile)
		}
		else
		{
			new CurrFile[256]
			formatex(CurrFile, charsmax(CurrFile), "%s/%s", HATS_PATH, HATMDL[i])
			
			if (file_exists (CurrFile))
			{
				precache_model(CurrFile)
				server_print("[%s] Precached %s",PLUG_NAME,CurrFile)
			}
			else
				server_print("[%s] Failed to precache %s",PLUG_NAME,CurrFile)
		}
	}
}

public client_connect(id)
{
	if(g_bwEnt[id] > 0) engfunc(EngFunc_RemoveEntity,g_bwEnt[id])
	g_bwEnt[id] = 0
}

public client_disconnect(id)
{
	if(g_bwEnt[id] > 0) engfunc(EngFunc_RemoveEntity,g_bwEnt[id])
	g_bwEnt[id] = 0
	UserHaveHatWith[id] = 'o'
	formatex(UserHatModel[id], 255, "!NULL")
}

public Give_Hat(id)
{
	new smodelnum[5], name[32]
	read_argv(1,name,31)
	read_argv(2,smodelnum,4)
	
	new player = cmd_target(id,name,2)
	if (!player) {
		print_col_chat(id, "!g[%s] !yР?РіСЂРѕРє СЃ таким именем РЅРµ найден", PLUG_NAME)
		return PLUGIN_HANDLED
	}
	
	new imodelnum = (str_to_num(smodelnum))
	if (imodelnum > MAX_HATS) return PLUGIN_HANDLED
	
	Set_Hat(player,imodelnum,id)

	return PLUGIN_CONTINUE
}

public Remove_Hat(id)
{
	for (new i = 0; i < get_maxplayers(); ++i) {
		if (is_user_connected(i) && g_bwEnt[i] > 0) {
			engfunc(EngFunc_RemoveEntity,g_bwEnt[i])
			g_bwEnt[i] = 0
		}
	}
	client_print(id,print_chat,"[%s] Removed hats from everyone.",PLUG_NAME)
	return PLUGIN_CONTINUE
}

public Set_Hat(player,imodelnum,targeter)
{
	new name[32]
	get_user_name(player, name, 31)
	if (imodelnum == 0) {
		if(g_bwEnt[player] > 0) engfunc(EngFunc_RemoveEntity,g_bwEnt[player])
		g_bwEnt[player] = 0
		print_col_chat(targeter, "!g[%s] !yШапка снята с !t%s", PLUG_NAME, name)
		
	} else {
		if(g_bwEnt[player] < 1) {
			g_bwEnt[player] = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))
			if(g_bwEnt[player] > 0) 
			{
				UserHaveHatWith[player] = 'n'
				new mdlName[256]
				new CsTeams:team = cs_get_user_team(player)
				
				formatex(UserHatModel[player], 255, "%s", HATMDL[imodelnum])
				
				set_pev(g_bwEnt[player], pev_movetype, MOVETYPE_FOLLOW)
				set_pev(g_bwEnt[player], pev_aiment, player)
				set_pev(g_bwEnt[player], pev_rendermode, kRenderNormal)
				set_pev(g_bwEnt[player], pev_renderamt, 0.0)
				
				if(HATNAME[imodelnum][0] == 'm')
				{
					UserHaveHatWith[player] = 'm'
					
					if(team == CS_TEAM_CT)
						formatex(mdlName, charsmax(mdlName), "%s/c_%s", HATS_PATH, HATMDL[imodelnum])
					else if(team == CS_TEAM_T)
						formatex(mdlName, charsmax(mdlName), "%s/t_%s", HATS_PATH, HATMDL[imodelnum])
					
					engfunc(EngFunc_SetModel, g_bwEnt[player], mdlName)
				}
				else
				{
					format(mdlName, charsmax(mdlName), "%s/%s", HATS_PATH, HATMDL[imodelnum])
					
					engfunc(EngFunc_SetModel, g_bwEnt[player], mdlName)
				}
				
				if(HATNAME[imodelnum][0] == 's')
				{
					UserHaveHatWith[player] = 's'
					
					if(team == CS_TEAM_CT)
						set_pev(g_bwEnt[player], pev_skin, 1)
					else if(team == CS_TEAM_T)
						set_pev(g_bwEnt[player], pev_skin, 0)
				}
			}
		} else {
				UserHaveHatWith[player] = 'n'
				new mdlName[256]
				new CsTeams:team = cs_get_user_team(player)
				formatex(UserHatModel[player], 255, "%s", HATMDL[imodelnum])
				
				if(HATNAME[imodelnum][0] == 'm')
				{
					UserHaveHatWith[player] = 'm'
					if(team == CS_TEAM_CT)
						formatex(mdlName, charsmax(mdlName), "%s/c_%s", HATS_PATH, HATMDL[imodelnum])
					else if(team == CS_TEAM_T)
						formatex(mdlName, charsmax(mdlName), "%s/t_%s", HATS_PATH, HATMDL[imodelnum])
					
					engfunc(EngFunc_SetModel, g_bwEnt[player], mdlName)
				}
				else
				{
					formatex(mdlName, charsmax(mdlName), "%s/%s", HATS_PATH, HATMDL[imodelnum])
					
					engfunc(EngFunc_SetModel, g_bwEnt[player], mdlName)
				}
				
				if(HATNAME[imodelnum][0] == 's')
				{
					UserHaveHatWith[player] = 's'
					
					if(team == CS_TEAM_CT)
						set_pev(g_bwEnt[player], pev_skin, 1)
					else if(team == CS_TEAM_T)
						set_pev(g_bwEnt[player], pev_skin, 0)
				}
		}
		if(HATNAME[imodelnum][0] == 's' || HATNAME[imodelnum][0] == 'm')
			print_col_chat(targeter, "!g[%s] !yШапку !g%s !yодел !t%s", PLUG_NAME, HATNAME[imodelnum][1],name)
		else
			print_col_chat(targeter, "!g[%s] !yШапку !g%s !yодел !t%s", PLUG_NAME, HATNAME[imodelnum],name)
	}
}

public command_load()
{
	if(file_exists(HatFile)) {
		HATMDL[0] = ""
		HATNAME[0] = "Снять шапку"
		TotalHats = 1
		new sfLineData[128]
		new file = fopen(HatFile,"rt")
		while(file && !feof(file)) {
			fgets(file,sfLineData,127)
			
			// Skip Comment and Empty Lines
			if (containi(sfLineData,";") > -1) continue
			
			// BREAK IT UP!
			parse(sfLineData, HATMDL[TotalHats],40,HATNAME[TotalHats],40)
			
			TotalHats += 1
			if(TotalHats >= MAX_HATS) {
				server_print("[%s] Reached hat limit",PLUG_NAME)
				break
			}
		}
		if(file) fclose(file)
	}
	MenuPages = floatround((TotalHats / 8.0), floatround_ceil)
	server_print("[%s] Loaded %i hats, Generated %i pages)",PLUG_NAME,TotalHats,MenuPages)
}

stock print_col_chat(const id, const input[], any:...) 
{ 
	new count = 1, players[32]
	static msg[191]
	vformat(msg, 190, input, 3)
	replace_all(msg, 190, "!g", "^4") // Green Color 
	replace_all(msg, 190, "!y", "^1") // Default Color
	replace_all(msg, 190, "!t", "^3") // Team Color 
	
	if (id)
		players[0] = id
	else
		get_players(players, count, "ch")
	
	{
		for ( new i = 0; i < count; i++ )
		{
			if (is_user_connected(players[i]))
			{
				message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i])
				write_byte(players[i])
				write_string(msg)
				message_end()
			}
		}
	}
}



Надо добавить проверку. Это я знаю. Но какая функция отвечает за снятию шапки?

Код: 
	new szCvarDr[127]
	get_cvar_string("deathrun_mode", szCvarDr, charsmax(szCvarDr))

	if(equal(szCvarDr, "INVIS"))
	{
             if(is_user_connected(id) && (cs_get_user_team(id) == CS_TEAM_T))
                    тут функция, отвечающая за снятию шапки
	}


Отредактировал: Captain, - 31.12.2016, 13:59
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   Цитировать сообщение
Статус пользователя paraz1t15
сообщение 31.12.2016, 14:37
Сообщение #2
Стаж: 11 лет
Город: Красноярск

Сообщений: 240
Благодарностей: 49
Полезность: 171

if(is_user_connected(id) && (cs_get_user_team(id) == CS_TEAM_T))
Remove_Hat(id)
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Captain
сообщение 31.12.2016, 15:09
Сообщение #3
Стаж: 12 лет

Сообщений: 251
Благодарностей: 7
Полезность: < 0

Цитата(paraz1t15 @ 31.12.2016, 15:37) *
if(is_user_connected(id) && (cs_get_user_team(id) == CS_TEAM_T))
Remove_Hat(id)

Remove_Hat(id) - вроде как у всех удаляет шапки, мне надо, чтобы только у террориста шапка была удалена.
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 15:24
Сообщение #4
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

Captain, в таком случаи Вам нужно переписать ф-ю:
Код: 
public Remove_Hat(id)
{
   for (new i = 0; i < get_maxplayers(); ++i) {
      if (is_user_connected(i) && g_bwEnt[i] > 0) {
         engfunc(EngFunc_RemoveEntity,g_bwEnt[i])
         g_bwEnt[i] = 0
      }
   }
   client_print(id,print_chat,"[%s] Removed hats from everyone.",PLUG_NAME)
   return PLUGIN_CONTINUE
}
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
voed
сообщение 31.12.2016, 15:26
Сообщение #5
Стаж: 11 лет

Сообщений: 2593
Благодарностей: 1760
Полезность: 405

Код: 
public ResetHUD(id) set_task(2.0, "reload_hat", id)

cbf1b2bfde1a.gif
Мой тебе совет: забудь об этом плагине и найди другой
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 15:27
Сообщение #6
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

voed, я конечно все понимаю, но зачем выбрасывать этот плагин? Если можно переписать ResetHUD в Ham_Spawn?
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 15:35
Сообщение #7
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

Captain, Код: 
stock removeHatTeam(szTeam[])
{
	new iPlayers[32], iNum, pId;
	
	get_players(iPlayers, iNum, "ae", szTeam);
	
	for(new i = 0; i < iNum; i++)
	{
		iPlayers[i] = pId;
		
		if(g_bwEnt[pId] > 0)
		{
			engfunc(EngFunc_RemoveEntity, g_bwEnt[pId]);
			g_bwEnt[pId] = 0;
		}
	}
}


вот Вам готовый код, он удаляет шапки для указаной команды:
Код: 
removeHatTeam("CT"); // удалит всем живым игрокам за кт
removeHatTeam("TERRORIST"); // удалит всем живым игрокам за т


Отредактировал: Sorokin, - 31.12.2016, 15:38
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Captain
сообщение 31.12.2016, 15:51
Сообщение #8
Стаж: 12 лет

Сообщений: 251
Благодарностей: 7
Полезность: < 0

Код: 
public plugin_init()
{
	 RegisterHam(Ham_Spawn, "player", "fw_spawn")
}

public fw_spawn(id)
	 set_task(2.0, "reload_hat", id)


Так имели ввиду будет лучше?

Отредактировал: Captain, - 31.12.2016, 15:52
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 15:53
Сообщение #9
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

Captain, да, это более лучший вариант. Т.к. resetHUD вызывается не только в начале раунда ;)

Код: 
new szCvarDr[127]
get_cvar_string("deathrun_mode", szCvarDr, charsmax(szCvarDr))
 
if(equal(szCvarDr, "INVIS"))
{
	removeHatTeam("TERRORIST");
}
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Captain
сообщение 31.12.2016, 15:58
Сообщение #10
Стаж: 12 лет

Сообщений: 251
Благодарностей: 7
Полезность: < 0

Sorokin, Еще 1 вопрос. В каком паблике лучше сделать проверку на то что включен режим "невидимка"?
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 16:02
Сообщение #11
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

Captain, а когда этот режим вызывается? Какой deathrun мод используете? И есть ли в нем API?

Отредактировал: Sorokin, - 31.12.2016, 16:04
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Captain
сообщение 31.12.2016, 16:11
Сообщение #12
Стаж: 12 лет

Сообщений: 251
Благодарностей: 7
Полезность: < 0

Цитата(Sorokin @ 31.12.2016, 17:02) *
Captain, а когда этот режим вызывается? Какой deathrun мод используете? И есть ли в нем API?

Когда в начале раунда террорист выбирает режим "Невидимка".
Deathrun Manager by xPaw v3.0.3
API нет
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 16:13
Сообщение #13
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

Captain, самый хороший вариант, так это сделать deathrun manager'у API в виде форварда, а уже в плагине шапок, в этом же форварде проверять на режим и снимать шапку

Отредактировал: Sorokin, - 31.12.2016, 16:14
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя JIuXeP
сообщение 31.12.2016, 16:14
Сообщение #14


Стаж: 12 лет

Сообщений: 338
Благодарностей: 205
Полезность: 792

Если удалить нужно из другого плагина, например из мода...

нативно
в исходнике шапок
Где-нибудь добавляем Код: 
public plugin_natives () {
    register_native("n21_remove_hat", "native_remove_hat", 1);
}

public native_remove_hat(id) Remove_Hat(id);



Потом.. заменяем Код: 
public Remove_Hat(id)
{
   for (new i = 0; i < get_maxplayers(); ++i) {
      if (is_user_connected(i) && g_bwEnt[i] > 0) {
         engfunc(EngFunc_RemoveEntity,g_bwEnt[i])
         g_bwEnt[i] = 0
      }
   }
   client_print(id,print_chat,"[%s] Removed hats from everyone.",PLUG_NAME)
   return PLUGIN_CONTINUE
}

На Код: 
public Remove_Hat(id)
{
      if (is_user_connected(id) && g_bwEnt[id] > 0) {
        engfunc(EngFunc_RemoveEntity,g_bwEnt[id])
        g_bwEnt[id] = 0
    }

    /* Если игрока надо информировать... лучше сделать в доп. плагине, где используется натив */
    //new player_name[32]
    //get_user_name(id, player_name, 31)
    //client_print(id,print_chat,"[%s] %s, you hat is removed.",PLUG_NAME,player_name)
    return PLUGIN_CONTINUE
}

public Remove_Hat_ALL(id)
{
   for (new i = 0; i < get_maxplayers(); ++i) {
      if (is_user_connected(i) && g_bwEnt[i] > 0) {
         engfunc(EngFunc_RemoveEntity,g_bwEnt[i])
         g_bwEnt[i] = 0
      }
   }
   client_print(id,print_chat,"[%s] Removed hats from everyone.",PLUG_NAME)
   return PLUGIN_CONTINUE
}


И...
Код: 
register_concmd("amx_removehats", "Remove_Hat", ADMIN_RCON, " - Removes hats from everyone.")

-->
Код: 
register_concmd("amx_removehats", "Remove_Hat_ALL", ADMIN_RCON, " - Removes hats from everyone.")

в том плагине, где нужно это применить
После подключения инклюдов, добавляем Код: 
native n21_remove_hat(id);
Немного подправим вариант, который кинул Sorokin... Код: 
stock removeHatTeam(szTeam[])
{
    new iPlayers[32], iNum, pId;
    get_players(iPlayers, iNum, "e", szTeam);
   
    for(new i = 0; i < iNum; i++)
    {
        pId = iPlayers[i];
        n21_remove_hat(pId);
    }
}


Используется так же как и тут:


Отредактировал: JIuXeP, - 31.12.2016, 16:20
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 16:22
Сообщение #15
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

JIuXeP, вы сделали слишком нудно, прочитайте поподробнее о get_players, там не надо проверка на коннект уже! ;)

Код: 
public plugin_init()
{
	register_srvcmd("amx_remove_hats_for_tt", "removeHatsTT");
}

public removeHatsTT()
{
	new iPlayers[32], iNum, pId;
	
	get_players(iPlayers, iNum, "ae", "TERRORIST");
	
	for(new i = 0; i < iNum; i++)
	{
		iPlayers[i] = pId;
		
		if(g_bwEnt[pId] > 0)
		{
			engfunc(EngFunc_RemoveEntity,g_bwEnt[pId]);
			g_bwEnt[pId] = 0;
		}
	}
}


далее в плагине выбора режима (когда выбрал игрок инвиз):
Код: 
server_cmd("amx_remove_hats_for_tt");
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя JIuXeP
сообщение 31.12.2016, 16:31
Сообщение #16


Стаж: 12 лет

Сообщений: 338
Благодарностей: 205
Полезность: 792

Sorokin, ну да. так веселее. crazy.gif
Я позже обновил, и увидел сток. просто добавил в него натив. Хорошо... А если бы натив вызывался не в вашем стоке?

Забыл... шапки надо будет вернуть, когда игрок станет опять КТ.
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
Статус пользователя Sorokin
сообщение 31.12.2016, 16:38
Сообщение #17
Стаж: 9 лет 5 месяцев

Сообщений: 427
Благодарности: выкл.

JIuXeP, можно было бы сделать обычный натив! С тем же содержимым, что и паблик с srvcmd, и уже опять же юзать в другом плагине
Перейти в начало страницы         Просмотр профиля    Отправить личное сообщение
   + Цитировать сообщение
« Предыдущая тема · Общие вопросы по модам и плагинам · Следующая тема »
 
  Ответить в данную темуНачать новую тему
 
0 пользователей и 1 гостей читают эту тему:
Режим отображения: Стандартный · Переключить на: Линейный · Переключить на: Древовидный
Сообщить другу · Версия для печати

Powered By Invision Power Board  © 2005-2026 
Counter Strike Support Community