Only HS без блокировки крови

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define SPR_BLOODDROP                        "sprites/blood.spr"                                // Куски разлетающейся крови
#define SPR_BLOODSPRAY                        "sprites/bloodspray.spr"                        // Спрайт кнови в точке попадания
#define is_user_valid(%1)                         (1 <= %1 <= g_iMaxPlayers)

// Sprites
new g_Blood_SprDrop, g_Blood_SprSpray;

// Others
new Float:g_Player_LastDmgTime[33];
new g_iMaxPlayers        // Max players counter

/*===============================================================================
================================================================
                                                                    [Plugin Init]
================================================================================
================================================================*/
public plugin_init()
{
    // TraceAttack
    RegisterHam(Ham_TraceAttack, "player", "fw_TraceAttack_Pre", 0);

    // Get Max Players
    g_iMaxPlayers = get_maxplayers();
}

/*===============================================================================
================================================================
                                                                    [Plugin Precache]
================================================================================
================================================================*/
public plugin_precache()
{
    g_Blood_SprDrop = precache_model(SPR_BLOODDROP);
    g_Blood_SprSpray = precache_model(SPR_BLOODSPRAY);
}

/*===============================================================================
================================================================
                                                                [Ham TraceAttack Pre]
================================================================================
================================================================*/
public fw_TraceAttack_Pre(victim, attacker, Float:damage, Float:direction[3], tracehandle, damage_bits)
{
    // Если Жертва или Аттакер Не Валидны
    if(!is_user_valid(victim) || !is_user_valid(attacker))
        return HAM_IGNORED;

    // Если Жертве Не попали в Хитбокс Голову
    if(get_tr2(tracehandle, TR_iHitgroup) != HIT_HEAD)
    {
        // Переменные
        new Float:VecEnd[3];

        // Находим текущее игровое Время
        new Float:flGameTime = get_gametime();

        // Если текущее игрокое время Больше Последнего запомненного (фикс множественного урона на Дробанах)
        if(flGameTime > g_Player_LastDmgTime[attacker])
        {
            // Вызываем фейковый урон, чтобы отбработать все эффекты
            ExecuteHam(Ham_TakeDamage, victim, attacker, attacker, 0.0, damage_bits);

            // Запоминаем текущее Время
            g_Player_LastDmgTime[attacker] = flGameTime;
        }

        // Рисуем кровь на стенах
        ExecuteHam(Ham_TraceBleed, get_tr2(tracehandle, TR_pHit), damage, direction, tracehandle, damage_bits);

        // Находим оригины точки попадания
        get_tr2(tracehandle, TR_vecEndPos, VecEnd);

        // Рисуем вылет кровь из Жертвы
        Make_SpawnBlood(VecEnd, damage);

        // Рисуем вылет кровь из Жертвы
        Make_BloodSplat(victim, VecEnd, direction, damage*5.0);

        return HAM_SUPERCEDE;
    }

    return HAM_IGNORED;
}

stock Make_SpawnBlood(const Float:vTraceEnd[3], Float:Damage)
{
    // Переводим в целое значение
    new amount = floatround(Damage);

    // Умножаем на 2
    amount *= 2;

    // Если размер больше максимального
    if(amount > 255)
        amount = 255;    // Ставим максимальный размер

    // Создаем Эффект разлета крови
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
    write_byte(TE_BLOODSPRITE);
    write_coord(floatround(vTraceEnd[0]));
    write_coord(floatround(vTraceEnd[1]));
    write_coord(floatround(vTraceEnd[2]));
    write_short(g_Blood_SprSpray);            // Spray
    write_short(g_Blood_SprDrop);            // Drop
    write_byte(247);                            // Color (red)
    write_byte(min(max(3, amount/10), 16));    // Size
    message_end();
}

stock Make_BloodSplat(victim, const Float:vTraceEnd[3], const Float:direction[3], Float:Damage)
{
    // Переменные
    new Float:fVelocity[3];

    // Переводим урон в целое Число
    new amount = floatround(Damage);

    // Находим ускорение Жертвы
    pev(victim, pev_velocity, fVelocity);

    // Создаем Брызки Крови
    engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, vTraceEnd, 0);
    write_byte(TE_BLOODSTREAM);
    engfunc(EngFunc_WriteCoord, vTraceEnd[0]);     // x (положение жертвы)
    engfunc(EngFunc_WriteCoord, vTraceEnd[1]);     // y (положение жертвы)
    engfunc(EngFunc_WriteCoord, vTraceEnd[2]);     // z (положение жертвы)
    engfunc(EngFunc_WriteCoord, direction[0]);        // x (направление вылета крови)
    engfunc(EngFunc_WriteCoord, direction[1]);        // y (направление вылета крови)
    engfunc(EngFunc_WriteCoord, direction[2]);        // z (направление вылета крови)
    write_byte(223);        // color
    write_byte(amount + random_num(0, 100));    // speed
    message_end();
}