Ночной режим (смена карты)

Команды
amx_mot off – Принудительно отключение ночного режима, доступна администраторам с флагом e (slay/slap).

Настройки:
В файле mot.ini прописывать в таком формате:
00:00 02:00 de_dust2_2x2
02:00 04:00 de_inferno_2x2
04:00 08:00 awp_india

В файле mot_block_words.ini можно прописать команды которые будут блокироваться, если включён ночной режим.
Плагин должен быть прописан в самом верху plugins.ini.

Квары:
mot_show_hud 0/1 – отображать hud сообщение (стандартно 1)
mot_light 0/1/2/3 – задаёт уровень освещённости карты во время ночного режима, 1 – чуть темнее 2 – ещё темнее 3 – достаточно темно 0 – обычное освещение (стандартно 0)

[coub]Код:

#include amxmodx
#if AMXX_VERSION_NUM < 183
	#include colorchat
	#define change_level(%0) server_cmd("changelevel %s", %0)
#endif	

#define STARTTIME	00		// Время начала ночного режима. Тестировал только с 00 часов. Поддежка раннего времени есть, но не проверялось:)
#define ENDTIME		10		// Окончание ночного режима
#define MAP 		"de_dust2"	// Карта ночного режима
#define AUTORR		30		// Авторестарт карты (sv_restart 1) каждые n раундов. Установите 0 для отключения данной плюшки.

new g_pTimeLimit, g_iOldTime, Float:g_flResetTime;
new bool:g_bNight;
#if AUTORR > 0
new g_iRound;
#endif

public plugin_init()
{
#define VERSION "1.0.6"
	register_plugin("Lite NightMode", VERSION, "neygomon");
	register_cvar("lite_nightmode", VERSION, FCVAR_SERVER | FCVAR_SPONLY);

	register_event("TextMsg", 	"eGameCommencing", "a", "2=#Game_Commencing", "2=#Game_will_restart_in");	
	register_event("HLTV", 		"eRoundStart", "a", "1=0", "2=0");

	register_clcmd("say rtv", "RtvHook");
	register_clcmd("say_team rtv", "RtvHook");
	register_clcmd("say /rtv", "RtvHook");
	register_clcmd("say_team rtv", "RtvHook");
	register_clcmd("amx_rtv", "RtvHook");
	
	g_pTimeLimit = get_cvar_pointer("mp_timelimit");
}

public plugin_end()
	if(g_iOldTime) 
		set_pcvar_num(g_pTimeLimit, g_iOldTime);

public client_putinserver(id)
	if(g_bNight) 
		remove_user_flags(id, ADMIN_MAP|ADMIN_VOTE);
		
public eGameCommencing()
{
	g_flResetTime = get_gametime();
#if AUTORR > 0	
	g_iRound = 0;
#endif	
}	

public eRoundStart()
{
	static szCurMap[32], CurHour; time(CurHour);
#if STARTTIME > ENDTIME
	if(STARTTIME <= CurHour || CurHour < ENDTIME)
#else
	if(STARTTIME <= CurHour < ENDTIME)
#endif	
	{	
		if(!szCurMap[0])
		{
			get_mapname(szCurMap, charsmax(szCurMap));
			if(!equal(szCurMap, MAP))
				change_level(MAP);
		}	
		else if(!g_bNight)
		{
			g_bNight = true;
			RemovePlayersFlags();
			g_iOldTime = get_pcvar_num(g_pTimeLimit);
			set_pcvar_num(g_pTimeLimit, 0);
		}	
#if AUTORR > 0			
		static iRound; iRound = AUTORR - ++g_iRound;
		if(iRound > 0) client_print_color(0, 0, "^1[^4Only ^3%s^1] ^4Через ^3%d ^4раундов авторестарт карты. ^1[ ^4Тек. раунд: ^3%d ^1| ^4Всего: ^3%d^1 ]", MAP, iRound, g_iRound, AUTORR);
		else server_cmd("sv_restart 1");
#endif			
	}	
	else if(g_bNight)
	{
		set_pcvar_num(g_pTimeLimit, floatround(get_gametime() - g_flResetTime) / 60 + 5);
		g_bNight = false;
	}
}

public RtvHook(id)
{
	if(!g_bNight) return PLUGIN_CONTINUE;
	client_print_color(id, 0, "^1[^4Only ^3%s^1] ^4RTV не работает в ^3Ночном режиме!", MAP);
	return PLUGIN_HANDLED;
}

RemovePlayersFlags()
{
	static players[32], pcount;
	get_players(players, pcount, "ch");
	for(new i; i < pcount; i++)
		remove_user_flags(players[i], ADMIN_MAP|ADMIN_VOTE);
}

[/coub]