Обсуждение раскрутки CS сервера

#include <amxmodx>

#pragma semicolon 1

const PATH_STRLEN					= 64;
const AUTHID_STRLEN				= 24;
const IP_STRLEN						= 24;
const NAME_STRLEN					= 32;
const MESSAGE_STRLEN				= 512;
const TIME_STRLEN					= 32;
const ELLIPSES_ARG					= 4;

new g_sLogsDir[PATH_STRLEN];

public plugin_init() {
	register_plugin("Connections", "1.0", "Salpson");
}

public plugin_cfg() {
	get_localinfo("amxx_logs", g_sLogsDir, charsmax(g_sLogsDir));
	add(g_sLogsDir, charsmax(g_sLogsDir), "/connections");
	if(!dir_exists(g_sLogsDir)) mkdir(g_sLogsDir);
}

public client_putinserver(id) {
	new sAuthID[AUTHID_STRLEN], sIP[IP_STRLEN], sName[NAME_STRLEN];
	
	get_user_authid(id, sAuthID, charsmax(sAuthID));
	get_user_ip(id, sIP, charsmax(sIP), .without_port = true);
	get_user_name(id, sName, charsmax(sName));
	
	Logging(g_sLogsDir, "connections_", "^"%-32s %-32s %s^"", sAuthID, sIP, sName);
}

stock Logging(const sLogsDir[], const sFileName[], const sMessage[], any:...) {
	new sFmtMsg[MESSAGE_STRLEN], sTime[TIME_STRLEN], sLogFile[PATH_STRLEN + 32], iFileID;
	vformat(sFmtMsg, charsmax(sFmtMsg), sMessage, ELLIPSES_ARG);
	get_time("%d.%m.%Y.log", sTime, charsmax(sTime));
	formatex(sLogFile, charsmax(sLogFile), "%s/%s%s", sLogsDir, sFileName, sTime);
	iFileID = fopen(sLogFile, "at");
	get_time("%d.%m.%Y - %H:%M:%S", sTime, charsmax(sTime));
	fprintf(iFileID, "^"%s^" %s^n", sTime, sFmtMsg);
	fclose(iFileID);
}