world-of-cs

#include <amxmodx>
#include <sqlx>

#define HOST            "host"
#define USER            "user"
#define PASSWD        "passw"
#define DB                "db"

#define PREFIX_TABLE    "grey_"

// Бонусный флаг
// Если >1 флага то прописывать через |
#define BONUS_FLAG ADMIN_LEVEL_G // Флаг s

new Handle:g_SqlTuple;
new data[2];

public plugin_init(){
    register_plugin("RegBonus", "0.1", "7RG");
    g_SqlTuple = SQL_MakeDbTuple(HOST, USER, PASSWD, DB);
    SQL_SetCharset(g_SqlTuple, "utf8");
}

public plugin_end() SQL_FreeHandle(g_SqlTuple);

public client_putinserver(id){
    if(is_user_bot(id) || is_user_hltv(id)) return;
    static steamid[25]; get_user_authid(id, steamid, charsmax(steamid));
    static query[512]; formatex(query, charsmax(query), "SELECT `id` FROM `%susers` WHERE `steam` = '%s'",PREFIX_TABLE , steamid);
    data[0] = id; data[1] = get_user_userid(id);
    SQL_ThreadQuery(g_SqlTuple, "sqlConnectHandler", query, data, sizeof(data));
}

public sqlConnectHandler(failstate, Handle:query, err[], errcode, data[], datasize){
    switch(failstate){
        case TQUERY_CONNECT_FAILED:{
            log_amx("MySQL connection failed");
            log_amx("[ %d ] %s",errcode, err);
            log_amx("Query state: %d", data[0]);
            return PLUGIN_CONTINUE;
        }
        case TQUERY_QUERY_FAILED:{
            log_amx("MySQL query failed");
            log_amx("[ %d ] %s", errcode, err);
            log_amx("Query state: %d", data[0]);
            return PLUGIN_CONTINUE;
        }
    }
    if(is_user_connected(data[0]) && get_user_userid(data[0]) == data[1]){
        if(SQL_NumResults(query)) addUserFlag(data[0]);
        else set_task(2.0, "dhudShow", data[0], _, _, "b");
    }
    return PLUGIN_CONTINUE;
}

public addUserFlag(id) set_user_flags(id, get_user_flags(id)|BONUS_FLAG);

public dhudShow(id){
    if(!is_user_alive(id)){
        set_dhudmessage(255, 255, 0, -1.0, 0.85, 0, 0.0, 2.0, 0.0, 0.0);
        show_dhudmessage(id, "Регистрируйся на world-of-cs.ru . Вип в подарок");
    }
}