[ReAPI] GunDrop

Плагин меняет физику выброса оружия на более реалистичное и добавляет подсветку модели как из CSO

Код:

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>
#include <reapi>

#define PDATA_VALID 2
#define is_entity(%0) (pev_valid(%0) == PDATA_VALID)
#define is_user(%0) (1 <= %0 <= MaxClients)
#define MODEL_GUNDROP "models/406/gundrop.mdl"
#define SOUND_GUNDROP "406/weapondrop.wav"

public plugin_precache()
{
	engfunc(EngFunc_PrecacheModel, MODEL_GUNDROP)
	engfunc(EngFunc_PrecacheSound, SOUND_GUNDROP)
}

public plugin_init()
{
	register_plugin("GunDrop", "1.0", "406")
	RegisterHam(Ham_Item_Kill, "weaponbox", "fw_ItemKillPost", 1)
	RegisterHam(Ham_Touch, "weaponbox", "fw_TouchPost", 1)
	RegisterHookChain(RG_CBasePlayer_DropPlayerItem, "rg_CBasePlayerDropPlayerItemPost", 1)
}

public rg_CBasePlayerDropPlayerItemPost(player, szName[])
{
	new entity = GetHookChainReturn(ATYPE_INTEGER)
	if(!is_entity(entity)) return HC_CONTINUE
	set_pev(entity, pev_movetype, MOVETYPE_BOUNCE)
	set_pev(entity, pev_gravity, 1.0)
	set_pev(entity, pev_friction, 0.8)
	new Float:vOrigin[3]
	vOrigin[1] = random_float(-360.0, 360.0)
	set_pev(entity, pev_angles, vOrigin)
	vOrigin[1] = random_float(-200.0, 200.0)
	set_pev(entity, pev_avelocity, vOrigin)
	pev(player, pev_v_angle, vOrigin)
	angle_vector(vOrigin, ANGLEVECTOR_FORWARD, vOrigin)
	vOrigin[0] *= 300.0; vOrigin[1] *= 300.0; vOrigin[2] *= 300.0
	set_pev(entity, pev_velocity, vOrigin)
	return HC_CONTINUE
}

public fw_TouchPost(entity, victim)
{
	if(pev(entity, pev_flags) & FL_KILLME)
	{
		new gundrop = pev(entity, pev_iuser1)
		if(is_entity(gundrop)) set_pev(gundrop, pev_flags, FL_KILLME)
		return HAM_IGNORED
	}
	if(is_user(victim)) return HAM_IGNORED
	new Float:vOrigin[3]
	pev(entity, pev_velocity, vOrigin)
	vOrigin[0] *= 0.7; vOrigin[1] *= 0.7; vOrigin[2] *= 0.7
	set_pev(entity, pev_velocity, vOrigin)
	if(ExecuteHam(Ham_IsBSPModel, victim)) engfunc(EngFunc_EmitSound, entity, CHAN_VOICE, SOUND_GUNDROP, VOL_NORM, ATTN_NORM, 0, random_num(90, 120))
	new gundrop = pev(entity, pev_iuser1)
	if(is_entity(gundrop)) return HAM_IGNORED
	gundrop = rg_create_entity("info_target")
	set_pev(gundrop, pev_aiment, entity)
	set_pev(gundrop, pev_movetype, MOVETYPE_FOLLOW)
	engfunc(EngFunc_SetModel, gundrop, MODEL_GUNDROP)
	set_pev(gundrop, pev_framerate, 1.0)
	set_pev(entity, pev_iuser1, gundrop)
	return HAM_IGNORED
}

public fw_ItemKillPost(entity)
{
	new gundrop = pev(entity, pev_iuser1)
	if(is_entity(gundrop)) set_pev(gundrop, pev_flags, FL_KILLME)
}

и как?

ЧТо то не компилируется .

У вас древняя версия амх.

Спасибо за плагин, но можно ли сделать, чтобы лазер-мины не учитывались за объект и не имели подсветку? К примеру, вот эти..
 zp_lasermine_282.sma ( 37,23 килобайт ) Кол-во скачиваний: 25

Я не знаю почему мины подсвечиваються, конфликта в вашем плагене с моим я не нашла.. Что именно происходит?

При установке лазеров они выглядят примерно вот так

Попробуйте сделать проверку отсеев класс мины в таче на моем плагине

Под 1.8.2 никак?

Вопрос к автору.

Каким образом удаляется кастомная энтити, при удалении оружия по таймауту или в конце раунда ?

Ham_Item_Kill на веапонбокс не вызывается как бэ. Единственно, что можно хукнуть, это Think и FM_FreeEntPrivateData

По факту плагин создает пустые энтити и они валяются где-то в нулевых оригинах карты. При чем, они остаются привязанными к определенным номерам энтити через мувтайп... К чему это в итоге приведет, можно лишь гадать.