Эффективность раскруток, хеши, тесты, раздачи

#include < amxmodx >
#include < reapi >

#pragma semicolon 1

new const HASHES_DIRECTORY[ ]		=	"/addons/rechecker/dlls";		// Путь до директории хранилище данных
new const HASHES_FILE_NAME[ ]		=	"ms_hashes.ini";				// Наименование файла хранилище данных

new const LOGS_FOLDER_NAME[ ]		=	"ms_check";						// Наименование каталога ведение журналов
new const LOGS_FILE_NAME[ ]			=	"ms_check";						// Наименование журналов для ведение информации

new const MS_UNKNOWN[ ]				=	"[UNKNOWN]";					// МС UNKNOWN
new const MS_STEAM[ ]				=	"[STEAM]";						// МС Steam
new const MS_RECLIENT[ ]			=	"[RECLIENT]";					// МС ReClient

const MAX_REGISTER_QUERY_FILE		=	32;								// Максимальное количество зарегистрированных файлов

const ELLIPSES_ARG					=	4;
const DP_PROTOCOL					=	48;
const DP_AUTH_REVEMU				=	4;

const MAX_LENGTH__PATH				=	64;
const MAX_LENGTH__MS_LINE			=	256;
const MAX_LENGTH__MS_FILE			=	64;
const MAX_LENGTH__MS_HASH			=	32;
const MAX_LENGTH__MS_NAME			=	32;
const MAX_LENGTH__AUTHID			=	64;
const MAX_LENGTH__NAME				=	32;
const MAX_LENGTH__IP				=	16;
const MAX_LENGTH__TIME				=	32;
const MAX_LENGTH__MESSAGE			=	512;

new g_dpProvider;
new g_dpProtocol;

new g_sLogsDir[ MAX_LENGTH__PATH ];
new g_sMsHashesFile[ MAX_LENGTH__PATH + 32 ];

new g_aRegisterQueryFile[ MAX_REGISTER_QUERY_FILE ][ MAX_LENGTH__MS_FILE ];

new bool: g_bMSCheck[ MAX_PLAYERS + 1 ];
new bool: g_bReClient[ MAX_PLAYERS + 1 ];

new Trie: g_tMsHashes;

public plugin_init( )
{
	register_plugin( "Master Servers Check", "1.0", "Javekson" );
}

public plugin_cfg( )
{
	formatex( g_sMsHashesFile, charsmax( g_sMsHashesFile ), "%s/%s", HASHES_DIRECTORY, HASHES_FILE_NAME );
	
	get_localinfo( "amxx_logs", g_sLogsDir, charsmax( g_sLogsDir ) );
	
	formatex( g_sLogsDir, charsmax( g_sLogsDir ), "%s/%s", g_sLogsDir, LOGS_FOLDER_NAME );
	
	if( !dir_exists( g_sLogsDir ) )
	{
		mkdir( g_sLogsDir );
	}
	
	g_dpProvider = get_cvar_pointer( "dp_r_id_provider" );
	
	g_dpProtocol = get_cvar_pointer( "dp_r_protocol" );
	
	g_tMsHashes = TrieCreate( );
	
	func_ReadMsHashesFile( );
}

public client_authorized( id )
{
	g_bMSCheck[ id ] = false;
	
	func_ReClientCheck( id );
}

func_ReadMsHashesFile( )
{
	new iFileID = fopen( g_sMsHashesFile, "rt" );
	
	new sMsLine[ MAX_LENGTH__MS_LINE ], sMsFile[ MAX_LENGTH__MS_FILE ], sMsHash[ MAX_LENGTH__MS_HASH ], sMsName[ MAX_LENGTH__MS_NAME ];
	
	while( !feof( iFileID ) )
	{
		fgets( iFileID, sMsLine, charsmax( sMsLine ) );
		
		trim( sMsLine );
		
		if( !sMsLine[ 0 ] || sMsLine[ 0 ] == ';' )
		{
			continue;
		}
		
		parse(sMsLine, sMsFile, charsmax( sMsFile ), sMsHash, charsmax( sMsHash ), sMsName, charsmax( sMsName ) );
		
		strtolower( sMsHash );
		
		for(new i; i < sizeof g_aRegisterQueryFile; i++ )
		{
			if( g_aRegisterQueryFile[ i ][ 0 ] )
			{
				if( equal( g_aRegisterQueryFile[ i ], sMsFile ) )
				{
					TrieSetString( g_tMsHashes, sMsHash, sMsName );
					
					break;
				}
			}
			else
			{
				RegisterQueryFile( sMsFile, "handler_MsQueryFile", RES_TYPE_HASH_ANY );
				
				TrieSetString( g_tMsHashes, sMsHash, sMsName );
				
				g_aRegisterQueryFile[ i ] = sMsFile;
				
				break;
			}
		}
	}
	
	fclose( iFileID );
	
	RegisterQueryFile( "../cstrike/config.cfg", "handler_MsQueryFile", RES_TYPE_HASH_ANY );
}

public handler_MsQueryFile( const id, const iMsHash, const iUniqueID )
{
	func_MasterServerCheck( id, iMsHash );
}

func_ReClientCheck( const id )
{
	server_cmd( "dp_clientinfo %d", id );
	server_exec( );
	
	if( get_pcvar_num( g_dpProtocol ) == DP_PROTOCOL )
	{
		if( get_pcvar_num( g_dpProvider ) == DP_AUTH_REVEMU )
		{
			query_client_cvar( id, "voice_quality", "QueryClientCvar_VoiceQuality" );
		}
	}
}

public QueryClientCvar_VoiceQuality( const id, const sCvar[ ], const sValue[ ] )
{
	g_bReClient[ id ] = bool: ( !equali( sValue, "Bad CVAR request" ) );
}

func_MasterServerCheck( const id, const iMsHash )
{
	if( g_bMSCheck[ id ] )
	{
		return PLUGIN_CONTINUE;
	}
	
	new sAuthID[ MAX_LENGTH__AUTHID ];
	get_user_authid( id, sAuthID, charsmax( sAuthID ) );
	
	new sPlayerName[ MAX_LENGTH__NAME ];
	get_user_name( id, sPlayerName, charsmax( sPlayerName ) );
	
	new sPlayerIP[ MAX_LENGTH__IP ];
	get_user_ip( id, sPlayerIP, charsmax( sPlayerIP ), .without_port = true );
	
	new sMsHash[ MAX_LENGTH__MS_HASH ];
	formatex( sMsHash, charsmax( sMsHash ), "%s", func_ByteToStringLE( iMsHash ) );
	
	strtolower( sMsHash );
	
	if( TrieKeyExists( g_tMsHashes, sMsHash ) )
	{
		new sMsName[ MAX_LENGTH__MS_NAME ];
		TrieGetString(g_tMsHashes, sMsHash, sMsName, charsmax( sMsName ) );
		
		func_Logging( g_sLogsDir, LOGS_FILE_NAME, "^"%-24s %-32s %-24s %s^"", sMsName, sAuthID, sPlayerIP, sPlayerName );
	}
	else
	{
		if( is_user_steam( id ) )
		{
			func_Logging( g_sLogsDir, LOGS_FILE_NAME, "^"%-24s %-32s %-24s %s^"", MS_STEAM, sAuthID, sPlayerIP, sPlayerName );
		}
		else if( is_user_authemu( id ) )
		{
			func_Logging( g_sLogsDir, LOGS_FILE_NAME, "^"%-24s %-32s %-24s %s^"", MS_RECLIENT, sAuthID, sPlayerIP, sPlayerName );
		}
		else
		{
			func_Logging( g_sLogsDir, LOGS_FILE_NAME, "^"%-24s %-32s %-24s %s^"", MS_UNKNOWN, sAuthID, sPlayerIP, sPlayerName );
		}
	}
	
	g_bMSCheck[ id ] = true;
	
	return PLUGIN_CONTINUE;
}

stock bool: is_user_authemu( id )
{
	return g_bReClient[ id ];
}

stock func_ByteToStringLE( iMsHash )
{
	new sMsHash[ MAX_LENGTH__MS_HASH ];
	formatex( sMsHash, charsmax( sMsHash ), "%02X%02X%02X%02X", ( iMsHash ) & 0xff, ( iMsHash >> 8 ) & 0xff, ( iMsHash >> 16 ) & 0xff, ( iMsHash >> 24 ) & 0xff );
	
	return sMsHash;
}

stock func_Logging( const sLogsDir[ ], const sFileName[ ], const sMessage[ ], any:... )
{
	new sFmtMsg[ MAX_LENGTH__MESSAGE ];
	vformat( sFmtMsg, charsmax( sFmtMsg ), sMessage, ELLIPSES_ARG );
	
	new sFileTime[ MAX_LENGTH__TIME ];
	get_time( "%d.%m.%Y", sFileTime, charsmax( sFileTime ) );
	
	new sLogFile[ MAX_LENGTH__PATH + 32 ];
	formatex( sLogFile, charsmax( sLogFile ), "%s/%s_%s.log", sLogsDir, sFileName, sFileTime );
	
	new iFileID = fopen( sLogFile, "at" );
	
	new sRecordTime[ MAX_LENGTH__TIME ];
	get_time( "%d.%m.%Y - %H:%M:%S", sRecordTime, charsmax( sRecordTime ) );
	
	fprintf( iFileID, "^"%s^" %s^n", sRecordTime, sFmtMsg );
	
	fclose( iFileID );
}