доработка плагина

#include <amxmodx>

#define ALL			// Показывать всем. Для показа только мервым и спектаторам закомментируйте
#define REPEAT_TIME 	45.0	// Время между сообщениями

#define MAX_MSG		256	// Не трогать!!!

new adMessages[MAX_MSG][191];
new ad_count, iMessgCount;

public plugin_init()
{
	register_plugin("Advert Messages", "1.22", "neygomon");
	set_task(REPEAT_TIME, "advert", .flags="b");
}

public plugin_cfg()
{
	new file = fopen("addons/amxmodx/configs/adverts.ini", "rt");
	if(file)
	{
		new string[192], message[191];
		while(ad_count < MAX_MSG && !feof(file))
		{
			fgets(file, string, charsmax(string));

			if(string[0] != ';' && parse(string, message, charsmax(message)))
			{
				while(replace(message, charsmax(message), "!n", "^1")) {}
				while(replace(message, charsmax(message), "!t", "^3")) {}
				while(replace(message, charsmax(message), "!g", "^4")) {}
				formatex(adMessages[ad_count++], charsmax(adMessages[]), "^1%s", message);
			}	
		}
		fclose(file);
		if(!ad_count) set_fail_state("Messages not found! Check file ^"addons/amxmodx/configs/adverts.ini^"");
	}
	else set_fail_state("File ^"addons/amxmodx/configs/adverts.ini^" not found!");
}

public advert()
{
#if defined ALL
	ChatColor(0, "%s", adMessages[iMessgCount == ad_count ? (iMessgCount = 0) : iMessgCount++]);
#else
	static players[32], pcount;
	get_players(players, pcount, "bch");
	for(new i; i < pcount; i++)
		ChatColor(players[i], "%s", adMessages[iMessgCount == ad_count ? (iMessgCount = 0) : iMessgCount++]);
#endif	
}

stock ChatColor(const id, const szMessage[], any:...)
{
	static pnum, players[32], szMsg[190], IdMsg; 
	vformat(szMsg, charsmax(szMsg), szMessage, 3);
	
	if(!IdMsg) IdMsg = get_user_msgid("SayText");
	
	if(id) 
	{ 
		players[0] = id;
		pnum = 1; 
	} 
	else get_players(players, pnum, "ch");
	
	for(new i; i < pnum; i++)
	{
		message_begin(MSG_ONE, IdMsg, .player = players[i]);
		write_byte(players[i]);
		write_string(szMsg);
		message_end();
	}
}